Discussion :

[Pierre67]

Bonjour à tous

dans les cellules cells (a,12) de la colonne L d'un tableau, je vais extraire depuis la colonne C une chaine de caractère comprise entre les signes "-" pour toutes les lignes de mon tableau avec la macro suivante et cela fonctionne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
Sub occurence()
Dim a As Integer, i As Integer
a = 4
For i = 4 To 79
     Cells(a, 12).Select
     ActiveCell.FormulaR1C1 = "=MID(RC[-9],(SEARCH(""-"",RC[-9],1))+1,SEARCH(""-"",RC[-9],(SEARCH(""-"",RC[-9],1))+1)-((SEARCH(""-"",RC[-9],1))+1))"
     a = a + 1
Next i
End Sub

mon tableau comporte plusieurs colonnes.
je peux recopier la macro pour chaque colonne cells(a,13).select ..... et la formule reste identique mais pas top

j'aimerai pouvoir incrémenter une variable pour les colonnes et ainsi balayer tout mon tableau.

Mais je me heurte à la syntaxe dans RC

quelqu'un aurait-il une idée

merci à vous

[parmi]

Bonjour,

J'ai de la difficulté à comprendre pourquoi les gens utilisent les formules R1C1 quand on peut utiliser Formula.
Les formules sont difficiles à lire par rapport à ce qu'on écrit dans les cellules de façon manuelle.

Quelle est cette formule que tu écris en colonne L et quelle serait celle que tu écrirais dans les autres ?

[Pierre67]

Bonjour

'ai de la difficulté à comprendre pourquoi les gens utilisent les formules R1C1 quand on peut utiliser Formula.

C'est parce qu'on a utilisé l'enregistreur de macros, si mes connaissances en vba étaient plus fournies ... je ne poserai peut-être pas cette question

Quelle est cette formule que tu écris en colonne L et quelle serait celle que tu écrirais dans les autres ?

Cells(a, 12).Select définit la colonne L

La formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ActiveCell.FormulaR1C1 = "=MID(RC[-9],(SEARCH(""-"",RC[-9],1))+1,SEARCH(""-"",RC[-9],(SEARCH(""-"",RC[-9],1))+1)-((SEARCH(""-"",RC[-9],1))+1))"

grâce a cette formule je fais mais ma recherche dans la colonne C
dans la colonne M j'irai chercher les valeurs de la colonne D donc toujours le même décalage RC-9, donc même formule

[SfJ5Rpw8]

bonjour,

pas vraiment clair il semble que tu contredise dans tes message : les formules dans les colonnes L et M ne sont-elles pas identiques ?

[Pierre67]

bonjour

oui elles sont identiques
d'où ma question: au lieu d'écrire plusieurs lignes de code pour des formules identiques comment remplacer le RC[-9] par une variables sur les colonnes

[SfJ5Rpw8]

Je comprends toujours pas ... si elle sont identique pourquoi veut tu une variable pour les modifier en fonction de la colonne destinataire ??

[joe.levrai]

Bonjour,

regarde si tout ceci te permet de perfectionner l'utilisation des formules sous VBA
4 méthodes, 4 résultats identiques

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Sub occurence()
Dim a As Integer, i As Integer
Dim Chaine As String
 
' colonnes L et M
For i = 12 To 13
    ' lignes 4 à 79
    For a = 4 To 79
 
        With Cells(a, i)
 
            ' adresse de la cellule située 9 colonnes avant
            Chaine = Replace(.Offset(0, -9).Address, "$", "")
 
            ' formula R1C1
            .FormulaR1C1 = "=MID(RC[-9],(SEARCH(""-"",RC[-9],1))+1,SEARCH(""-"",RC[-9],(SEARCH(""-"",RC[-9],1))+1)-((SEARCH(""-"",RC[-9],1))+1))"
 
            ' formula Local
            .FormulaLocal = "=STXT(" & Chaine & ";(CHERCHE(""-"";" & Chaine & ";1))+1;CHERCHE(""-"";" & Chaine & ";(CHERCHE(""-"";" & Chaine & ";1))+1)-((CHERCHE(""-"";" & Chaine & ";1))+1))"
 
            ' formula
            .Formula = "=MID(" & Chaine & ",(SEARCH(""-""," & Chaine & ",1))+1,SEARCH(""-""," & Chaine & ",(SEARCH(""-""," & Chaine & ",1))+1)-((SEARCH(""-""," & Chaine & ",1))+1))"
 
            ' calcul sous VBA et écriture du résultat
            ' sans écrire la formule dans excel
            If UBound(Split(.Offset(0, -9), "-")) > 0 Then .Value = Split(.Offset(0, -9), "-")(1)
 
        End With
    Next a
Next i
 
End Sub

seule la 4ème méthode gère le cas où tu n'as pas de texte encadré par deux "-"
pour les 3 autres ... je n'ai fais que transposer ta formule qui à la base ne gère pas le cas, et renvoi #VALEUR quand la formule tombe en erreur


quand tu seras à l'aise avec ce que je t'ai proposé, on verra pour te proposer l'optimisation ultime : ne pas utiliser deux boucles pour remplir tes cellules .... il est possible de tout réaliser sans boucle et en 5 lignes de code