VBA Excel Array

**ecornut** · 01/11/2016, 09h40

Bonjour - j'ai un tableau ( 10 colonne ) pour la lire et la mémoriser avec array aucun problème, pour copier les colonnes 1, 3 et 5 par exemple, j'ai un black out.. J'arrive à recopier la totalité des 10 colonnes .. je devrai ensuite supprimer les colonnes dont je n'ai pas besoin .. mais je pense qu il y a beaucoup plus simple, Merci pour votre aide ( Manu )

**patricktoulon** · 01/11/2016, 10h59

Bonjour

oui en effet il y a beaucoup plus simple
voici un exemple qui copy ta plage A1:J10 sans les colonne 1,3,5
et les colle a partir de la ligne 15 su le même sheets

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
Sub Macro1()
    Range("A:A,C:C,E:E").EntireColumn.Hidden = True
Range("A1:J10").SpecialCells(xlCellTypeVisible).Copy Cells(15, 1)
Range("A:A,C:C,E:E").EntireColumn.Hidden = False
End Sub

tu devrais t'en sortir avec cela c'est pas trop compliqué
espérant que cela soit moins flou pour toi
modification pour cette méthode suite a mon ereur d'interprétation signaler par le vieux sanglier préhistorique

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Sub Macro1()
   range ("A:J").EntireColumn.Hidden = True  
Range("A:A,C:C,E:E").EntireColumn.Hidden = false
 Range("A1:J10").SpecialCells(xlCellTypeVisible).Copy Cells(15, 1)
 range ("A:J").EntireColumn.Hidden = false
 End Sub

mille excuse au demandeur

**RyuAutodidacte** · 01/11/2016, 11h04

Bonjour, coucou Patrick

,

autre solution à adapter :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub toto()
 
    With Feuil1.UsedRange
        VA = Application.Index(.Value, Evaluate("ROW(1:" & .Rows.Count & ")"), [{1,3,5}]) ' Code donné par Marc-L :1, 3 et 5 sont les colonnes choisies
    End With 'on peut aussi choisir l'ordre des colonnes comme [{5,3,1}] par exemple
    Feuil2.Range("A1").Resize(UBound(VA, 1), UBound(VA, 2)) = VA
 
End Sub

**patricktoulon** · 01/11/2016, 11h13

bien RYU mais c'est l'inverse que l'on veut les colonnes 1,3,5 doivent sauter

tu t'es enfin permis d'utiliser app.index hein ca y est t'a compris

+1 car le code est propre

**RyuAutodidacte** · 01/11/2016, 11h16

oui index c'est top et bien pratique dans des cas

Edit : astucieux l'idée de cacher les colonnes je t'ai mis

**ecornut** · 01/11/2016, 11h21

Envoyé par patricktoulon

Bonjour

oui en effet il y a beaucoup plus simple
voici un exemple qui copy ta plage A1:J10 sans les colonne 1,3,5
et les colle a partir de la ligne 15 su le même sheets

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub Macro1()
    Range("A:A,C:C,E:E").EntireColumn.Hidden = True
Range("A1:J10").SpecialCells(xlCellTypeVisible).Copy Cells(15, 1)
Range("A:A,C:C,E:E").EntireColumn.Hidden = False
End Sub

tu devrais t'en sortir avec cela c'est pas trop compliqué
espérant que cela soit moins flou pour toi

Merci, c est une solution .. mon exemple était "simple" - je veux utiliser une fonction array pour une BD beaucoup plus volumineuse j ai d ailleurs utilisé le code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
For i = 1 To 5
 
    ActiveCell.Value = vBD(i, 1)
    ActiveCell.Offset(0, 1).Select
    ActiveCell.Value = vBD(i, 9)
    ActiveCell.Offset(0, 1).Select
    ActiveCell.Value = vBD(i, 3)
    ActiveCell.Offset(1, -2).Select
 
Next i

**patricktoulon** · 01/11/2016, 11h22

re
ce que veux le demandeur

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub toto()
 dim tableau 
    With Feuil1.UsedRange
        tableau = Application.Index(.Value, Evaluate("ROW(1:" & .Rows.Count & ")"), [{2,4,6,7,8,9,10}]) ' Code donné par Marc-L :1, 3 et 5 sont les colonnes choisies
    End With 'on peut aussi choisir l'ordre des colonnes comme [{5,3,1}] par exemple
    Feuil2.Range("A15").Resize(UBound(tableau, 1), UBound(tableau, 2)) = tableau
 
End Sub

@econut
les deux propositions sont parfaitement aptes a traiter des tableaux de grande taille il suffit d'adapter la plage

attention a usedrange quand même!!! des cellules non concernées par ton tableaux peuvent être prises en compte adapte plutôt ta plage textuellement

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub toto()
 
    With Feuil1.range("A1:J"& cells(rows.count,1).end(xlup).row)
        VA = Application.Index(.Value, Evaluate("ROW(1:" & .Rows.Count & ")"), [{2,4,6,7,8,9,10}]) ' Code donné par Marc-L :1, 3 et 5 sont les colonnes choisies
    End With 'on peut aussi choisir l'ordre des colonnes comme [{5,3,1}] par exemple
    Feuil2.Range("A15").Resize(UBound(VA, 1), UBound(VA, 2)) = VA
 
End Sub

**RyuAutodidacte** · 01/11/2016, 11h30

he oui @ecornut, simple à utiliser, tu peux même effacer les données de la même feuille pour les copier par la suite dans cette même feuille puisque les données sont mémorisées dans le tableau
Et comme dit plus haut solution à adapter

**patricktoulon** · 01/11/2016, 11h32

re
non ceci est tout bonnement inacceptable

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
For i = 1 To 5
 
    ActiveCell.Value = vBD(i, 1)
    ActiveCell.Offset(0, 1).Select
    ActiveCell.Value = vBD(i, 9)
    ActiveCell.Offset(0, 1).Select
    ActiveCell.Value = vBD(i, 3)
    ActiveCell.Offset(1, -2).Select
 
 Next i

d'autant plus que tu parle de tableau volumineux 1 select par cellule visitée wahouh!!! si tu a du temps a perdre OK

re
@Ryu

Edit : astucieux l'idée de cacher les colonnes je t'ai mis

je m'adapte au niveau du demandeur

**RyuAutodidacte** · 01/11/2016, 11h44

En effet, c'est la solution la plus simple quand on débute

**ecornut** · 01/11/2016, 11h59

Envoyé par patricktoulon

re
ce que veux le demandeur

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Sub toto()
 dim tableau 
    With Feuil1.UsedRange
        tableau = Application.Index(.Value, Evaluate("ROW(1:" & .Rows.Count & ")"), [{2,4,6,7,8,9,10}]) ' Code donné par Marc-L :1, 3 et 5 sont les colonnes choisies
    End With 'on peut aussi choisir l'ordre des colonnes comme [{5,3,1}] par exemple
    Feuil2.Range("A15").Resize(UBound(tableau, 1), UBound(tableau, 2)) = tableau
 
End Sub

**eriiic** · 01/11/2016, 12h18

Bonjour à tous,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
    With Feuil1.UsedRange
        VA = Application.Index(.Value, Evaluate("ROW(1:" & .Rows.Count & ")"), [{1,3,5}]) ' Code donné par Marc-L :1, 3 et 5 sont les colonnes choisies
    End With 'on peut aussi choisir l'ordre des colonnes comme [{5,3,1}] par exemple

Concis, souple et intéressant.
A condition d'être sûr de ne jamais dépasser 65536 lignes (même dans 3 ans si les données s'accumulent)
eric

**jurassic pork** · 01/11/2016, 12h34

hello,
heu il est quand même fort le Patrick. De la demande initiale :

Envoyé par ecornut

Bonjour - j'ai un tableau ( 10 colonne ) pour la lire et la mémoriser avec array aucun problème, pour copier les colonnes 1, 3 et 5 par exemple, j'ai un black out.

Il est arrivé à faire croire à tout le monde que c'était l'inverse qui était demandé (même au demandeur)

:

Envoyé par patricktoulon

bien RYU mais c'est l'inverse que l'on veut les colonnes 1,3,5 doivent sauter.

Où alors c'est moi qui ne comprend plus le français

Ami calmant, J.P

**patricktoulon** · 01/11/2016, 12h42

tu a raison hihihihihi!!

je traite 2 sujet similaire en même temps l'autre c'est l'inverse

je ferais un bon Gourou moi hahahaha

**RyuAutodidacte** · 01/11/2016, 16h32

Envoyé par eriiic

Concis, souple et intéressant.
A condition d'être sûr de ne jamais dépasser 65536 lignes (même dans 3 ans si les données s'accumulent)
eric

Bien vu, je n'ai jamais été confronté à ce problème. Etant donné que je suis en train d'apprendre j'aimerai bien une explication de cette limitation stp.

je ne suis pas sur de ce que vont penser les cadors mais pour pallier à cette limitation et garder le coté souple du choix des colonnes et quelque soit le nombre de de lignes

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub Titi()
    HTab = Feuil1.Cells(Rows.Count, 1).End(xlUp).Row 'à modifier selon le critère de la colonne maitre en nombre de lignes
    Xlig = Int(HTab / 65536) + 1
 
Application.ScreenUpdating = False
    For i = 1 To Xlig
 
    If i = Xlig Then M = 65536 - (HTab Mod 65536)
 
        With Feuil1.Range("A" & 1 + (i - 1) * 65536 - M & ":" & "J" & 65536 + (i - 1) * 65536 - M)
            VA = Application.Index(.Value, Evaluate("ROW(1:" & .Rows.Count & ")"), [{1,3,1}]) ' Code donné par Marc-L :1, 3 et 5 sont les colonnes choisies
        End With 'on peut aussi choisir l'ordre des colonnes comme [{5,3,1}] par exemple
        Feuil2.Range("A" & 1 + (i - 1) * 65536 - M).Resize(UBound(VA, 1), UBound(VA, 2)) = VA
 
    Next
Application.ScreenUpdating = True
End Sub

On reste que sur une boucle comme cela. je sais qu'il existe plusieurs façon de faire s'en est une de plus. A vous de juger de son efficacité

Voilà

Edit : Modification du code pour que tous les contextes soit pris :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub Titi()
    HTab = Feuil1.Cells(Rows.Count, 1).End(xlUp).Row
    Xlig = Int(HTab / 65536) + 1
 
Application.ScreenUpdating = False
    For i = 1 To Xlig
 
    If Xlig = 1 Then M = 0 Else If Xlig = i Then M = 65536 - (HTab Mod 65536)
 
        With Feuil1.Range("A" & 1 + (i - 1) * 65536 - M & ":" & "J" & 65536 + (i - 1) * 65536 - M)
            VA = Application.Index(.Value, Evaluate("ROW(1:" & .Rows.Count & ")"), [{1,3,1}]) ' Code donné par Marc-L :1, 3 et 5 sont les colonnes choisies
        End With 'on peut aussi choisir l'ordre des colonnes comme [{5,3,1}] par exemple
        Feuil2.Range("A" & 1 + (i - 1) * 65536 - M).Resize(UBound(VA, 1), UBound(VA, 2)) = VA
 
    Next
Application.ScreenUpdating = True
End Sub

bon je pense que l'on peut faire encore une petite amélioration, à voir …

Edit 2 : je me suis créé des fausses données avec ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub FaussesDonnees()
Application.ScreenUpdating = False
    ReDim VA(1 To 500000, 1 To 10)
        For i = 1 To UBound(VA, 1)
            For j = 1 To UBound(VA, 2)
                x = x + 1
                VA(i, j) = x
            Next
        Next
    Feuil1.Range("A1").Resize(UBound(VA, 1), UBound(VA, 2)) = VA
Application.ScreenUpdating = True
End Sub

**eriiic** · 01/11/2016, 16h53

C'est une limitation de Index, tout comme Transpose.
Sans doute n'ont-ils pas pu/voulu faire évoluer à l'arrivée de 2007 pour une raison qu'on ignore (limiter les incompatibilités descendantes ?)

**RyuAutodidacte** · 01/11/2016, 16h57

Merci pour l'explication, surtout que pour transpose je ne le savais pas non plus
merci

**joe.levrai** · 01/11/2016, 17h29

oui, cette limitation du Transpose sur 2^16 grrr

j'avais déjà du rallonger une proposition du double de sa longueur, juste pour gérer ça

http://www.developpez.net/forums/d15...s/#post8259216

EDIT : https://newtonexcelbach.wordpress.co...2013-and-2016/
intéressant pour bien comprendre les effets de bords possibles sur les versions récentes

**RyuAutodidacte** · 01/11/2016, 17h39

en effet je vois qu'on a utilisé quasi le même principe à peu de chose près

**patricktoulon** · 01/11/2016, 18h03

perso je comprends pas votre dernier débats
un tableau (variable variant) peut contenir autant de ligne que ce que vous propose Excel en terme de ligne dans un sheets

parti de la vous m'avez perdu

VBA Excel Array [Toutes versions]

Macros et VBA Excel

Discussions similaires

Partager

Partager