Discussion :

[ip203]

Bonjour,

Mon titre est un peu flou mais le manque de place le justifie. Voici ma question, j'ai dans un formulaire une longue liste de zone de texte groupées par 3 sur 15 lignes. En fait on demande le sexe, l'age et un code pour chaque personne (jusqu'à 15 au max). Mon formulaire commence par rendre tous les controles Enabled = False sauf le premier.
Le GotFocus du premier entrainant Enabled = True du deuxième etc...
Arrivé à ma zone des Controles texte je fais ce code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
max = (Me.Nbr_total_pers.Value + 1) * 6
 
    For i = 14 To max Step 2
        strControl = "Texte" & i
        Me.Controls(strControl).Enabled = True
        strControl = ""
    Next i

Qui fonctionne parfaitement. Ce que j'aimerai faire maintenant c'est quand l'utilisateur fait un GotFocus sur le dernier controle rendu accessible (Me.Controls(Texte56)) par exemple, je puisse faire tourner du code. Le problème c'est que je ne sais pas:

- Parametrer cet évènement, puisque le nom de ce controle est une variable et je ne sais pas si on peut fabriquer une Sub avec comme nom le nom d'une variable:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

 private Sub Me.Controls(maVar)_GotFocus()

Cela me parait un peu tiré par les cheveux, non ?!

Merci de vos conseils

[=JBO=]

Bonjour,

Si tu ne veux absolument pas créer une procédure événementielle pour chacun de tes contrôles, alors tu peux créer une procédure de type Function qui utilisera le contrôle actif (Me.ActiveControl), dans le module de code de ton form ou dans un module de code général.
Et pour chaque événement ciblé des contrôles concernés, tu renseignes la propriété avec une expression qui commence par le signe égal (sinon Access recherche une Macro).

Exemple de fonction dans le module du Form:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
Private Function MaFonctionEvent()
    MsgBox "Contrôle actif: " & Me.ActiveControl.Name
End Function

Exemple de fonction (la même) dans un module de code général:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
Public Function MaFonctionEvent()
    MsgBox "Contrôle actif: " & Screen.ActiveControl.Name
End Function

Exemple d'expression à utiliser:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MaFonctionEvent()

[...] je ne sais pas si on peut fabriquer une Sub avec comme nom le nom d'une variable:

VBA ne sait pas faire ça

[ip203]

Bonjour,

Ca m'a l'air pas mal. Je vais essayer ca ce week end...Je te tiens au jus

@+++

Merci pour tes conseils

[cafeine]

Hello,

il y a aussi ce type de méthode

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Option Explicit
 
Private Sub Form_Load()
    Dim ctl As Control
 
    For Each ctl In Me.Controls
        If ctl.ControlType = acCommandButton Then
            ctl.Properties("onclick") = "=GotAClick('" & ctl.name & "')"
        End If
    Next ctl
 
    Set ctl = Nothing
 
End Sub
 
Private Function GotAClick(ByVal NomCmd As String)
    MsgBox ("l'utilisateur a cliqué sur le bouton : " & NomCmd)
End Function

[cafeine]

[...] je ne sais pas si on peut fabriquer une Sub avec comme nom le nom d'une variable:

VBA ne sait pas faire ça

Sinon, on peut malgré tout faire ça en VBA ... grâce à Eval() qui d'ailleurs n'existe pas dans VB 6

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Function Getit01(var)
    Getit01 = var + 1
End Function
 
Function Getit02(var)
    Getit02 = var * 2
End Function
 
Sub TestEval()
    Dim i As Integer
    Dim maVar
 
    maVar = 100
    For i = 1 To 2
        Debug.Print Eval("Getit" & Format(i, "00") & "(""" & maVar & """)")
    Next i
End Sub

[ip203]

Salut,

Bon et bien avec tout cela j'ai à manger pour tout le week end !!!
Je vais décortiquer ca et à Lundi...

Merci