Discussion :

[Tiviia]

Bonjour à tous

Je souhaite créer une macro permettant de comparer deux plages (ou colonnes: par exemple A et B) de données.
Je me suis dit qu'il fallait trouver tous les doublons afin de retrouver les éléments uniques de chaque plage.

Quelqu'un aurait une idée à me proposer s'il vous plait?

Cordialement
Tiviia

[Theze]

Bonjour,

Les plages à comparées se trouvent sur la même feuille, dans mon exemple, la feuille est "Feuil1" et les plages sont en colonnes A et B, à adapter. Les cellules en doublons auront le fond en rouge :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
 
Sub Doublons()
 
    Dim PlageA As Range
    Dim PlageB As Range
    Dim Cel As Range
 
    'sur la feuille "Feuil1"
    With Worksheets("Feuil1")
 
        'en colonne A de A1 à Ax
        Set PlageA = .Range(.Cells(1, 1), .Cells(.Rows.Count, 1).End(xlUp))
 
        'en colonne B de B1 à Bx
        Set PlageB = .Range(.Cells(1, 2), .Cells(.Rows.Count, 2).End(xlUp))
 
    End With
 
    For Each Cel In PlageA
 
        'si trouvée au moins une fois, le fond en rouge
        If Application.WorksheetFunction.CountIf(PlageB, Cel.Value) <> 0 Then
 
            Cel.Interior.ColorIndex = 3
 
        End If
 
    Next Cel
 
End Sub

Hervé.

[patricktoulon]

Bonjour

Oui sinon il y a le moyen de le faire en utilisant la librairie des dictionnaires

voila un exemple qui te tri les doublons dans les colonnes a et b
et te les retranscrit dans les colonnes a et b sans doublons bien entendu

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Sub supprime_les_doublons_dans_AetB()
 dim dico1,dico2
 Set dico1 = CreateObject("Scripting.Dictionary")
  Set dico2 = CreateObject("Scripting.Dictionary")
 'on tri les doublons dans la colonne"A"
  For Each c In Range("A1", [A65000].End(xlUp))
    dico1(c.Value) = ""
  Next c
'on tri les doublons dans la colonne "B"
For Each c2 In Range("B1", [B65000].End(xlUp))
    dico2(c2.Value) = ""
  Next c2
 
Columns("a:b").Clear'on efface tout dans les deux colonnes
'on transfert les données des deux dictionnaires dans les colonnes correspondantes
[A1].Resize(dico1.Count, 1) = Application.Transpose(dico1.keys)
[B1].Resize(dico2.Count, 1) = Application.Transpose(dico2.keys)
 
End Sub

Voila
Au plaisir

re
et si tu veux supprimer en meme temps les doublons correspondant a la colonne "A" qui sont dans la colonne "B"
tu change ca :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
 
'on tri les doublons dans la colonne "B"
For Each c2 In Range("B1", [B65000].End(xlUp))
    dico2(c2.Value) = ""
  Next c2

pour ca:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
 
'on tri les doublons dans la colonne "B"
For Each c2 In Range("B1", [B65000].End(xlUp))
 If Not dico1.exists(c2.Value) Then dico2(c2.Value) = ""
  Next c2

ainsi tu n'aura vraiment aucun doublons dans les deux colonnes

voila
Au plaisir

[sophieceuzin]

Bonjour,

Chaque groupe de doublons a une couleur différente.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
Sub DoublonsEntre2Colonnes()
  Set d = CreateObject("Scripting.Dictionary")
  couleurs = Array(3, 4, 6, 7, 8, 15, 17, 20, 22, 24, 26, 27, 28, 33, 34, 35, 36, 37, 38, 39, 40, 42, 43, 44, 45, 46, 50, 53)
  Set plage1 = Range("A2:A" & [a65000].End(xlUp).Row)
  Set plage2 = Range("B2:B" & [b65000].End(xlUp).Row)
  Union(plage1, plage2).Interior.ColorIndex = xlNone
  For Each C In plage1
    d.Item(C.Value) = d.Item(C.Value) & C.Row & "-"
  Next C
  For Each C In plage2
    If d.exists(C.Value) Then
       nocoul = (Application.Match(C.Value, d.keys, 0)) Mod UBound(couleurs)
       C.Interior.ColorIndex = couleurs(nocoul)
       a = Split(d.Item(C.Value), "-")
       For k = LBound(a) To UBound(a) - 1
         tmp = a(k) - plage1.Row + 1
         plage1(tmp).Interior.ColorIndex = couleurs(nocoul)
       Next k
     End If
   Next C
End Sub

Ceuzin

[patricktoulon]

bonjour sophie

quand je regarde ton code je ne vois pas la comparaison pour les doublons de la colonnes2 par rapport a la colonnes 2
c'était un des critères de départ je crois

en effet tu compare la colonne 2 au dico1 mais pas les doublons dans la meme colonnes

tu vois ce que je veux dire ?
Au plaisir

[Tiviia]

Bonjour à tous

Je vous remercie de m'avoir répondu !

J'ai testé toutes vos solutions.

L'idée étais de répertorier tous les doublons afin de voir les éléments qui sont uniques dans les deux listes.

Du coup l'idée de ceuzin est pas mal du tout!
Chaque doublons à sa couleur !

Question: comment automatiquement extraire les couples de doublons et les insérer dans des colonnes à cotés (C et D par exemples) ?

Merci pour vos réponses !

Cdt

Tiviia

Re

Le code de ceuzin ne fonctionne pas lorsqu'il y a beaucoup de données dans les colonnes ..