Discussion :

[joe.levrai]

Bonjour,

je dispose d'une tableau structuré contenant sur chaque ligne :

- une date de relevé d'indicateurs
- diverses colonnes de classification
- une date "données la plus ancienne"

ce tableau ne dispose pas d'une colonne "délai de traitement" qui serait basée sur la différence (en jours ouvrés) entre "date la plus ancienne" et "date de relevé d'indicateurs"

sur un reporting, j'utilise donc une formule matricielle assez fiable qui me remonte, pour une date d'indicateur donnée, le délai de traitement le plus élevé

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(NB.SI.ENS(INDIC[DATE];MaDate;INDIC[POLE];MonPole;INDIC[FLUX];"STOCK";INDIC[MEDIA];MonMedia;INDIC[DOMAINE];"<>" & MonDomaine1;INDIC[ITEM];"<>" & MonDomaine2)=0;"NC";MAX(NB.JOURS.OUVRES(MIN(SI((INDIC[DATE]=MaDate)*(INDIC[POLE]=MonPole)*(INDIC[FLUX]="STOCK")*(INDIC[MEDIA]=MonMedia)*(INDIC[DOMAINE]<>MonDomaine1)*(INDIC[ITEM]<>MonDomaine2);INDIC[PLUS_ANCIEN]));MaDate) - 1;0))

Seulement, je dois aujourd'hui modifier cette formule pour ne plus remonter le délai maximal sur une journée donnée (il y a environ 100 lignes pour chaque journée dans mon tableau structuré), mais pour effectuer une moyenne du délai de chaque ligne

Je n'ai pas la possibilité de créer une colonne supplémentaire qui afficherait le délai (même temporaire)

Auriez-vous une piste à me proposer, je pense avoir la tête dans le guidon sur cette formule et ne trouve aucune idée

[Zekraoui_Jakani]

Je cite "Je n'ai pas la possibilité de créer une colonne supplémentaire qui afficherait le délai (même temporaire)"
Mais tu as la possibilité d'ajouter une feuille avec une colonne affichant la moyenne journalière

[Pierre Fauconnier]

Salut,

Pourrais-tu donner un exemple de quelques lignes avec ce que tu souhaites obtenir (copie d'écran par exemple)?

[joe.levrai]

Bonjour,

voici deux lignes exemples "bidon" de la table
j'en ai environ 100 par jour, et je cherche à calculer (mensuellement) le délai moyen entre "PLUS_ANCIEN" et "DATE" (via NB.JOURS.OUVRES) avec pas mal de critères sur les autres colonnes




Actuellement, je calcule le délai max de chaque journée (via la formule que j'ai présenté en ouverture de discussion), et je fais ensuite une moyenne de chaque "délai max quotidien"

Ce que je souhaite à présent, c'est effectuer une moyenne arithmétique de l'ensemble des délais de chaque ligne correspond aux critères souhaités

[papouclo]

Bonjour,
Le problème vient du fait que la fonction NB.JOURS.OUVRES "est allergique" à un emploi dans une formule matricielle lui imposant comme paramètres des plages de cellules.
Une première piste est de retrouver un calcul redonnant le même résultat que la fonction.
Vu les paramètres de la fonction NB.JOURS.OUVRES dans la formule du premier post, j'ai supposé qu'il ne s'agissait d'éliminer comme jours chômés que les deux jours des weekends à l'exclusion d'une liste de jours féries. J'ai supposé aussi que les dates prises en compte, aussi bien "date la plus ancienne" que "date de relevé d'indicateurs" sont des dates de jours ouvrés donc ni des samedis, ni des dimanches.
Le tableau ci-dessous illustre une procédure de remplacement dans ce cas de la fonction NB.JOURS.OUVRES pour emploi dans des formules matricielles.

Les formules en C3, D3, E3, F3 , G3 et I3 sont respectivement :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
= 7*ENT($A3/7) 
= 7*ENT($B3/7)
= 2*(ENT($B3/7)-ENT($A3/7)) 
= B3-A3
= ($B3-$A3-2*(ENT($B3/7)-ENT($A3/7)))*($B3-$A3-2*(ENT($B3/7)-ENT($A3/7))>0)
= MAX(NB.JOURS.OUVRES(A3;B3)-1;0)

Les noms début et fin désignant respectivement les plages A3:A25 et B3:B25, les formules matricielles en H3:H25 et J23:J25 sont :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
= (fin-début-2*(ENT(fin/7)-ENT(début/7)))*(fin-début-2*(ENT(fin/7)-ENT(début/7))>0)
= NB.JOURS.OUVRES(début;fin)-1

bien sûr validées par Ctrl + Maj + Entrée. On peut vérifier le dysfonctionnement dans ce cas de la fonction NB.JOURS.OUVRES.
Pour des calculs plus élaborés, on a alors le choix entre la création d'une colonne intermédiaire ( ou feuille intermédiaire comme le propose Zekraoui_Jakani ) et le calcul de remplacement permettant d'obtenir une matrice virtuelle de délais.
On arrive au même résultat 10,95... en calculant la moyenne d'une façon ou de l'autre en H27 ou I27.
Reste à :
- adapter la méthode au problème intéressant joe.levrai
- réfléchir à la signification de la partie décimale qu'il risque d'y avoir dans le calcul de la moyenne et à l'utilité de la conserver (délai horaire à rajouter au nombre de jours ouvrés ???? Arrondir à l'entier le plus proche ? Pour ne pas risquer d'optimiser cette moyenne de délais, utiliser la fonction PLANCHER ? )

Cette dernière remarque vient à cause d'une autre idée de piste, non vérifiée, inspirée du contournement du problème par joe.levrai dans le calcul du délai maximum en remarquant qu'avec une seule date de fin, chercher le délai maximum revenait à chercher la "date la plus ancienne" minimale.
S'il s'agissait de "délais calendaires", il est évident que l'on a :
MOYENNE(délais calendaires) = MOYENNE(fin) - MOYENNE(début).
Qu'en est-il avec la fonction NB.JOURS.OUVRES ? Je n'ai pas essayé de chercher de façon rigoureuse mais la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

= NB.JOURS.OUVRES( MOYENNE(début);MOYENNE(fin))

donne comme résultat 11 ce qui est un bel arrondi de 10,95652174.
Cordialement
Claude