Discussion :

[ESVBA]

Bonjour,

j'ai des listes déroulantes contenant de longs textes.

Je souhaiterais que par le survol de la souris sur une ligne, on puisse afficher l'intégralité du texte dans une étiquette sans cliquer dessus (sans perdre la sélection actuelle). Un "controlTips" en fonction du survol par le curseur de la souris de la zone de liste.

Je ne retrouve pas le code.

Merci pour vos indices.

ESVBA

[mercatog]

Une alternative
à côté de ta listbox tu crée un label Label1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Private Sub UserForm_Initialize()
Me.ListBox1.RowSource = "Feuil1!A1:A20" 'initialisation de la listbox
With Me.Label1                          'Mise en forme du label prix comme info bulle
    .Caption = ""
    .BackColor = &H80000018
    .Visible = False
End With
End Sub
 
Private Sub ListBox1_MouseMove(ByVal Button As Integer, ByVal Shift As Integer, ByVal X As Single, ByVal Y As Single)
Dim i As Integer
Dim msg As String
With Me.ListBox1
    i = (Y - 1) \ (.Font.Size + 1) + .TopIndex
    If i <= .ListCount - 1 Then msg = .List(i)
    If X * Y <= 10 Or Y >= .Height - 5 Or X >= .Width - 15 Then msg = vbNullString
End With
With Me.Label1
    .Visible = Len(msg) > 0
    .Top = Me.ListBox1.Top + Y
    .Caption = msg
End With
End Sub

[ESVBA]

Pour des indices, ça ressemble à une solution.

Merci.
Je pensais à quelque chose de plus complexe.
Je teste ça.

ESVBA

[ESVBA]

j'ai un problème lorsqu'il y a une dizaine de lignes dans la "listbox".

Il se produit un décalage, j'obtiens la ligne du dessous dans le "label1".

Après divers essais, je constate :

• La taille de la police définie dans VBE pour la "listbox" est de "8".
• La taille indiquée par ".Font.size" est de "8,25".
• Le "Y" varie de "0,75" par déplacement mimimal sur l'écran.
• La variation de "Y" est de "9,75" pour une ligne de la listbox.
• Et (vérifié) de "10,5" pour sauter à la ligne d'après (9.75+0.75).
• Il y a une "ligne vide de pixel entre chaque item" ou plus.
• Le changement de taille et de police ne changent rien. Sauf mauvais choix.

Je suis perdu pour relier toutes ces données. Je ne vois pas comment faire ?

ESVBA

[Arkham46]

bjr

on peut utiliser les fonctions d'accessibilité

si j'extrais du module clAccessibility ce qui nous intéresse pour que le code soit moins lourd, cela se résume à ce module :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
 
Option Explicit
 
Private Declare Function AccessibleObjectFromPoint Lib "oleacc" (ByVal lX As Long, ByVal lY As Long, ppacc As IAccessible, pvarChild As Variant) As Long
Private Declare Function GetCursorPos Lib "user32.dll" (lpPoint As PointAPI) As Long
Private Type PointAPI
    X As Long
    Y As Long
End Type
 
Public Function GetListIndexUnderMouse() As Long
Dim lPt As PointAPI
Dim lChild As Variant
GetCursorPos lPt
AccessibleObjectFromPoint lPt.X, lPt.Y, Nothing, lChild
GetListIndexUnderMouse = CLng(lChild) - 1
End Function

il suffit d'appeler GetListIndexUnderMouse sur souris déplacée sur la liste pour avoir l'index de la ligne survolée

Remarque : j'ai testé avec Excel 2003

[Arkham46]

une autre version, avec une API en moins, cette fois-ci je suis sur Excel 2007
je n'ai pas expliqué cette méthode dans l'article mais on peut passer par un objet IAccessible pour utiliser les fonctions d'accessibilité acc* des contrôles

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
 
Option Explicit
 
Private Declare Function GetCursorPos Lib "user32.dll" (lpPoint As PointAPI) As Long
Private Type PointAPI
    X As Long
    Y As Long
End Type
 
Public Function GetListIndexUnderMouse(pObject As IAccessible) As Long
Dim lPt As PointAPI
Dim lChild As Variant
GetCursorPos lPt
lChild = pObject.accHitTest(lPt.X, lPt.Y)
GetListIndexUnderMouse = CLng(lChild) -1
End Function

[ESVBA]

Je n'arrive pas à faire fonctionner les deux bouts de code donnés même en lisant le tutoriel.

"accole.dll" est installé par défaut. Ca ne fonctionne pas.
J'ai installé la version "accesibility" proposé (lien mort). Le programme d'installation me dit que c'est déjà installé pour winXP.

J'ai installé la dernière version pour Win7. Pareil.

Rien à faire j'ai toujours des problèmes.

En voici un sous Excel 2007 :

membre de méthode ou de données introuvable.

avec arrêt sur ".accHitTest".



"accHitTest" est absent de la liste des propriétés/évènements du membre "ListBox" et "ListBoxes".

Quelle est mon erreur ?

[Arkham46]

Rien à faire j'ai toujours des problèmes.

En voici un sous Excel 2007 :

avec arrêt sur ".accHitTest".

tu passes bien par un objet IAccessible comme dans mon code juste au dessus?
(pour que IAccessible soit reconnu, il y a une référence à ajouter "Microsoft Office XX Object Library")

[ESVBA]

il y a des fois...

J'ai refait un fichier excel et ça fonctionne avec les deux codes sous 2007 !
(Microsoft Office 12 Object Library est coché par défaut, j'ai vérifié avec les fichiers antérieurs).

Pourquoi alors ? Aucune raison. J'étais aussi parti d'un fichier vide.

Enfin, ca fonctionne très très bien. Pose du .

Merci Arkham46.

ESVBA