Pb fichier Excel

**jj37fr** · 30/08/2012, 11h47

Bonjour

Trois jours de galère, je relance la question...

Une macro VBA Word qui manipule (qui veut manipuler !) Excel.

Elle fonctionne une fois puis chaque fois suivante elle déclenche une erreur 1024. même si je change de fichier (Test1.xlsx vers Test2.xlsx).

Il faut fermer l'application Word pour que la macro fonctionne à nouveau une seule fois !

Si quelqu'un pense à une piste ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
 
    Dim XlApp As Object
    Dim XlBook As Object
    Dim Sheet1 As Object
    Dim Sheet2 As Object
    Dim DernLig As Integer
    Dim Msg As String
 
    Set XlApp = CreateObject("Excel.Application")
    Set XlBook = XlApp.Workbooks.Open("D:\Test1.xlsx")
    Set Sheet1 = XlBook.Worksheets(1)
    Set Sheet2 = XlBook.Worksheets(2)
 
    XlApp.Visible = True
    On Error Resume Next
 
    DernLig = Sheet2.Range("G65536").End(xlUp).Row
 
    Sheet1.Select
    XlBook.Sheets(1).Range(Cells(1, 1), Cells(5, 3)). _
        Font.Italic = True
 
    If Err.Number <> 0 Then
        Msg = "Erreur : " & Str(Err.Number) & "générée par " _
            & Err.Source & Chr(13) & Err.Description
        MsgBox Msg, , "Erreur", Err.HelpFile, Err.HelpContext
        Err.Clear
    End If
 
    XlBook.Close
    XlApp.Quit
    Set XlApp = Nothing
    Set Sheet1 = Nothing

Cordialement
Jean-Jacques

**Daniel.C** · 30/08/2012, 13h34

Bonjour,

Sur quelle ligne as-tu l'erreur ?

**jj37fr** · 30/08/2012, 14h26

Bonjour

J'ai un peu progressé car avec la gestion de l'erreur, il suffit de fermer le document Word pour recommencer. Avant, il fallait relancer la machine !

Cela voudrait, aussi, dire que mon traitement de l'erreur n'est pas satisfaisant !

J'ai enfin pu cerner l'erreur... et elle apparait sur

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Sheet2.Range(Cells(2, 1)).Value = "I"

alors que, par exemple,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
 Sheet2.Range("F1:F2690").Value = "M"

fonctionne de même que les Copier/Coller du type

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Sheet1.Columns(1).Copy Destination:=Sheet2.Cells(1, 11)

Il semble donc que "Cells" n'est pas accepté avec Value ou... !

Je souhaite remplir, par exemple, la colonne "F" de 1 à "DernLig" avec "M"
Ici "DernLig = 2690", mais cela varie !

J-J

**gFZT82** · 30/08/2012, 14h59

Bonjour,

Je souhaite remplir, par exemple, la colonne "F" de 1 à "DernLig" avec "M"

Essaie avec

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheet2.range("F1:F" & DernLig)="M"

Tu ne peux pas écrire

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheet2.Range(Cells(2, 1)).Value = "I"

Pour affecter la valeur “I” à la cellule A2, tu dois écrire

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheet2. Cells(2, 1)).Value = "I"

ou

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheet2.Range(“A2”).Value = "I"

Cordialement.

**jj37fr** · 31/08/2012, 12h13

Bonjour

Merci...
La ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Sheet2.range("F1:F" & DernLig)="M"

Fonctionne parfaitement.

Deux questions

1) Comment faire la même chose que ci-dessus avec "Cells" ?
2) Y a-t-il une faute dans la gestion de mon erreur qui expliquerait que je puisse pas relancer ? C'est comme si le fichier restait ouvert !

**Didier Gonard** · 31/08/2012, 13h24

Bonjour,

Envoyé par jj37fr

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheet2.range("F1:F" & DernLig)="M"

1) Comment faire la même chose que ci-dessus avec "Cells" ?

l'écriture équivalente est :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Range(Cells(1, 6), Cells(DernLig, 6)) = "M"

Cordialement,

Ps : si le côté technique de la réponse = OK ou pas => pensez à cliquer sur les pouces et quand question résolue à la taguer résolue, et chaque action vous rapporte des points

Didier

**jj37fr** · 31/08/2012, 14h12

Bonjour

Où l'on retombe sur le problème.
Si je rajoute :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Sheet2.Range(Cells(1, 6), Cells(DernLig, 6)) = "M"

en lieu et place de

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Sheet2.Range("F1:F" & DernLig).Value = "M"

Cela fonctionne une fois ! J'ouvre D:\Test1.xlsx ; j'efface la feuille 2 ; je relance ; j'obtiens une erreur 1004 "La méthode 'Cells' de l'objet '_Global' a échoué"

Étrange ! Non !

J-J

**Didier Gonard** · 31/08/2012, 14h32

Bonjour,

dans ton code du début, tu as ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set Sheet1 = Nothing

as-tu aussi un

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set Sheet2 = Nothing

et idem pour les autres instanciations de variables objet ?

Cordialement,

Ps : si le côté technique de la réponse = OK ou pas => pensez à cliquer sur les pouces et quand question résolue à la taguer résolue, et chaque action vous rapporte des points

Didier

**Didier Gonard** · 31/08/2012, 16h21

Bonjour,

J'ai (enfin) regardé ton 1er code de près, il est très brouillon, ce qui est tout à fait compréhensible selon ton niveau / VBA, mais qui forcément t'amèneras à ce genre de galère sur des projets qui ne sont plus basiques.

par exemple, pourquoi utilises-tu cette écriture :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

XlBook.Sheets(1).Range(Cells(1, 1), Cells(5, 3)).Font.Italic = True

alors que tu as instancié une variable objet qui pointe justement sur la feuille1 ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

 Set Sheet1 = XlBook.Worksheets(1)

C'est pas-propre et très dangereux car de plus tu utilises Sheets(1) et non plus Worksheets(1) qui, si tu as le malheur d'avoir une feuille de Graph en 1ère position pointera sur celle-ci et plantera (ouf, ça évitera des mélanges) à l'invocation de cellules qu'elle ne possède pas...

Donc, ton soucis vient, je pense, d'une confusion du VBA, à un moment donné, entre les objets Range d'Excel et de Word et entre la propriété Cells d'Excel et la collection Cells de Word ceux-ci n'ayant rien à voir les uns avec les autres....
(c'est pourquoi j'avais flashé sur la non destruction d'un pointeur sur mon post précédent)
Bref, on gagne toujours à être explicite dans les codes

Test le code ci-dessous, vois l'aide VBA sur les mots clefs et surtout les tutoriels dispos sur DVP à ces sujets !

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Option Explicit
Sub GOGO() 'dans Word
''demande à référencer la librairie Excel dans Outils-Références
 
Dim XlApp As Excel.Application 'Ne pas travailler en auto-instanciation, mais ainsi
Dim XlBook As Workbook  ''travailler en liaison anticipées / early binding
Dim Sheet1 As Worksheet ''travailler en liaison anticipées / early binding
'''Dim MaPlage as Excel.Range ' Si j'instanciai une variable objet pour la plage cible, elle serait typée ainsi...
Dim Msg As String
 
Set XlApp = New Excel.Application 'Ne pas travailler en auto-instanciation, mais ainsi
XlApp.Visible = True
Set XlBook = XlApp.Workbooks.Open(Chemin voulu) 'chemin + classeur à définir
Set Sheet1 = XlBook.Worksheets(1)
 
With Sheet1
    .Select 'inutile et ralentissant si pas voulu, la feuille n'a pas besoin d'être active pour écrire dessus...
    .Range(.Cells(1, 1), .Cells(5, 3)).Value = "DG" 'explicite ! 
    ''' équivalent à l'écriture : Sheet1.Range(Sheet1.Cells(1, 1), Sheet1.Cells(5, 3)).Value = "DG" si pas de With...
End With
 
If Err.Number <> 0 Then
    Msg = "Erreur : " & Str(Err.Number) & "générée par " & Err.Source & Chr(13) & Err.Description
    MsgBox Msg, , "Erreur", Err.HelpFile, Err.HelpContext
Err.Clear
End If
' penser à gérer la sauvegarde des modifs avant de fermer / quitter
Set Sheet1 = Nothing
XlApp.Quit
Set XlApp = Nothing
 
End Sub

Cordialement,

Ps : si le côté technique de la réponse = OK ou pas => pensez à cliquer sur les pouces et quand question résolue à la taguer résolue, et chaque action vous rapporte des points

Didier

**jj37fr** · 31/08/2012, 17h24

Bonsoir

Merci pour ce mini cours...

J'ai essayé cela... aussi... à un moment... mais difficile de trouver la bonne version avec tout ce qui traîne sur la toile.

Je vais reprendre mon code (qui fonctionne pour l'instant) dans ce sens !

Pour abuser - un peu - je souhaite (toujours à partir de Word) sauvegarder ma feuille 2 en .csv, séparé par des virgules !!!
As-tu une idée ?
J'imagine qu'après XlBook.Save, je dois, peut-être faire un Sheet2. save avec un Destination:= ... ????

Je ne trouve pas grand chose sur ce sujet !

J-J

**Didier Gonard** · 31/08/2012, 17h47

Bonjour,

Pour ça il faut lire :

Les règles :http://club.developpez.com/regles/

Un sujet par fil

cordialement,

Didier

Pb fichier Excel

Macros et VBA Excel

Discussions similaires

Partager

Partager