Discussion :

[Phifou]

Bonjour à tous,

Voilà que je me retrouve avec des tas de données dans un classeur excel, pour chaque colonne j'ai plein de données fournisseurs sous le nom du fournisseur. J'aimerais pouvoir filtrer mes différents fournisseurs selon les données que j'ai, avez-vous une idée pour filtrer dans le sens inverse de l'habituel ?

Je vous remercie,


Philippe

[illight]

J'ai rien compris un ptit exemple ?

[Phifou]

Eh bien, en prenant le tableau en PJ :

La première colonne correspond à mes légendes, les suivantes sont toutes remplies d'information correspondant à chaque fournisseur : comment filtrer par lignes les colonnes : par exemple, je ne veux afficher que les fournisseurs qui ont un mode de transport direct...

Merci d'avance,


Philippe

[illight]

Je sais pas s'il est possible de faire un filtre à "l'horizontal".

bêtement, je te dirais : pourquoi tu fais pas un copier/coller de ton tableau en transposé, pour avoir les titres en haut, et du coup faire un filtre simple ?

[Phifou]

En fait, mon format est figé par des instances supérieurs, mais si je peux filtrer à l'horizontal, ça donnera un plus au produit final.
Dans la pratique je ne devrais pas avoir trop de colonnes, pour des cas où exceptionnellement j'ai 30 colonnes, ça suffit pour devenir un peu compliqué à lire.

Je n'ai vu aucune solution sur internet, mais peut-être qu'il y a un génie sur ce forum qui aura trouver une solution. (ça ne doit pas y être dans 2013 non plus d'ailleurs ?)


Philippe

[AlainTech]

Bonjour,

Le challenge me plaisait.
Voir le classeur joint.
Cliquer sur une des cellules de la colonne A et voir le résultat.
C'est, bien sûr, imparfait. Il n'est pas possible de combiner 2 critères dans cette version mais ça peut être une piste de réflexion.

Voici les codes utilisés.
Dans un module

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Option Explicit
 
Public iLastCol As Integer ' Comme le nombre de colonnes visibles peut varier, on doit stocker la dernière à l'ouverture du classeur

Dans ThisWorkbook

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Option Explicit
 
Private Sub Workbook_Open()
  Dim wks As Worksheet
  Set wks = ThisWorkbook.Sheets("Feuil1") ' A adapter
  With wks
    iLastCol = .Cells(1, .Columns.Count).End(xlToLeft).Column ' Stockage de la dernière colonne renseignée
    ' Attention, le classeur doit être fermé avec toutes les colonnes visibles
    ' Autrement dit, sans aucun filtre
    '  J'ai prévenu que ce code était imparfait. Il sert juste de piste de réflexion
  End With
End Sub

Dans Feuil1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
Option Explicit
 
Private Sub Worksheet_Change(ByVal Target As Range)
  Dim c As Range
  Dim iLastRow As Long
  Dim rRange As Range
  With ActiveSheet ' Comme on travaille sur clic dans la feuille, on peut travailler avec ActiveSheet
    If Not Intersect(.Columns(1), Target) Is Nothing Then ' Si on a modifié une cellule de la colonne A
      Set rRange = Range(.Cells(Target.Row, 3), .Cells(Target.Row, iLastCol)) ' On définit un range des cellules renseignées de la ligne modifiée
      If Target.Value = vbNullString Then
        ' Si la cellule modifiée à été mise à "vide"
        For Each c In rRange
          ' On montre toutes les colonnes
          Columns(c.Column).Hidden = False
        Next c
      Else
        ' On a mis une valeur de filtrage dans une cellule
        For Each c In rRange
          ' Pour chaque cellule (c) de la ligne concernée
          If c.Value = Target.Value Then
            ' Si la valeur de la cellule modifiée (Target) = la valeur de la cellule c
            ' On montre la colonne
            Columns(c.Column).Hidden = False
          Else
            ' Si valeurs différentes, on cache la colonne
            Columns(c.Column).Hidden = True
          End If
        Next c
      End If
    End If
    ' La suite sert à effacer toutes les cellules de la colonne A sauf celle qui vient d'être modifiée
    iLastRow = .Cells(.Rows.Count, 2).End(xlUp).Row
    Set rRange = Range(.Cells(1, 1), .Cells(iLastRow, 1))
    Application.EnableEvents = False ' Indispensable pour éviter de retomber dans l'Event Worksheet_Change
    For Each c In rRange
      If Not c.Row = Target.Row Then
        c.Value = vbNullString
      End If
    Next c
    Application.EnableEvents = True
  End With
End Sub

[illight]

Alors la chapeau

Par contre, j'ai vraiment du mal à comprendre ton code

[AlainTech]

Bonjour,

Commentaires ajoutés dans le code.
Ca te convient?

[illight]

Bonjour,


Oui je comprend un poil mieux, mais je ne vois pas dans ton code où tu "rajoute" les valeurs dans ta liste déroulante.

De plus, autre question : ta liste déroulante, au départ tu l'a renseignée par défaut, ou elle se remplit uniquement lorsque tu cliques sur la cellule ?

Dernière question : je comprend pas pourquoi tu cache les colonnes ?

[AlainTech]

je ne vois pas dans ton code où tu "rajoute" les valeurs dans ta liste déroulante.

Normal, ce n'est pas dans le code.
J'ai créé une zone nommée (voir gestionnaire de noms) par ligne.
Et chaque liste déroulante a comme source la zone nommée de sa ligne.

ta liste déroulante, au départ tu l'a renseignée par défaut, ou elle se remplit uniquement lorsque tu cliques sur la cellule ?

Répondu au dessus.

Dernière question : je comprend pas pourquoi tu cache les colonnes ?

C'était la demande initiale: Filtrer par lignes

[illight]

Je crois que j'ai compris Merci

[Phifou]

Bonjour,

je déterre un peu le sujet, tout d'abord pour dire Merci (tardivement, je l'admets). C'est énorme tout ça.

Je vais essayer de voir ça tranquillement pour en faire un code bien propre et fonctionnel dès que possible.

Un grand merci de ces réponses !!

[papouclo]

Bonjour,
Merci à Alain Gérard pour son code ! (Cela me fera quelque chose à "digérer").
Mais sa remarque prévenant a priori qu'on ne pouvait combiner 2 critères, j'ai essayé d'écrire une autre procédure en partant de la proposition de transposition d'illight .
Le classeur joint comprend 4 feuilles :

• la feuille BD contenant le tableau donné originalement par Phifou (j'ai interverti deux valeurs pour que les critères pays = France d'une part et transport = direct d'autre part
  ne donnent pas le même résultat après filtrage),
• une feuille Critères où l'on peut combiner des critères sur chaque champ avec un bouton lançant la procédure,
• une feuille Intermédiaire masquée,
• une feuille Résultat

.
Des critères de filtre étant choisis, la procédure "nettoie" la feuille Résultat, affiche la feuille Intermédiaire, copie le tableau de la feuille BD et en colle le transposé sur la feuille Intermédiaire,
filtre ce tableau vertical puis copie le tableau filtré et en colle le transposé sur la feuille Résultat.
Le code écrit dans un module comprend deux procédures :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Sub Trihorizontal()
    Application.ScreenUpdating = False
' Affiche la feuille Intermédiaire
    Sheets("Intermédiaire").Visible = True
' Efface la feuille Résultat
    Call Nettoie_Feuille("Résultat")
' Copie la feuille BD
    Sheets("BD").Range("A1").CurrentRegion.Copy
' Colle le tableau transposé sur la feuille Intermédiaire
    Sheets("Intermédiaire").Select
    Range("A1").Select
    Selection.PasteSpecial Paste:=xlPasteAll, Operation:=xlNone, SkipBlanks:= _
        False, Transpose:=True
' Filtre ce tableau et copie le résultat
    Application.CutCopyMode = False
    Selection.AdvancedFilter Action:=xlFilterInPlace, CriteriaRange:=Range _
        ("Critères"), Unique:=False
    Selection.Copy
' Recopie le tableau filtré en le transposant sur la feuille Résultat
    Sheets("Résultat").Select
    Range("A1").Select
    Selection.PasteSpecial Paste:=xlPasteAll, Operation:=xlNone, SkipBlanks:= _
        False, Transpose:=True
' Rétablit le tableau non filtré sur la feuille Intermédiaire,
' l'efface  et la masque
    Sheets("Intermédiaire").Activate
    Range("A1").Select
    Application.CutCopyMode = False
    On Error Resume Next
    ActiveSheet.ShowAllData
    Call Nettoie_Feuille("Intermédiaire")
    Sheets("Intermédiaire").Visible = False
' Affiche la feuille Résultat
    Sheets("Résultat").Select
    Application.ScreenUpdating = True
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub Nettoie_Feuille(Nom_Feuille As String)
    Sheets(Nom_Feuille).Activate
    Range("A1").CurrentRegion.Select
        With Selection
            .ClearContents
            .Borders(xlEdgeLeft).LineStyle = xlNone
            .Borders(xlEdgeTop).LineStyle = xlNone
            .Borders(xlEdgeBottom).LineStyle = xlNone
            .Borders(xlEdgeRight).LineStyle = xlNone
            .Borders(xlInsideVertical).LineStyle = xlNone
            .Borders(xlInsideHorizontal).LineStyle = xlNone
        End With
End Sub

De nombreuses parties du code ont été obtenues directement avec l'enregistreur de macro et à peine modifiées.
Le classeur est enregistré en version 2003 pour ne pas avoir à le compresser.
Cordialement
Claude

[Phifou]

[edit] j'ai pu regarder le travail, c'est splendide. Pour un truc codé comme ça. Whouah !

Est-ce que vous savez s'il est possible de savoir si une colonne est cachée ?

Pour pouvoir faire une sorte de :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
for each column in selection
    if IsHidden(column) = True Then
        'Nothing
    Elseif IsHidden(column) = False then
        Hide Column
    End If

Bon, l'implémentation est très moche, mais c'est simplement pour l'idée, est-ce qu'il existe un truc dans le genre ?