Discussion :

[scoubi77]

Bonsoir à tous,

Y a-t-il un moyen des trier des fichiers par date dans un répertoire sous Windows ?

J'ai bien trouvé comment parcourir un répertoire, copier des fichiers, renommer, effacer ... mais rien concernant ce fameux trie.
Par avance merci à ceux qui aurais une méthode Vba ou un début de piste.

Bien amicalement

[parmi]

Bonjour,

Une façon de faire

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
Sub ExtraireFichiers()
    Dim Repertoire As String, Fichier As Variant
    Dim Tablo() As Variant
    Dim Cnt As Long
 
    Repertoire = "C:\Test\"
 
    'Comptabilise le nombre de fichiers excel trouvés
    Fichier = Dir(Repertoire & "*.xl*", vbArchive)
    Do While Fichier <> ""
        Cnt = Cnt + 1
        Fichier = Dir
    Loop
 
    'Dimensionne un tableau qu'on va remplir et trier par la suite
    ReDim Tablo(Cnt - 1, 1)
    Cnt = 0
    Fichier = Dir(Repertoire & "*.xl*", vbArchive)
    Do While Fichier <> ""
        Tablo(Cnt, 0) = Fichier   'Nom du fichier
        Tablo(Cnt, 1) = FileDateTime(Repertoire & Fichier)   'Sa date de modification
        Cnt = Cnt + 1
        Fichier = Dir
    Loop
 
    'Le tableau revient trié
    Tablo = TriTableau(Tablo)
 
End Sub
 
Function TriTableau(Tablo) As Variant
    Dim I As Long, J As Long
    Dim tmpVal1, tmpVal2
 
    For I = 0 To UBound(Tablo) - 1
        For J = I + 1 To UBound(Tablo)
            If Tablo(I, 1) > Tablo(J, 1) Then
                tmpVal1 = Tablo(I, 0)
                tmpVal2 = Tablo(I, 1)
                Tablo(I, 0) = Tablo(J, 0)
                Tablo(I, 1) = Tablo(J, 1)
                Tablo(J, 0) = tmpVal1
                Tablo(J, 1) = tmpVal2
            End If
        Next
    Next
 
    TriTableau = Tablo
End Function

[scoubi77]

Merci beaucoup pour cette réponse,
Mais je veux juste les trier sans les récupérer dans Excel

[patricktoulon]

Merci beaucoup pour cette réponse,
Mais je veux juste les trier sans les récupérer dans Excel

??????????????????
tu pourrais etre plus precis tu veux les trier dans quoi alors ??

[scoubi77]

Seulement dans le répertoire Patrick

[unparia]

Bonjour

L'ordre d'affichage des fichiers d'un répertoire dans l'explorateur n'est pas une question VBA, mais une question Windows.
Cet affichage est décidé (s'il y est autorisé) par l'utilisateur depuis l'onglet "Affichage" de la barre de menus de la fenêtre de l'explorateur.

[scoubi77]

Certes mais existe-t-il une instruction en vba qui permettrait justement de pouvoir faire cela à la place de l’utilisateur.
J’utilise un répertoire de stockage dans lequel je crée depuis Excel des fichiers PDF, mais il peut arriver que certains utilisateurs en rajoute de façon manuel sans passer par mon programme.
J’ai écris une boucle qui récupère depuis ce répertoire les noms de fichiers, date de création et je l’affiche dans une listeview.
Pour éviter de faire deux opérations, à savoir écrire dans une feuille les fichiers, trier et refaire une boucle pour les afficher dans ma listeview... directement les trier à la source avant l’affichage !
J’arrive à copier, créer, renommer un fichier, connaître sa date de modification.... depuis le Vba dans un répertoire Windows pourquoi pas lancer un tri par date dans ce même répertoire ?

[unparia]

existe t’il une instruction en vba qui permettrait justement de pouvoir faire cela à la place de l’utilisateur

Non. Aucune en VBA. Il t'est par contre possible de mettre en place un mécanisme (l'un d'entre eux t'a été suggéré) VBA pour afficher dans un contrôle de ton choix (rien à voir avec la fenêtre de l'explorateur) et dans l'ordre de ton choix les fichiers de ton choix.
Je te laisse maintenant là.

[scoubi77]

Merci beaucoup pour cette piste