Discussion :

[amoves]

Bonjour,
Je suis entrain d'écrire un code VBA pour le calcul des notes d'étudiants. Prenons une UE comportant deux ECU. Lorsque l'étudiant est défaillant dans un ECU le résultat est "Déf." (défaillant) et il a une note 15 dans le second ECU. Le calcul de la moyenne de l'UE fait (Moyenne ECU 1 + Moyenne ECU 2)/2. Ce qui veut dire que je vais obtenir ("Déf." + 15)/2 = 7,5.
J'arrive à le faire dans la feuille de calcul. Mais en écrivant le code VBA, j'ai des difficultés. Voilà ce j'ai écrit pour que le message (Erreur de compilation: Sub ou fonction non définie) lors de l'exécution de la macro.
Le problème se pose au niveau de la ligne en gras et qui est soulignée. A toutes fins utiles, je joints le fichier excel avec le code VBA.
Merci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Option Explicit 'Obligation de déclarer les variables
Const DebEtu_Cell = "C5"
'===================================================
'Calcul de notes pour les étudiants
'===================================================
Public Sub Calcul_Notes()
Dim MC As Range
'Se positionner sur le premier étudiant
Set MC = Range(DebEtu_Cell)
'Itérer vers le bas tant que la cellule est non vide
Do While Not IsEmpty(MC.Value)
'Calcul de la moyenne
If MC.Offset(0, 1).Value = "" And MC.Offset(0, 2).Value = "" Then
    MC.Offset(0, 3).Value = "Déf."
    ElseIf MC.Offset(0, 1).Value = "" Then
    MC.Offset(0, 3).Value = MC.Offset(0, 2).Value
    Else: MC.Offset(0, 3).Value = (MC.Offset(0, 1).Value) * 1 / 3 + (MC.Offset(0, 2).Value) * 2 / 3
End If
If MC.Offset(0, 4).Value = "" And MC.Offset(0, 5).Value = "" Then
    MC.Offset(0, 6).Value = "Déf."
    ElseIf MC.Offset(0, 4).Value = "" Then
    MC.Offset(0, 6).Value = MC.Offset(0, 5).Value
    Else: MC.Offset(0, 6).Value = (MC.Offset(0, 4).Value) * 1 / 3 + (MC.Offset(0, 5).Value) * 2 / 3
End If
If MC.Offset(0, 3).Value = "Déf." And MC.Offset(0, 6).Value = "Déf." Then
    MC.Offset(0, 7).Value = "Déf."
    Else: MC.Offset(0, 7).Value = Sum(MC.Offset(0, 3).Value And MC.Offset(0, 6).Value) / 2
End If
'
'Se position sur la cellule du dessous
    Set MC = MC.Offset(1, 0)
Loop
End Sub

[unparia]

Bonjour

Nul besoin de la fonction SUM
L'opérateur d'addition est l'opérateur +

[Pierre Fauconnier]

Salut

Sans avoir regardé le reste du code: AND est un opérateur logique, alors que tu dois utiliser l'opérateur arithmétique +. Du coup. SUM n'est plus utile.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Else: MC.Offset(0, 7).Value = (MC.Offset(0, 3).Value + MC.Offset(0, 6).Value) / 2

Cela étant, je serais enclin à réaliser l'opération par formules Excel, éventuellement placées par VBA:

• tu éviterais les boucles et la sélection des cellules à traiter (gourmand en temps);
• tu sortirais ta logique métier du code;
• tu éviterais les imbrications de IF... ENDIF;
• ton code ne ferait dès lors plus que quelques lignes;
• si demain ton calcul en F s'effectue différemment, tu dois uniquement modifier la formule sans toucher au reste du code^(*), alors que le code que tu proposes risque fort d'être bon à jeter et à reprendre de 0.

Dans Excel, la formule pour F peut s'écrire comme sur l'illustration suivante:



Si tu veux réaliser cela en VBA, tu utilises le code suivant (J'ai écrit le code uniquement pour F, à toi d'adapter pour les autres colonnes à droite)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub Calcul_Notes()
  Dim Formule As String
  Dim Plage As Range
 
  Set Plage = Range("f5:f" & Range("c1048576").End(xlUp).Row) ' On définit la plage à impacter
  Formule = "=IF(D5="""",IF(E5="""",""DEF."",E5),D5/3+E5*2/3)" ' Transcription de la formule "française" au format international (perso, je préfère)
  Plage.Formula = Formule ' Application de la formule sur la plage définie (équivaut à sélectionner la plage en Excel et à valider la formule par CTRL+ENTER
 
  ' Eventuellement, si tu veux figer les calculs par un copier/coller spécial valeurs
  Plage.Copy
  Plage.PasteSpecial xlPasteValues
  Application.CutCopyMode = False
End Sub

^(*) Si tu stockais ta formule dans une cellule Excel (par exemple dans une feuille de paramètres), tu n'aurais même pas à modifier ton code, il te suffirait de modifier la formule dans la cellule de la feuille de paramètres...

[amoves]

Je vous remercie sincèrement pour la solution

[Menhir]

Voilà ce j'ai écrit pour que le message (Erreur de compilation: Sub ou fonction non définie) lors de l'exécution de la macro.
Le problème se pose au niveau de la ligne en gras et qui est soulignée. A toutes fins utiles, je joints le fichier excel avec le code VBA.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

    Else: MC.Offset(0, 7).Value = Sum(MC.Offset(0, 3).Value And MC.Offset(0, 6).Value) / 2

Sum n'est pas une fonction VBA.
Pour pouvoir utiliser la fonction Sum de Excel en VBA, il faut préciser que c'est une fonction Excel en utilisant WorksheetFunction.
https://msdn.microsoft.com/library/f...ice.15%29.aspx

En plus, le contenu de ton Sum me parait très étrange.
Mais ne sachant pas ce que contiennent les cellules concernées, difficile d'avoir une certitude.

[joe.levrai]

Sum peut se rapporter à la classe Application ou la sous-classe Worksheetfunction

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Sub toto()
MsgBox Application.Sum(Cells(1, 1), Cells(2, 1))
MsgBox Application.WorksheetFunction.Sum(Cells(1, 1), Cells(2, 1))
End Sub

[Marc-L]

Bonjour,

et il vaut mieux éviter WorksheetFunction en cas de résultat en erreur …

___________________________________________________________________________________________________________

Je suis Paris, Egypte, Nigeria, New-York, Mogadicio, Barcelone, London, Manchester, Stockholm, Istanbul, Berlin, Nice, Bruxelles, Charlie, …