Discussion :

[aescobar]

Bonjour à tous,

Je suis nouveau ici et c'est mon 1er message.
N'hésitez pas à corriger ma présentation.

Je rencontre un problème sur boucle VBA avec IF (ci-dessous)
Cela fonctionne une fois, pour l'enregistrement 16 (par exemple), mais pas pour les suivants, qui respectent pourtant la même condition que la ligne 16.

Je m'explique.
Tant que la cellule (i, 38) n'est pas vide, et SI la valeur = 1 (sachant que le 1 est calculé), ALORS exécute les quelques commandes qui suivent, SINON on passe à la cellule du dessous.

Merci d'avance pour tous conseils ! :-)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Sub Liste_des_mvt_injustiées()
 
Sheets("Saisie").Activate
 
Dim i As Integer
 
i = 7
 
While Sheets("Saisie").Cells(i, 38).Value <> ""                      'boucle qui contrôle l'ensemble de la liste cariste
 
 If Cells(i, 38).Text = "1" Then                                     'Si le contrôle(soupçon de fraude) est vrai
 
    Sheets.Add.Move After:=Sheets(Sheets.Count)                     'Je crée une nouvelle feuille et la déplace en dernier
    ActiveSheet.Name = Sheets("Saisie").Cells(i, 4).Value           'Je renomme la feuille au nom du cariste
 
    Sheets("Check").Select
 
   With Selection
        .AutoFilter Field:=2, Criteria1:=Sheets("Saisie").Cells(i, 5).Value        'Détail: Je filtre sur les mvt du cariste
   End With
 
    Range("A2").Select                                                             'Je sélectionne le détail de ses mouvements
    Selection.CurrentRegion.Select
    Selection.Copy
    Sheets(Sheets.Count).Select                                                    'Je colle sur la dernière feuille
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False
                                                                          'Je passe au contrôle suivant
 End If
 
i = i + 1
 
Wend
 
End Sub

[parmi]

Bonjour,

Sélectionner les feuilles ne sert à rien la plupart du temps.
Par contre, nommer les feuilles avant le Range permet d'éviter bien des erreurs...

[Patrice740]

Bonjour,

Par exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub Liste_des_mvt_injustiées()
Dim i As Long, f As Worksheet
  i = 7
  With Sheets("Saisie")
    While .Cells(i, 38).Value <> ""                                             'Boucle qui contrôle l'ensemble de la liste cariste
      If .Cells(i, 38).Text = "1" Then                                          'Si le contrôle(soupçon de fraude) est vrai
        Worksheets.Add.Move After:=Sheets(Sheets.Count)                         'Je crée une nouvelle feuille de calcul et la déplace en dernier
        Set f = ActiveSheet                                                     'Je défini la feuille créée
        f.Name = Worksheets("Saisie").Cells(i, 4).Value                         'Je renomme la feuille au nom du cariste
        Worksheets("Check").AutoFilter Field:=2, Criteria1:=.Cells(i, 5).Value  'Détail: Je filtre sur les mvt du cariste
        Worksheets("Check").Range("A2").CurrentRegion.Copy                      'Je copie le détail de ses mouvements
        f.Range("A1").PasteSpecial Paste:=xlPasteValues                         'Je colle le détail de ses mouvements
      End If
      i = i + 1                                                                 'Je passe au contrôle suivant
    Wend
  End With
End Sub

[Menhir]

Je te conseille aussi de remplacer :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Dim i As Integer
i = 7
While Sheets("Saisie").Cells(i, 38).Value <> ""
 
i = i + 1
Wend

Par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Dim i As Long
For i = 7 To Sheets("Saisie").Cells(Rows.Count, 38).End(xlUp).Row
 
Next i

[aescobar]

Merci à tous pour vos 1ères corrections

Mais hélas elle ne répondent pas à ma problématique principale, étant:

- Mon IF fonctionne à la 1ère ligne respectant les conditions, mais pas sur les lignes suivantes respectant pourtant les mêmes conditions.
- La condition est cells(i, 38) = "1"
- Ce "1" est calculé. D'où le ".Text" (et non un ".Value")

Sauriez-vous pourquoi mon IF ne se répète pas ?

Patrice merci, j'ai essayé ta proposition mais VBA se met en bugue. l'argument suivant n'étant pas défini:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Worksheets("Check").AutoFilter Field:=2, Criteria1:=.Cells(i, 5).Value

[riaolle]

Bonjour,
Je pense que ton problème se situe bien dans les Selection/Select. C'est dangeureux de travailer avec des Select/Activate ...
Si tu ne spécifie rien devant Cells(i,j), alors on s'intéresse à la cellule de la feuille active, or :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub Liste_des_mvt_injustiées()
Sheets("Saisie").Activate
Dim i As Integer
i = 7
While Sheets("Saisie").Cells(i, 38).Value <> ""                      
 If Cells(i, 38).Text = "1" Then                                     
      [...]
    Sheets("Check").Select    '----------> la feuille active devient donc "Check" et le prochain Cells(i,38) sera donc étudié sur cette feuille.
      [...]
 End If
i = i + 1
Wend
End Sub

D'où le conseil de Patrice740 depasser par des objets.

En ce qui concerne le

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Worksheets("Check").AutoFilter Field:=2, Criteria1:=.Cells(i, 5).Value

AutoFilter s'effectue sur un objet Range.
Supposons que ton tableau va de la colonne A à la colonne Z :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
With Sheets("Check")
    .Range("A1:Z" & .Range("A" & .Rows.Count).End(xlUp).Row).AutoFilter Field:=2, Criteria1:=Sheets("Saisie").Cells(i,5).Value
End With

.Range("A" & .Rows.Count).End(xlUp).Row permet de trouver la dernière ligne non vide.

[aescobar]

Oui c'est tout à fait ça !

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

 If Sheets("Saisie").Cells(i, 38).Text = "1" Then

Grand merci à Patrice et Riaolle

Cordialement,