Discussion :

[a.faurie]

bonjour,
je viens d'inscrire un code dans ThisWorkbook :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
    Option Explicit
 
    Private Sub Workbook_Deactivate()
      On Error Resume Next
        With Application
          .CommandBars("Cell").Controls("préparation envoi").Delete
        End With
      On Error GoTo 0
    End Sub
 
    Private Sub Workbook_SheetBeforeRightClick(ByVal Sh As Object, ByVal Target As Range, Cancel As Boolean)
 
      Dim cBut As CommandBarButton
 
      On Error Resume Next
        With Application
          .CommandBars("Cell").Controls("préparation de l'envoi2").Delete
          Set cBut = .CommandBars("Cell").Controls.Add(Temporary:=True)
        End With
 
        With cBut
               .Caption = "préparation de l'envoi2"
               .BeginGroup = True
               .FaceId = 2933 ' n° de l'icone
               .Style = msoButtonIconAndCaption
               .OnAction = "macro"
        End With
      On Error GoTo 0
 
    End Sub

mon problème c'est qu'il marche bien quand je clic sur une cellule bateau mais dès que c'est une cellule de tableau ça ne marche plus.
comment puis-je faire pour que ça marche tout le temps ?

[Invité]

Tu ne travailles plus sur la même 'CommandBars'...

Le code associé pour une 'CommandBars' de type 'List Range Popup' (tableau):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Option Explicit
 
Private Sub Workbook_Deactivate()
  On Error Resume Next
    With Application
      .CommandBars("List Range Popup").Controls("préparation envoi").Delete
    End With
  On Error GoTo 0
End Sub
 
Private Sub Workbook_SheetBeforeRightClick(ByVal Sh As Object, ByVal Target As Range, Cancel As Boolean)
 
  Dim cBut As CommandBarButton
 
  On Error Resume Next
    With Application
      .CommandBars("List Range Popup").Controls("préparation de l'envoi2").Delete
      Set cBut = .CommandBars("List Range Popup").Controls.Add(Temporary:=True)
    End With
 
    With cBut
      .Caption = "préparation de l'envoi2"
      .BeginGroup = True
      .FaceId = 2933 ' n° de l'icone
      .Style = msoButtonIconAndCaption
      .OnAction = "macro"
    End With
  On Error GoTo 0
 
End Sub

[a.faurie]

Merci pour t'as réponse
mais du coup ça me fait l'inverse !
y a pas moyen de le faire sur les 2 ?

[Invité]

Si mais tu aurais pu faire l'effort (c'est juste la combinaison des deux):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Option Explicit
 
Private Sub Workbook_Deactivate()
  On Error Resume Next
    With Application
      .CommandBars("Cell").Controls("préparation envoi").Delete
      .CommandBars("List Range Popup").Controls("préparation envoi").Delete
    End With
  On Error GoTo 0
End Sub
 
Private Sub Workbook_SheetBeforeRightClick(ByVal Sh As Object, ByVal Target As Range, Cancel As Boolean)
 
  Dim strCmb
  Dim cBut As CommandBarButton
 
  On Error Resume Next
    For Each strCmb In Array("Cell", "List Range Popup")
 
      With Application
        .CommandBars(strCmb).Controls("préparation de l'envoi2").Delete
        Set cBut = .CommandBars(strCmb).Controls.Add(Temporary:=True)
      End With
 
      With cBut
        .Caption = "préparation de l'envoi2"
        .BeginGroup = True
        .FaceId = 2933
        .Style = msoButtonIconAndCaption
        .OnAction = "macro"
      End With
 
    Next strCmb
  On Error GoTo 0
 
End Sub

[patricktoulon]

Bonjour vcotinneau

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Private Sub Workbook_Deactivate()
  On Error Resume Next
    With Application
      .CommandBars("Cell").Controls("préparation envoi").Delete
      .CommandBars("List Range Popup").Controls("préparation envoi").Delete
    End With
  On Error GoTo 0
End Sub

a moins qu'il y est plusieur bouton persos dans le menu cell je te suggere de faire plutot

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

 .CommandBars("Cell").reset

en effet si il y a une erreur pour la premiere la deuxieme ne se fait pas non plus

Au plaisir

[a.faurie]

Parfait merci pour vos réponse,
Dsl d'être un boulet mais je début tout juste en VBA et j'ai pas encore capter le principe du coup je tourne les truc dans tous les sens et ça marche que dalle !
en tous cas merci bcp !