Discussion :

[Sadr'ihel]

Bonjour,

J'ai un soucis d'utilisation de Find, j'imagine que je ne l'utilise pas correctement.
Ce qui est "amusant" c'est que cette syntaxe fonctionne sur une centaine de ligne et parfois ca bloque avec l'erreur variable objet ou variable de bloc with non défini.

Comme vous pouvez le voir dans ce code je cherche une chaîne de caractère et je sélectionne/copie la valeur adjacente vers un autre classeur avec la même chaîne de caractère.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
 
Cells.Find(what:=tri2).Offset(0, 9).Select
Selection.Copy
Windows("modele NO gestion.xlsm").Activate
Sheets(tri).Select
Cells.Find(what:=tri2).Offset(0, -1).Select
Selection.PasteSpecial Paste:=xlPasteAll
 
Windows("inventaire.xlsm").Activate
 
Cells.Find(what:=tri2).Offset(0, 4).Select
Selection.Copy
Windows("modele NO gestion.xlsm").Activate
Sheets(tri).Select
Cells.Find(what:=tri2).Offset(0, 1).Select
Selection.PasteSpecial Paste:=xlPasteAll

Merci de votre aide

[patricktoulon]

bonjour
toujours utiliser find dans une condition d'existence sinon c'est le crash assuré en find de find next
ton code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Cells.Find(what:=tri2).Offset(0, 9).Select
Selection.Copy
Windows("modele NO gestion.xlsm").Activate
Sheets(tri).Select
Cells.Find(what:=tri2).Offset(0, -1).Select
Selection.PasteSpecial Paste:=xlPasteAll

mon code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
set c=Cells.Find(what:=tri2)
if not c is nothing then c.Offset(0, 9).Copy
Windows("modele NO gestion.xlsm").Activate
Sheets(tri).Select
set c2=Cells.Find(what:=tri2)
if not c2 is nothing then 
c2.Offset(0, -1).Select
Selection.PasteSpecial Paste:=xlPasteAll
end if

et je suis casiment sur que l'on peut se passer des activate de window et select sur classeur differents ,je vais faire des tests

re
bon ben c'est bien ce que je pensait on a pas besoins de select ou activate et tout le toin toin

un exemple vite fait comme ca pour la demo

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
 
 
Sub test()
Dim Wbk1 As Workbook, Wbk2 As Workbook, c As Range, c2 As Range, tri2 As String
 
Set Wbk1 = ThisWorkbook
Set Wbk2 = Workbooks("Classeur2")
 
tri2 = "toto"
 
Set c = Wbk1.Sheets(1).Cells.Find(what:=tri2)
If Not c Is Nothing Then
Set c2 = Wbk2.Sheets(2).Cells.Find(what:=tri2)
If Not c2 Is Nothing Then c.Offset(0, 9).Copy Destination:=c2.Offset(0, -1)
End If
End Sub

en gros c'est simple

tu declare deux workbook (les concernés)
tu fait un find sur le sheets que tu veux du classeur 1 c'est C1
si c'a n'est pas rien alors tu peux aller faire le find dans le classeur2 .sheets(que tu veux)sera C2
si c2 n'est pas rien alors on copie destination directement

tu ne peut pas avoir d'erreur soulevée car on teste l'existence des deux donc si l'une des deux n'existe pas ben rien du tout alors
a noter que l'on pourrais encore plus simplifier l'ecriture en faisant les deux find d'affillé et faire le if nothing apres

edit:
voila pour etre precis tu peux faire comme ca

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub test()
Dim Wbk1 As Workbook, Wbk2 As Workbook, c As Range, c2 As Range, tri2 As String
Set Wbk1 = ThisWorkbook
Set Wbk2 = Workbooks("Classeur2")
tri2 = "toto"
Set c = Wbk1.Sheets(1).Cells.Find(what:=tri2)
Set c2 = Wbk2.Sheets(2).Cells.Find(what:=tri2)
critere = Not c Is Nothing And Not c2 Is Nothing
If critere = True Then c.Offset(0, 9).Copy Destination:=c2.Offset(0, -1)
End Sub

[Sadr'ihel]

merci pour ces exemples je vais les tester de suite.
Je reviens vite.

Edit

Ca marche super bien.
Je modifie tout mon projet et mes projets avec les wbk1 et 2 et 3 .... quand ce sera possible evidement.

Merci beaucoup