Boucle sur fichiers excel ouverts

**Supermichou** · 19/03/2018, 12h25

Bonjour, EDIT : et désolé je pensais vraiment écrire sur le forum VBA.....

Je souhaite faire une boucle For each .. Next sur des extractions d'un ERP qui sort des .xlsx sans pour autant avoir à les enregistrer.

Le soucis c'est que la détection des fichiers ouverts est sensible et que je ne la comprend pas.
Cette simple macro ne revoit que le fichier où je suis si je referme le fichier où se trouve la macro et le réouvre.

idem si j'enregistre les fichiers extraits et que je les ouvre depuis l'explorateur.

Par contre tout va très bien si je les ouvre depuis le menu excel.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Sub Macro2()
'
For Each book In Workbooks
MsgBox book.Name
Next
End Sub

J'avais déjà vu ce soucis sur d'autres macro, mais là c'est ennuyeux.

En bref, j'ai 5 ou 6 .xlsx ouverts en même temps que le .xlsm mais c'est ce en même temps qui ne semble pas être évident du point de vue du code.

Merci pour votre aide.

SM

**unparia** · 19/03/2018, 12h45

Bonjour
Rappels :
1) la collection WorkBooks ne contient que les classeurs ouverts (des procédures d'ouverture, dans la même instance de Excel, donc) depuis le classeur principal
2) les procédures d'un classeur ne sont plus effectives si l'on ferme ce classeur.

Ton soucis vient probablement d'une faille de prise en compte de ces deux aspects (le mécanisme mis en place lui-même).

**Igloobel** · 19/03/2018, 12h59

Bonjour,

Envoyé par Supermichou

...Le soucis c'est que la détection des fichiers ouverts est sensible et que je ne la comprend pas...

Qui ouvre les fichiers Excel ? toi manuellement ou une macro ?

**Supermichou** · 19/03/2018, 12h59

Merci Unparia,

pour le point 1) comment écrire le code pour que les fichiers excel ouverts en même temps soient pris en compte quelque soit le mode d'ouverture ?

pour le 2) c'était juste pour expliquer maladroitement que je changeais de session...

SM

**Supermichou** · 19/03/2018, 13h02

Envoyé par Igloobel

Bonjour,

Qui ouvre les fichiers Excel ? toi manuellement ou une macro ?

Bonjour,

moi, en faisant les extractions depuis l'ERP.
Le nombre peu varier un peu et le nom sera toujours différent (croisement de date et heure de l'extraction).

Donc je passe en revue les fichiers ouverts.

SM

**parmi** · 19/03/2018, 13h07

Bonjour,

Si je comprends bien, tu pourrais utiliser les Windows

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
For each prog in Application.Windows
    msgbox prog.caption
Next

**Igloobel** · 19/03/2018, 13h43

Envoyé par Supermichou

Bonjour,

moi, en faisant les extractions depuis l'ERP.
Le nombre peu varier un peu et le nom sera toujours différent (croisement de date et heure de l'extraction).

Donc je passe en revue les fichiers ouverts.

SM

Juste pour que l'on se comprenne bien :

- c'est l'ERP qui génère les fichiers Excel ou c'est toi qui pilote l'ERP qui envoie les données dans Excel

**Supermichou** · 19/03/2018, 13h49

re-

C'est l'ERP qui génère les .xlsx

SM

**Supermichou** · 19/03/2018, 13h54

Envoyé par parmi

Bonjour,

Si je comprends bien, tu pourrais utiliser les Windows

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
For each prog in Application.Windows
    msgbox prog.caption
Next

Bonjour,

J'ai testé ta solution.
Malheureusement elle doit obéir aux même contraintes, puisque je rencontre les même difficultés.
Merci quand même.

SM

**Igloobel** · 19/03/2018, 14h27

Envoyé par Supermichou

re-

C'est l'ERP qui génère les .xlsx

SM

Donc j'en déduis que c'est toi qui les ouvre pour les gérer

Dans ce cas j'utiliserai les "FileDialog"

exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
    Dim Wrbk As Workbook
    Dim Chem_Select As String
    Dim Shp As Shape
    Dim Wsh As Worksheet
 
'ouverture d'un fichier par boite FileDialog
'**********************************************************
    'Declaration d'une variable comme objet FileDialog
    Dim fd As FileDialog
 
    'Creation d'un objet FileDialog comme un File Open dialog box.
    Set fd = Application.FileDialog(msoFileDialogOpen)
 
    'Déclaration d'une variable contenant le "path" de style variant
    Dim vrtSelectedItem As Variant 'obligatoirement de type variant
 
    With fd
        .AllowMultiSelect = True
        .InitialFileName = "D:\Travaux\en cours"
 
        If .Show = -1 Then
             .Execute
        Else
            Exit Sub
        End If
    End With

là tous tes fichiers sont ouvert puis

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
    For Each Wrbk In Workbooks
 
    ' ...
    ' ton traitement par classeur
    ' ...
 
    Wrbk.Close
 
    Next Wrbk

j'ai épurer mon code qui est en production actuellement dans mon entreprise

tu dis
A+

**Supermichou** · 19/03/2018, 14h36

Igloobel,

C'est l'ERP qui créé les fichiers .xlsx
C'est l'ERP qui nomme les fichiers automatiquement
C'est l'ERP qui ouvre automatiquement les fichiers
C'est moi qui pourrait enregistrer les fichiers mais qui ne veut pas car une fois la macro exécutée, je n'ai plus besoin des fichiers.

en clair, l'ERP créé/ouvre/nomme des fichiers excel totalement non enregistrés et je lance une macro dessus pour en sortir les info. Puis ces fichiers, je les ferme sans les enregistrer car devenus inutiles.

Il n'y a donc ni chemin, ni racine de répertoire à indiquer.

Merci encore pour l'effort.

SM

**parmi** · 19/03/2018, 15h02

Si tu vas dans le gestionnaire de tâches quand ces fichiers sont ouverts par l'ERP, est-ce qu'il y a plusieurs instances d'Excel ?

**Igloobel** · 19/03/2018, 15h53

Envoyé par Supermichou

Igloobel,

C'est l'ERP qui créé les fichiers .xlsx
C'est l'ERP qui nomme les fichiers automatiquement
C'est l'ERP qui ouvre automatiquement les fichiers
C'est moi qui pourrait enregistrer les fichiers mais qui ne veut pas car une fois la macro exécutée, je n'ai plus besoin des fichiers.

en clair, l'ERP créé/ouvre/nomme des fichiers excel totalement non enregistrés et je lance une macro dessus pour en sortir les info. Puis ces fichiers, je les ferme sans les enregistrer car devenus inutiles.

Il n'y a donc ni chemin, ni racine de répertoire à indiquer.

Merci encore pour l'effort.

SM

Comment cela se lance ?
Parce que je vois pas comment l'ERP ferait tout ce que tu dis sans y être invité d'une manière ou d'une autre

**Supermichou** · 19/03/2018, 16h05

Envoyé par parmi

Si tu vas dans le gestionnaire de tâches quand ces fichiers sont ouverts par l'ERP, est-ce qu'il y a plusieurs instances d'Excel ?

Une seule session d'Excel

**Supermichou** · 19/03/2018, 16h06

Envoyé par Igloobel

Comment cela se lance ?
Parce que je vois pas comment l'ERP ferait tout ce que tu dis sans y être invité d'une manière ou d'une autre

Alors un "bouton" me permet d'extraire les données présentées, je choisis entre .CSV et .XLSX et zou j'ai mon fichier devant les yeux.
Je précise, ce n'est pas SAP...

SM
Nom : Capture.PNG
Affichages : 1701
Taille : 1,8 Ko

Nom : Capture.PNG
Affichages : 1701
Taille : 1,8 Ko

**Marc-L** · 20/03/2018, 00h19

Bonjour,

comment ouvres-tu alors le classeur contenant le code ?
Après son ouverture, vérifier au moins qu'il y a bien une seule instance
auquel cas tous les classeurs sont bien visibles dans la collection Workbooks,
ce n'est pas plus compliqué que cela …

___________________________________________________________________________________________________________

Je suis Paris, Egypte, Nigeria, New-York, Mogadicio, Barcelone, London, Manchester, Stockholm, Istanbul, Berlin, Nice, Bruxelles, Charlie, …

**patricktoulon** · 20/03/2018, 09h02

bonjour

Une seule session d'Excel

ca me parait difficile a croire etant donné que c'est pas le classeur macro qui ouvre les new xlx mais ton "ERP"

si ton "ERP" utilise l'instance de l'application excel faisant tourner le classeur macro pour ouvrir tes new XLSX , il y a la un soucis d'autorisation et meme de conception je dirais ,une enorme faille de securité

c'est pas du tout clair ton truc

**patricktoulon** · 20/03/2018, 09h55

re
je serait curieux de savoir ce que donne ceci: chez toi

declaration des Apis

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
#If VBA7 Then
  Private Declare PtrSafe Function AccessibleObjectFromWindow Lib "oleacc" ( _
    ByVal hwnd As LongPtr, ByVal dwId As Long, riid As Any, ppvObject As Object) As Long
  Private Declare PtrSafe Function FindWindowExA Lib "user32" ( _
    ByVal hwndParent As LongPtr, ByVal hwndChildAfter As LongPtr, _
    ByVal lpszClass As String, ByVal lpszWindow As String) As LongPtr
#Else
  Private Declare Function AccessibleObjectFromWindow Lib "oleacc" ( _
    ByVal hwnd As Long, ByVal dwId As Long, riid As Any, ppvObject As Object) As Long
  Private Declare Function FindWindowExA Lib "user32" ( _
    ByVal hwndParent As Long, ByVal hwndChildAfter As Long, _
    ByVal lpszClass As String, ByVal lpszWindow As String) As Long
#End If

sub de test
la collection "GetExcelInstances()" contient toutes les instances d'excel
pour acceder eventuellement au(x) classeur(s) c'est xl.workbooks qui contiendra tout les classeur enregistré ou pas !!!! dans chaque items "xl" de la collection

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub Test()
    Dim xl As Application
    For Each xl In GetExcelInstances()
        For Each wbk In xl.Workbooks
            Debug.Print wbk.FullName
        Next
    Next
End Sub

fonction de listage

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
 
Public Function GetExcelInstances() As Collection
  Dim guid&(0 To 3), acc As Object, hwnd, hwnd2, hwnd3
  guid(0) = &H20400
  guid(1) = &H0
  guid(2) = &HC0
  guid(3) = &H46000000
  Set GetExcelInstances = New Collection
  Do
    hwnd = FindWindowExA(0, hwnd, "XLMAIN", vbNullString)
    If hwnd = 0 Then Exit Do
    hwnd2 = FindWindowExA(hwnd, 0, "XLDESK", vbNullString)
    hwnd3 = FindWindowExA(hwnd2, 0, "EXCEL7", vbNullString)
    If AccessibleObjectFromWindow(hwnd3, &HFFFFFFF0, guid(0), acc) = 0 Then
      GetExcelInstances.Add acc.Application
    End If
  Loop
End Function

**Supermichou** · 22/03/2018, 09h18

Bonjour à tous,

Merci Patrick, ça marche très bien !!

Je ne pensais pas qu'il faudrait en arriver à ce niveau de complexité, mais ça marche bien.
J'ai parfois la liste qui se répète, mais au moins ça passe en revue tous les excel ouverts quel que soit le mode d'ouverture.

Grace à ça j'ai vu que les .xlsx sont enregistrés dans un C:\Tmp

Pour la faille de sécurité, je ne comprends pas de quoi il retourne, si tu as 2 minutes, je suis preneur d'info.
En tout cas, un grand merci à toi.

Cdlt,
SM

**Supermichou** · 22/03/2018, 09h22

Envoyé par Marc-L

Bonjour,

comment ouvres-tu alors le classeur contenant le code ?
Après son ouverture, vérifier au moins qu'il y a bien une seule instance
auquel cas tous les classeurs sont bien visibles dans la collection Workbooks,
ce n'est pas plus compliqué que cela …

___________________________________________________________________________________________________________

Je suis Paris, Egypte, Nigeria, New-York, Mogadicio, Barcelone, London, Manchester, Stockholm, Istanbul, Berlin, Nice, Bruxelles, Charlie, …

Bonjour Marc,

le classeur contenant le code, je passe par l'explorateur.
Pour vérifier qu'il y ait une seule instance, je regarde dans le gestionnaire des tâches et il y a bien qu'une seule ligne.

SM

Boucle sur fichiers excel ouverts [XL-2016]

Macros et VBA Excel

Discussions similaires

Partager

Partager