Discussion :

[SylvainM]

Bonjour à tous,

Désolé si cette demande a déjà été faite précédemment, mais les codes que j'ai trouvés jusqu'à présent n'étaient pas exactement adaptés à mon besoin, et je ne suis pas parvenu à les adapter tout seul.
Voici mon objectif :
Lister les dossier d'un répertoire dans une colonne (uniquement les dossiers à la racine : pas les sous-dossiers), et la taille de ces répertoires dans une 2e colonne.
Est-ce que quelqu'un pourrait m'aider pour cette tâche ?

Voila le résultat attendu :

Dossier	Taille
C:\Dossier\Sousdossier1	128 Mo
C:\Dossier\Sousdossier2	50 Mo
C:\Dossier\Sousdossier3	2 Mo

(j'ai mis en Mo, je m'occuperai des formules pour gérer o / Ko / Mo / Go ...)

Merci à vous.

Sylvain M.

[pijaku]

Bonjour,

Ce code est une adaptation, à ton cas, d'un code trouvé ici-même.
N'oublie pas de changer l'adresse du répertoire (variable NomRep).

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
'sources :
    'http://www.developpez.net/forums/d1169224/logiciels/microsoft-office/excel/contribuez/lister-feuille-calcul-l-arborescence-dossiers-sous-dossiers-d-repertoire/
Sub ListeDossiers()
Dim Fso As Object, SourceFolder As Object
Dim SubFolder As Object, NomRep As String
Dim Tb_Out()
 
On Error GoTo Fin
NomRep = "F:\Dossier\Dossiere\Dossier" '*-*-*-*-*-*-*-*-* A ADAPTER !!!!!
Set Fso = CreateObject("Scripting.FileSystemObject")
Set SourceFolder = Fso.GetFolder(NomRep)
 
For Each SubFolder In SourceFolder.SubFolders
    i = i + 1
    ReDim Preserve Tb_Out(1 To 2, 1 To i)
    'pour récupérer le chemin complet
    Tb_Out(1, i) = SubFolder.Path
'pour récupérer la taille
    Tb_Out(2, i) = SubFolder.Size
Next SubFolder
Range("A2").Resize(i, 2) = Application.Transpose(Tb_Out)
Fin:
End Sub

Précisions :
1- les tailles sont en Octet
2- ça mouline pas mal sur mon PC... A voir!

[pgz]

Bonjour.

Je ne sais pas comment tu as fait pour ne pas trouver de réponse à une question aussi courante.
Sur la même idée mais en plus complet et avec la fameuse mais méconnue bibli : Windows Script Host Object Model

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
Option Explicit
 
Function fListeSousDossiers() As Variant
'liste les sous-dossiers d'un répertoire, renvoie un tableau [Nom, Taille]
'utilise la référence : Windows Script Host Object Model (IWshRuntimeLibrary)
 
Dim oFso As IWshRuntimeLibrary.FileSystemObject
Dim oRep As IWshRuntimeLibrary.Folder
Dim oFold As IWshRuntimeLibrary.Folder
 
Dim oFDiag As Office.FileDialog
Dim oRepPath As String
Dim iNbFold As Integer, i As Integer, v As Variant
 
'l'opérateur est invité à choisir un repertoire
Set oFDiag = Application.FileDialog(msoFileDialogFolderPicker)
oFDiag.AllowMultiSelect = False
oFDiag.Title = "Choisir un répertoire."
If oFDiag.Show = -1 Then
    oRepPath = oFDiag.SelectedItems(1)
End If
 
Set oFDiag = Nothing
If oRepPath = vbNullString Then GoTo etqPasDeRepertoire
 
'Compter les sous-dossiers dans le répertoire
Set oFso = New IWshRuntimeLibrary.FileSystemObject
Set oRep = oFso.GetFolder(oRepPath)
iNbFold = oRep.SubFolders.Count
If iNbFold = 0 Then
    Set oFso = Nothing
    Set oRep = Nothing
    fListeSousDossiers = Null
    GoTo etqSortie
End If
 
'dimensionner le tableau
ReDim v(1 To iNbFold, 1 To 2)
 
'scruter le répertoire
i = 0
For Each oFold In oRep.SubFolders
    i = i + 1
    v(i, 1) = oFold.Name
    v(i, 2) = oFold.Size
Next oFold
 
fListeSousDossiers = v
 
Set oFso = Nothing
Set oRep = Nothing
 
etqSortie:
Exit Function
 
etqPasDeRepertoire:
    fListeSousDossiers = Null
    GoTo etqSortie
 
End Function
 
Sub subTest_fListeSousDossiers()
Dim oRng As Excel.Range
Dim v As Variant
 
v = fListeSousDossiers
 
If Not IsNull(v) Then
    Set oRng = ThisWorkbook.Worksheets(1).Range("A2")
    Set oRng = oRng.Resize(UBound(v, 1), 2)
    oRng.Value = v
 
    Set oRng = Nothing
    v = Empty
End If
 
End Sub

Si ça te plaît je t'accueille volontiers dans mon association pour la défense du passé simple et de la classe IWshRuntimeLibrary.

Cordialement,

pgz

[SylvainM]

Merci à vous pour ces 2 solutions ! : (et désolé pour la (les ?) faute(s) d'orthographe, corrigée )

Elles ont toute 2 fonctionné sur des dossiers de tailles raisonnables, mais dès que j'ai voulu les lancer sur le dossier visé (1To répartis en une 30aine de dossiers de plusieurs Go), j'ai eu :
- aucune réponse du 1er (pas de message d'erreur, pas de résultat)
- une "erreur d’exécution 76 - chemin d'accès introuvable", qui ouvre la console de débogage à cet emplacement :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
For Each oFold In oRep.SubFolders
    i = i + 1
    v(i, 1) = oFold.Name
    v(i, 2) = oFold.Size
Next oFold

Pour information, le dossier à scanner se trouve sur le réseau avec une adresse de type \\nomserveur\chemin\dossier (mais ça n'est pas un pb en soit, puisque ça marche sur des sous-dossiers du serveur, plus petits)

Une idée de la source du problème ?

Merci encore !

Sylvain M.

[pgz]

Mince alors. Du coup c'est foutu pour ton adhésion (de coeur) à mon assoce ?

Bon, quand ça plante, sur la ligne précédente, v(i,1) est renseigné ? (tu peux le voir en survolant avec le curseur)
Si tu sautes la ligne en erreur (mise en commentaire de ligne v(i,1), F8, réactivation de la ligne v(i,2), F5) ça recommence plus loin ?
Si tu le fais 2 fois, ça s'arrête toujours sur le même sous-dossiers?

pgz

[SylvainM]

Oui, ça s'arrête toujours sur les mêmes sous dossiers (i=12, i=16) après avoir fait les manip conseillées (super, je découvre le fonctionnement de la console de débogage : et oui, je pars de loin !!!)
Pourtant, quand je regarde les dossiers en questions, je ne vois pas ce qu'ils ont de particulier : pas de caractères spéciaux, taille pas plus importante que d'autres non problématiques...

J'ai testé sur un autre dossier, en local, j'ai un autre message d'erreur :
"Erreur d'éxecution 70 : permission refusée"
Et cette fois, c'est au niveau du dossier dont le nom est "System Volume Information" (fichier système ? en tout cas, pas visible dans l'explorateur Windows)

Ca fait avancer le smillblick ?
(en tout cas, sur les dossier où ça marche, c'est redoutable et répond à 100% du besoin !)

Sylvain M.

[pgz]

As-tu regardé si le nom d'un sous-dossier qui pose pb peut être lu, comme je te l'ai demandé, si j'ai été clair?
Est-ce que les sous-dossiers qui posent pb ont des noms particulièrement long ?

Si tu modifies le code comme cela

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
For Each oFold In oRep.SubFolders
    i = i + 1
    v(i, 1) = oFold.Name
    On Error Resume next
    v(i, 2) = oFold.Size
    On Error GOTO 0
Next oFold

tu obtiens quoi?

pgz

[clementmarcotte]

Bonjour,

Oui, ça s'arrête toujours sur les mêmes sous dossiers (i=12, i=16) après avoir fait les manip conseillées (super, je découvre le fonctionnement de la console de débogage : et oui, je pars de loin !!!)
Pourtant, quand je regarde les dossiers en questions, je ne vois pas ce qu'ils ont de particulier : pas de caractères spéciaux, taille pas plus importante que d'autres non problématiques...

Il y a quand même une limite sur le nombre de caractères du chemin d'accès. Je ne sais plus si c'est dans les 100 ou les 200 caractères. J'ai même expérimenté des cas (en VB.net et Windows 7) où l'erreur/l'exception "PathTooLongException", qui est supposée être là pour ça, n'était même pas signalée, et que VB se contentait de juste passer au dossier suivant, et sans prévenir.

J'ai testé sur un autre dossier, en local, j'ai un autre message d'erreur :
"Erreur d'éxecution 70 : permission refusée"
Et cette fois, c'est au niveau du dossier dont le nom est "System Volume Information" (fichier système ? en tout cas, pas visible dans l'explorateur Windows)

Sylvain M.

Ça, cela vient des Windows. Dépendant de la version de Windows et/ou du logiciel de gestion du réseau en cause, certains dossiers "sensibles" dans la tête de Microsoft ou des dictateurs du service de dictature informatique peuvent être carrément interdits, même si c'est juste pour lire, d'accès à tout programme. Et c'est bien le cas de System Volume Information.

[SylvainM]

Il y a quand même une limite sur le nombre de caractères du chemin d'accès.

Dans mon cas, ce n'est pas le problème : le script fonctionne sur des chemins beaucoup plus long.
Ceux qui sont problématiques ne dépassent pas la 20aine de caractères.

As-tu regardé si le nom d'un sous-dossier qui pose pb peut être lu, comme je te l'ai demandé, si j'ai été clair?
Est-ce que les sous-dossiers qui posent pb ont des noms particulièrement long ?

Oui, le nom peut être lu : quand je passe la souris dessus, il s'affiche bien :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
oFold="\\serveur\dossier\sousdossierX"
oFold.Size = <Chemin d'accès introuvable>

Je viens de faire les modifs proposées, et le script à tourné sans jamais s'arrêter... (d'ailleurs, quelle est la procédure adaptée dans cette situation pour débloquer Excel ?)
J'en profite pour préciser que je suis sur Excel 2007 (je me rends compte que j'avais oublié de préciser !)

Une idée du problème ?

Sylvain M.

[SylvainM]

[suite]
comme le problème se pose avec l'appel d'oFold.Size, j'ai ajouté "On Error Resume Next" derrière la ligne en question.
Résultat : le script est parvenu à boucler sur tous les dossiers : très long, mais OK pour la plupart des dossiers, sauf 3.
En regardant ces 3 dossiers, je ne vois vraiment pas pourquoi la fonction ne parvient pas à calculer la taille... ???
Des idées ?

Sylvain M.

[pgz]

Bonjour.

De moins en moins !
Si tu cherches les dossiers en question avec l'explorateur, peux-tu lire les propriétés sans pb ?

pgz

[SylvainM]

peux-tu lire les propriétés sans pb ?

Pas de problème particulier :

Rien de différent des autres, à mes yeux en tout cas !?

Sylvain M.

[Marc-L]

Bonjour,

discussion à consulter notamment le post #14, sait-on jamais …




__________________________________________________________________________________________________
Tous unis, tous Charlie

[SylvainM]

Merci Marc-L,

Malheureusement, je n'ai pas le niveau pour en tirer une conclusion :
- partir sur Dir plutôt que FSO ? Je suis en réseau là, ça contredirait "Sinon en réseau je plussoie Robert : préférer FSO !" (dans tous les cas, je ne saurai pas ré-écrire ce code en partant d'une nouvelle bibliothèque...)
- changer l'ordre des instruction ?

Comme j'ai légèrement modifié le code pour l'adapter à mes besoins, voici la partie mise à jour au niveau de la ligne en erreur :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
For Each oFold In oRep.SubFolders
    i = i + 1
    v(i, 1) = oRepPath
    v(i, 2) = oFold.Path
    v(i, 3) = oFold.Size
    On Error Resume Next
    v(i, 4) = DatScan
Next oFold

Merci de te pencher sur mon problème en tout cas !

Sinon, à part ce souci, le Classeur que j'ai créé avec cette fonction me rend déjà énormément service : j'ai créé un tableau croisé+graphique dynamique sur le résultat du Scan, et ça me permet de suivre l'évolution du poids des dossiers de différents emplacements sur le Serveur : très efficace !
(je ne sais pas si ça a un intérêt de le partager ici ?)

Sylvain M.

[Marc-L]

En fait, tout dépend des dossiers scannés.

Le souci, et du reste même en local, certains dossiers peuvent ne pas être accessibles,
réservés au système, verrouillés par une application comme par exemple un anti-virus
et particulièrement en réseau, selon des droits d'accès ou privilèges …

Si avec une gestion d'erreur le souci est réglé, voir avec l'administrateur du réseau pour les trois dossiers restants …

[SylvainM]

Si je peux éviter de faire travailler la maintenance informatique (prestataire) ce serait pas plus mal (en l’occurrence, je ne pense pas qu'ils m'aideront car ils ne font pas de VBA) : j'ai les droits d'administration* sur le serveur, donc j'aimerai bien y arriver tout seul (enfin, avec vous quoi ! )
(* sans en avoir les compétences, car je suis sur de nombreuses missions, informatique parmi d'autres...)

Ce qui est vraiment étrange, c'est que les dossiers en question sont les dossiers "privés" des utilisateurs, et que ceux qui posent souci n'ont aucune différences de droits au niveau de l'Active Directory / ACL.
J'ai 3 utilisateurs sur 30 dont le dossier n'arrive pas à être scanné, alors que leur nom ne dépasse pas 10 caractères, en minuscule et sans accent/caractères spéciaux.

L'idée de mon script, c'est de suivre l'évolution de la taille des dossiers privés pour identifier les problèmes (fréquents) de serveur surchargé parcequ'untel a récupéré la collection de DivX de son collègue (c'est déjà arrivé ! )

Sylvain M.