Discussion :

[lumpys]

Bonjour,

J'ai réalisé un formulaire avec des boutons précédent et suivant or ceux-ci ne fonctionnent pas correctement.

Quelqu'un saurait-il ce qui ne convient pas. J'aurai par ailleurs souhaiter mettre un message quand on est sur le dernier enregistrement et qu'on ne peut pas passer au suivant car on a atteind la fin du tableau. J'ai essayé différentes choses mais aucune n'a fonctionné.

Merci beaucoup pour votre aide.

[kevin254kl]

Bonjour, peux tu nous montrer ton code?

[lumpys]

Il est dans le document joint mais voilà ci-dessous :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Private Sub Bt_Precedent_Click()
 
    If Me.NumOrdre.ListIndex = -1 Then Exit Sub
 
    Ligne = Me.NumOrdre.ListIndex + 1
 
    If Ligne > 1 Then
 
        Nom = Ws.Cells(Ligne, "B") 'Nom
 
        Prenom = Ws.Cells(Ligne, "C") 'Prénom
    Else
        MsgBox "Il n'existe pas d'enregistrement précédent."
    End If
 
End Sub
 
Private Sub Bt_Suivant_Click()
 
    If Me.NumOrdre.ListIndex = -1 Then Exit Sub
 
    Ligne = Me.NumOrdre.ListIndex + 3
 
    Nom = Ws.Cells(Ligne, "B") 'Nom
    Prenom = Ws.Cells(Ligne, "C") 'Prénom
    '    MsgBox "Vous avez atteint la fin des enregistrements."
 
End Sub

[OBO29]

Bonjour,

La prochaine fois, montre l'ensemble de ton code, ça sera plus facile.
Voici une adaptation :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
 
Dim Ws As Worksheet
Dim Ligne As Long
Dim Stop_Event As Boolean
 
Private Sub UserForm_Initialize()
    Dim J As Long
 
    Set Ws = Sheets("Feuil1")
 
    Stop_Event = True
 
    For J = 2 To Ws.Range("A" & Rows.Count).End(xlUp).Row
 
        NumOrdre.AddItem Ws.Range("A" & J)
 
    Next J
 
    For J = 2 To Ws.Range("B" & Rows.Count).End(xlUp).Row
 
        Nom.AddItem Ws.Range("B" & J)
 
    Next J
 
    Stop_Event = False
 
End Sub
 
Private Sub NumOrdre_Change()
 
    If Stop_Event = True Then Exit Sub
 
    If NumOrdre.ListIndex = -1 Then Exit Sub
 
    Stop_Event = True
 
    Nom.ListIndex = NumOrdre.ListIndex
 
    Prenom = Ws.Cells(NumOrdre.ListIndex + 2, "C") 'Prénom
 
    Stop_Event = False
 
End Sub
 
Private Sub Nom_Change()
 
    If Stop_Event = True Then Exit Sub
 
    If Nom.ListIndex = -1 Then Exit Sub
 
    Stop_Event = True
 
    NumOrdre.ListIndex = Nom.ListIndex
 
    Prenom = Ws.Cells(Nom.ListIndex + 2, "C") 'Prénom
 
    Stop_Event = False
 
End Sub
 
Private Sub Bt_Precedent_Click()
 
    If NumOrdre.ListIndex > 0 Then
 
        NumOrdre.ListIndex = NumOrdre.ListIndex - 1
 
    Else
 
        MsgBox "Il n'existe pas d'enregistrement précédent."
 
    End If
End Sub
 
Private Sub Bt_Suivant_Click()
 
    If NumOrdre.ListIndex < (NumOrdre.ListCount - 1) Then
 
        NumOrdre.ListIndex = NumOrdre.ListIndex + 1
 
    Else
 
        MsgBox "Vous avez atteint la fin des enregistrements."
 
    End If
 
End Sub

N'oublie pas le si ça te va.

Bonne continuation.

[clementmarcotte]

Bonjour,

Il est dans le document joint

La plupart des répondeurs ne veulent pas télécharger les fichiers-joints, surtout des fichiers de macros, et surtout aussi lorsqu'ils sont balancés ici sans avoir été demandés au préalable.

http://www.developpez.net/forums/d84...s-discussions/

[Invité]

Bonsoir,
Personnellement j'utilise un scrolbarre.

Je fixe le min à 2 si la ligne 1 contient les titres et le max sur la dernière ligne du tableau et value me donne la ligne j'utilise l'événement change pour rafraichir mes textbox!

[lumpys]

Autant pour moi concernant la pièce jointe.

Merci OBO29 ça fonctionne, c'est parfait