Discussion :

[Rotax27]

Bonjour à tous,
À la place d'utiliser une InputBox je souhaite utiliser un Userform plus complet et plus souple. Mai comment puis je contrôler les entrées que tape l'utilisateur dans les zones de texte?
Dans la zone Nom je voudrais que l'utilisateur ne puisse rentrer que des lettres en majuscule
Dans la zone Prénom je voudrais que l'utilisateur ne puisse rentrer que des lettres
Dans la zone Pseudo je voudrais que l'utilisateur ne puisse rentrer que des lettres et/ou des chiffres
Dans la zone Age je voudrais que l'utilisateur ne puisse rentrer que des Chiffres.
Bien sûr en VBA

[a_diard]

voir ceci

bonne journée

http://silkyroad.developpez.com/VBA/ControlesUserForm/

[Rotax27]

Avec mes remerciements .
Le temps d'étudier tout çà et peut être je reviens vers toi . ou pas ....
Merci

[patricktoulon]

re
bonjouir
tu peux le controlzer directement au taper des touches
exemple utilisation de l'evenement keyPress pour tous et keyUp pour le nom en majuscule ca evite d'aller chercher si la touche maj est active

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
'l age rien que des num
Private Sub age_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
If Not IsNumeric(Chr(KeyAscii)) Then KeyAscii = 0: Exit Sub
End Sub
'le nom rien que des lettres
Private Sub nom_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
If Not Chr(KeyAscii) Like "[a-z-A-Z]" Then KeyAscii = 0: Exit Sub
End Sub
'le nom toujours en majuscule
Private Sub nom_KeyUp(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
nom = UCase(nom)
End Sub
'le prenom rien que des lettres maj ou min
Private Sub prenom_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
If Chr(KeyAscii) Like "[0-9]" Or Not Chr(KeyAscii) Like "[a-z-A-Z]" Then KeyAscii = 0: Exit Sub
End Sub
'le pseudo rien que des lettres ou des num
Private Sub pseudo_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
If Not Chr(KeyAscii) Like "[a-z-A-Z]" Then
If Not IsNumeric(Chr(KeyAscii)) Then KeyAscii = 0: Exit Sub
End If
End Sub

[Rotax27]

Bonjour a_diard et PatrickToulon.
Merci pour vos infos.
Mais tout de même j'ai du mal pour tout comprendre du premier coup. Enfin cela prends tournure, mais avec quelques défauts:
- Je suis pas arrivé à forcer les majuscule dans un champ; j' ai préféré passer par l'intermédiaire d'une autre cellule ou j'ai utiliser la fonction "MAJUSCULE" Cela fonctionne.
- Je n'arrive pas à mettre une valeur par défaut dans un OptionButton Ex: homme ou Femme je voudrais par défaut Homme. Je ne sais pas ou mettre le code du Userform-Initialize!
- J'ai un soucis avec des OptionButton dans un même GroupName au nombre de 7 choix de catégorie de poids : -60 Kg;60 - 70 Kg;70 - 80 Kg;80 - 90 Kg et + 90 Kg.
Pour que le choix + 90 Kg fonctionne : il faut d'abord que je valide l'un des premiers choix(qui fonctionnent) avant de valider le dernier choix + 90 Kg.
Et je voudrais aussi avoir la valeur par défaut de 70 - 80 Kg à l'ouverture du USF dans ces OptionButton


Merci pour vos réponses.
Comment fait on pour joindre un bout de code dans les règles de l'art (au bon format)?

[unparia]

Bonjour
je ne vais (et ne veux) répondre qu'aux questions posées à l'ouverture de ta discussion (contrôle de saisies dans des textboxes d'un userform) --->>
regarde ce que fait ceci, par exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Private Sub TextBox1_Change() '--->> ne recevra que des majuscules non accentuées, espaces et/ou tirets (pour les patronymes composés) et apostrophes (hé oui, commme D'HUMIERES, par exemple)
 TextBox1.Text = controle(TextBox1, "*[!A-Z '-]*", "patronyme")
End Sub
Private Sub TextBox2_Change() '--->> ne recevra que des lettres (accentuées ou non) , espaces, virgules et tirets (de qui écrire des prénoms, quoi)
 TextBox2.Text = controle(TextBox2, "*[!A-zâàéèîîôù, -]*", "prenom")
End Sub
Private Sub TextBox3_Change() '--->> ne recevra que des lettres (accentuées ou non) et des chiffres
 TextBox3.Text = controle(TextBox3, "*[!A-zâàéèîîôù0123456789]*")
End Sub
Private Sub TextBox4_Change() '--->> ne recevra que des chiffres
  TextBox4.Text = controle(TextBox4, "*[!0-9]*")
End Sub
Private Function controle(T As MSForms.TextBox, flt As String, Optional style As String) As String
  If style = "patronyme" Then T.Text = UCase(T.Text)
  If style = "prenom" Then T.Text = StrConv(T.Text, vbProperCase)
  If T.Text Like flt Then controle = T.Tag: Exit Function
  T.Tag = T.Text: controle = T.Tag
End Function

Les commentaires en début de chaque textbox t'indiquent ce qui va être traité et comment il le sera.
Tu verras à l'essai que la tache de l'utilisateur est simplifiée au-delà de ce que tu demandais, mais également que sont prévus les patronymes composés ainsi que les prénoms multiples et/ou composés.