Discussion :

[Arsene12]

Bonjour,

j'ai créé un nouvel onglet dans le ruban d'excel, un nouveau groupe et un bouton lié à une macro. Je voudrai pouvoir renommer ce bouton à chaque fois que j'y clique dessus. Pourriez-vous m'indiquer comment faire, svp. J'ai testé le code ci-dessous mais il m'a pas permis d'identifier le bouton:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
    Dim ctrl As CommandBarControl
    For Each Cbar In Application.CommandBars
        '''MsgBox (Cbar.Name)
        With Cbar
            If .Type = msoBarButton Then
                For Each ctrl In .Controls                    
                    If ctrl.Name = "My Button Name" Then
                        MsgBox ("OK")
                    End If
                Next ctrl
            End If
        End With
    Next

[Vba14]

Bonjour,

Peut-être une réponse ici :

https://www.developpez.net/forums/d1...-bouton-ruban/

[patricktoulon]

Attention de quoi parle-t-on de UIribboncontrol ou de commandbarcontrol c'est pas tout à fait la même chose pas du tout même

si c'est un onglet (customUI) il te faut

le callback du ribbon voir même le onload callback (si bien entendu tu l'as prévu dans le custonUI.xml) pour déterminer de quoi on parle
après je ne sais pas si on peut changer le label d'un (<button...) pas VBA
par contre faire une bascule avec un autre bouton (visible/ou pas) je pense que c'est possible

SI c'est une commandbars alors récupère-le par son index dans la commandbars et son .caption=....

[patricktoulon]

re bon finalement avec une toute petite recherche j'ai trouvé pour les controls de ruban customUI
tu peux même changer l'image aussi

dans un module standard les callbacks

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
Dim RibbonUI As IRibbonUI
Dim ChangeLabel As Boolean
 
Sub CustomUI_onLoad(ribbon As IRibbonUI)
Set RibbonUI = ribbon
End Sub
 
Sub getLabelMonBouton(control As IRibbonControl, ByRef returnedVal)
If ChangeLabel Then
  returnedVal = "Off"
Else
  returnedVal = "On"
End If
End Sub
 
Sub getImageMonBouton(control As IRibbonControl, ByRef returnedVal)
If ChangeLabel Then
  returnedVal = "SadFace"
Else
  returnedVal = "HappyFace"
End If
End Sub
 
Sub MonBoutonPerso_Click(control As IRibbonControl)
If ChangeLabel Then
  'MsgBox "Change le label en ON et l'image ''souriant''"
Else
 ' MsgBox "Change le label en OFF et l'image ''fais la gueule''"
End If
'---
ChangeLabel = Not ChangeLabel
'---
RibbonUI.InvalidateControl "MonBoutonPerso"
End Sub

dans le customUI.xml

Code xml :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
 
<customUI xmlns="http://schemas.microsoft.com/office/2006/01/customui"  onLoad="CustomUI_onLoad">
 <ribbon>
    <tabs>
      <tab id="mon_menu_perso" label="mon menu perso">
        <group id="GroupPerso" label="Mon groupe perso">
          <button id="MonBoutonPerso" 
  size="large"
            getLabel = "getLabelMonBouton"
            getImage = "getImageMonBouton"
            onAction="MonBoutonPerso_Click" />
        </group>
      </tab>
    </tabs>
  </ribbon>
</customUI>

[Arsene12]

re bon finalement avec une toute petite recherche j'ai trouvé pour les controls de ruban customUI

Merci beaucoup Patrick pour ces bouts de code. Je connaissais pas le fichier CustomUI.xml. Le dessin résume très bien ce que je veux faire. Ça me permet d'avoir qu'un bouton pour deux macros "opposées". Je vais suivre les instructions et je pense pouvoir y arriver. J'ai repéré des liens 1, 2, qui vont m'aider aussi.