Discussion :

[Denis_67]

Bonjour,

Je bute sur un problème relativement simple
Je boucle sur une colonne, quand je trouve une certaine valeur je veux sauvegarder l'adresse d'une cellule.
plus tard en trouvant une autre valeur, je veux écrire une information à l'adresse précédemment sauvegardée dans ma variable et la remettre à blanc.

Malgé la consultation du tuto sur les variables (qui d'ailleurs ne parle pas du type RANGE), je ne trouve pas la solution.
http://silkyroad.developpez.com/vba/tableaux/

Si je déclare ma variable Lprod AS Range, j'ai une erreur 91 quand je veux sauvegarder l'adresse de la cellule (ligne 10)
Si je déclare ma variable Lprod As String, j'ai erreur une erreur de compilation qualificateur incorrect quand je lance la macro avec la variable Lprod en surlignée en bleu là où je suis sensé ecrire la valeur "F" ( ligne 14)
Si je ne déclare pas ma variable j'ai une erreur 424 quand je veux écrire dans cette adresse. ( ligne 14)
Le code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
 
Sub Fin()
Dim Of, Act, NoF, LProd As String
 
Range("AM2").Select
NoF = "X"
Do While Not IsEmpty(ActiveCell)
 
If ActiveCell.Value = "PRODUCTION" Then
LProd = ActiveCell.Offset(0, 9).Address
End If
 
If ActiveCell.Offset(0, -13).Value <> ActiveCell.Offset(-1, -13).Value Then
LProd.Value = "F"
LProd = Nothing
End If
 
ActiveCell.Offset(1, 0).Select
 
Loop
End Sub

Comment faire pour ce cas ?
Merci

[Philippe Tulliez]

Bonjour,

Malgé la consultation du tuto sur les variables (qui d'ailleurs ne parle pas du type RANGE), je ne trouve pas la solution

Le tutoriel référencé traite spécifiquement des variables tableaux et est en quelques sortes un complément d'un autre tutoriel du même auteur Utiliser les variables en VBA Excel où tu trouveras au chapitre II-K. Object les explications sur les variables objets.

[Denis_67]

MErci pour ta réponse, Philippe,

Je m'étais trompé dans le copier coller du lien et j'étais bien sur les variables;
Par contre je n'avais pas fait le lien objet range.

Mais je n'arrive toujours pas à faire fonctionner la séquence.
Soyons clair c'est pour comprendre, car j'ai utilisé une autre solution temporairement la colonne ne changeant pas je récupère la ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
 
Sub Fin()
Dim Of, Act, NoF, LProd As Range 'String
 
Range("AM2").Select
NoF = "X"
Do While Not IsEmpty(ActiveCell)
 
If ActiveCell.Value = "PRODUCTION" Then
'LProd = ActiveCell.Row
Set LProd = ActiveCell.Offset(0, 13).Address
End If
 
If ActiveCell.Offset(0, -13).Value <> ActiveCell.Offset(-1, -13).Value Then
'Cells(LProd, 48).Value = "F"
'LProd = ""
LProd.Value = "F"
LProd = Nothing
End If
 
ActiveCell.Offset(1, 0).Select
 
Loop
End Sub

[Philippe Tulliez]

Bonjour,
Si je lis la ligne 11 du code de ta procédure

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set LProd = ActiveCell.Offset(0, 13).Address

Tu confonds Objet et propriété
Un objet a des propriétés et des méthodes donc si tu souhaites qu'une variable soit un objet Range ce sera plutôt

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set LProd = ActiveCell.Offset(0, 13)

où LProd devient l'objet de la 13ème cellule à droite de la cellule active et une variable objet hérite des propriétés et méthodes de cet objet.
Tu peux donc ensuite connaître l'adresse de cet objet en écrivant par exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

MsgBox LProd.Address

Par contre si tu veux simplement conserver l'adresse de la 13ème colonne à droite de la cellule active alors tu utilises une variable de type String comme par exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

LProd = ActiveCell.Offset(0, 13).Address

que tu peux ensuite utiliser avec un objet Range comme par exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Range(LProd).Value = 10

Attention toutefois qu'alors l'adresse est par exemple A20 et que si tu souhaites obtenir l'adresse complète (Classeur, feuille, cellule) il faut utiliser l'argument nommé External en lui passant True comme valeur

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

LProd = ActiveCell.Offset(0, 13).Address(external:=True)

[Denis_67]

Merci BEAUCOUP Philippe pour ce petit cours qui m'a permis de comprendre mon erreur.
effectivement à partir en auto didacte, on manipule des éléments sans chercher à les comprendre et on mélange les genres.

en tout cas, c'est bien clair et bien sûr cela fonctionne. je pourrais donc reprendre cette procédure avec l'adresse indépendamment du fait que la colonne ou la ligne soit fixe ou pas.

encore merci.

[Menhir]

Ton code en plus propre (les Select/Selection, moins on en mets, mieux on se porte).

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub Fin()
Dim LProd As Range
Dim Ligne As Long
 
For Ligne = 2 To Cells(Rows.Count, "AM").End(xlUp).Row
   If Cells(Ligne, "AM").Value = "PRODUCTION" Then
       Set LProd = Cells(Ligne, "AV")
   End If
 
    If Cells(Ligne, "Z").Value <> Cells(Ligne - 1, "Z").Value Then
        LProd.Value = "F"
        Set LProd = Nothing
    End If
Next Ligne
 
End Sub

Si je déclare ma variable Lprod AS Range, j'ai une erreur 91 quand je veux sauvegarder l'adresse de la cellule (ligne 10)

C'est normal puisque l'adresse est une donnée String. On ne peut pas la mettre dans une variable Range.
Range est un objet donc, pour l'assignée, il faut commencer la ligne avec un Set.
https://msdn.microsoft.com/fr-fr/lib.../gg251642.aspx

Si je déclare ma variable Lprod As String, j'ai erreur une erreur de compilation qualificateur incorrect quand je lance la macro avec la variable Lprod en surlignée en bleu là où je suis sensé ecrire la valeur "F" ( ligne 14)

Il faudrait dans ce cas l'utiliser sous la forme Range(Lprod).

[Denis_67]

Merci à Menhir pour le complément et pour le nettoyage
Denis