Discussion :

[Marlan]

Bonjour à vous,

Je suis tout nouveau inscrit sur le forum, et je viens déjà vous poser une question...

Comment créer une routine dans un code source en fortran 90 qui permettrait de supprimer des fichiers?

Exemple: dans mon programme actuel, je créé un paquet de fichiers (environ 50k) temporaires.

Je souhaiterai qu'à la fin du programme, ces derniers soient écrasés. (nota: je ne peux pas employer le status 'scratch' car ces fichiers sont fermés puis réutilisés plus tard dans le programme)

Merci d'avance,

Marlan

[Ladgalen]

Bonjour et bienvenue !

Tu peux utiliser la commande system qui te permet d'exécuter des commandes systèmes. Suivant ton système d'exploitation ces commandes seront différentes.

Sous linux tu peux faire :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
call system("rm mon_fichier")

La subroutine system prend comme argument une chaine de caractère, donc tu peux mettre le nom de fichier dans une variable si tu veux :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
character(len=100) :: fichier
call system("rm "//fichier )

Attention, juste une précaution d'emplois, system n'est pas dans la norme fortran. Ceci dis la majorité des compilateurs l'acceptent.

[Sylvain Bergeron]

Solution alternative toute Fortran : Tu peux utiliser la clause status='delete' de la commande close.

Si le fichier est déjà ouvert, il est alors très simple de fermer les fichiers par close(unit=22, status='delete').

Si le fichier n'est pas déjà ouvert, tu peux utiliser quelque chose comme :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
 
module FilesModule
   implicit none
contains
 
   subroutine FileDelete(Name,iostat)
      character(*),      intent(in)  :: Name
      integer, optional, intent(out) :: iostat
 
      integer i
      logical Used
 
      i = 100
      Used = .true.
      do while(Used)
         i = i - 1
         inquire(unit=i, opened=Used)
      enddo
      if (present(iostat)) then
         open(Unit=i, file=Name, status='old', iostat=iostat)
         if (iostat /= 0) return
         close(Unit=i,status='delete', iostat=iostat)
      else
         open(Unit=i, file=Name, status='old')
         close(Unit=i,status='delete')
      endif
      end subroutine
 
end module
 
program Test
   use FilesModule
   implicit none
   integer k
   call FileDelete('test.txt')
   write(0,*) 'OK'
   call FileDelete('test2.txt',iostat=k)
   write(0,*) 'iostat=',k
   call FileDelete('test2.txt',iostat=k)
   write(0,*) 'iostat=',k   
   end program

[Marlan]

Oki merci beaucoup, c'est parfait.