Discussion :

[Caroline1]

Bonjour,

Je déclare une variable frm de type Form. Je boucle sur la collection Forms et pour chaque frm ouvert, j'appelle une fonction setLangue(frm as Form). Selon la fenêtre espion, frm est bien initialisé à un formulaire. J'obtiens une erreur 13 Incompatibilité de type dont je n'arrive pas à m'expliquer.

Quand je copie le code de setLangue directement dans setLangueAll, j'obtiens ce à quoi je m'attends.

Je ne vois pas où regarder d'autres pour trouver ce qui est incompatible. Des idées?

Merci.
Caroline

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Private Sub setLangueAll()
Dim frm As Form
 
    'Changement des libellés-variables des modules standards
    setLangueBas
 
    'Changement des libellés de tous les formulaires ouverts
    For Each frm In Forms
        If frm.HasModule Then setLangue (frm) 'ERREUR 13 ICI
    Next
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Public Sub setLangue(frm As Form)
 
    'Changement des libellés du formulaire
    'Activation de la gestion d'erreur pour les formulaires n'ayant pas de fonction publique "Francais" ou "Anglais"
    On Error Resume Next
        Select Case m_LangueAffichage
            Case cFrancais
                frm.Francais
            Case cAnglais
                frm.Anglais
        End Select
    On Error GoTo 0
 
End Sub

[pgz]

Bonsoir,

Je ne suis pas sûr qu'on puisse passer ce genre d'objet en argument. Tu pourais essayer de passer plutôt le nom du form.
du style

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Private Sub setLangueAll() 
Dim frm As Form 
 
    'Changement des libellés-variables des modules standards 
    setLangueBas 
 
    'Changement des libellés de tous les formulaires ouverts 
    For Each frm In Forms 
        If frm.HasModule Then setLangue (frm.name) 
    Next 
End Sub
 
 
Public Sub setLangue(fname As String) 
 
    'Changement des libellés du formulaire 
    'Activation de la gestion d'erreur pour les formulaires n'ayant pas de fonction publique "Francais" ou "Anglais" 
dim frm as form
set form = Forms(fname)
    On Error Resume Next 
        Select Case m_LangueAffichage 
            Case cFrancais 
                frm.Francais 
            Case cAnglais 
                frm.Anglais 
        End Select 
 
End Sub

Pour voir,

Bon courage,

pgz[/code]

[Caroline1]

Passer un string à la place devrait marcher, oui.

Pourtant, j'utilise "setLangue Me" à l'ouverture de chaque formulaire multilingue et ça fonctionne très bien. Si c'était un problème de form en argument qu'Access n'aime pas, ça planterait aussi.

EDIT : Ça fonctionne effectivement. C'est mieux que de recopier la fonction! Par contre, je ne comprends toujours pas pourquoi mon SetLangue(frm as Form) fonctionnait quand on l'appelait d'un form_Open avec SetLangue(me) et pas à partir de la boucle For Each frm in Forms...

[=JBO=]

Bonjour Caroline,

Je pense que le Pb se situe au niveau du passage de paramètre à la procédure setLangue.

Il s'agit d'une procédure Sub, qui n'a pas besoin de parenthèses autour des paramètres.
Ou bien, il faut utiliser la syntaxe d'appel:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Call <nom procédure Sub> (<arg1>,...<arg n>)

Dans ton cas, les parenthèses sont interprétées comme une expression à évaluer pour obtenir le paramètre qui sera finalement passé à la procédure.
Et VBA ne sait pas évaluer une expression comme (<object>).

Alors choisis...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
If frm.HasModule Then setLangue frm
 
OU
 
If frm.HasModule Then Call setLangue(frm)

Quant à la solution de passer en paramètre le nom de l'objet, proposée par pgz, elle ne me convient pas trop car j'utilise fréquemment de multiples instances du même formulaire... et du coup le nom du formulaire n'est plus discriminant.

[cafeine]

Hello,

on peut parfaitement passer en argument, un objet / collection / variant / form / controle ... ce qui atteste que le problème se situe ailleurs.

je pense que le post de JBO est une bonne piste.

[Tofalu]

Comme cafeine, je pense que JBO a mis le doigt là où il fallait.

Faut quand même avouer que le passage d'argument à une sub est un peu tordu en VB6.

Tant qu'on est dans la manipulation de objets, je vais donner deux petites astuces.

L'utilisation de IS. Is permet de vérifier si deux variables resence le même objet. Exemple dans ton cas pour éviter le formulaire courant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
    For Each frm In Forms 
        If frm.HasModule And Not (frm Is Me) Then setLangue (frm.name) 
    Next

Si frm représente le même objet que Me alors la condition est vrai. Not ... est donc faux, on ne passe pas dans le IF.

L'utilisation de Set

En VB on peut déclarer les objets de deux façon :

Imaginons, une classe nommé clToto possédant une méthode mamethode.

Je peux déclarer ainsi :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Dim obj as new clToto
obj.mamethode

ou bien

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Dim obj as clToto
Set obj= New clToto
obj.mamethode

Pourtant, il existe une différence fondamentale entre les deux syntaxe. En Visual Basic, dés qu'une méthode est appelée, une vérification interne est réalisée. Celle ci consiste à vérifier que l'objet a été instancié avant l'appel. Le mot clé SET permet d'outrepasser cette vérification et de dire explicitement au système que l'objet a été instancié. Ainsi, on gagne de nombreuses vérifications internes qui auraient dûes être effectuées à chaque fois que l'objet aurait été référencé. La syntaxe 2 consomme donc une ligne de code de plus mais est beaucoup plus performante

[Caroline1]

Je pense que le Pb se situe au niveau du passage de paramètre à la procédure setLangue.

Il s'agit d'une procédure Sub, qui n'a pas besoin de parenthèses autour des paramètres.

Arf... Pile dessus! Je suis déjà tombé sur ce "problème" en utilisant msgbox. Jamais pensé à ça avec setLangue.

J'ai tout remis comme le premier code et j'ai enlevé les parenthèses. Je trouve bien plus "élégant" de passer l'objet. Pour l'instant, je n'ai pas plusieurs instances du même formulaire mais ça pourrait arriver.

Merci JBO!

[...]And Not (frm Is Me)

C'est vrai que ça aurait pu poser problème mais là, la fonction est définie dans un module.

L'utilisation de Set [...] La syntaxe 2 consomme donc une ligne de code de plus mais est beaucoup plus performante Wink

Merci pour l'information! C'est bon à savoir.

Caroline