Discussion :

[uuubuuu]

Bonjour à tous,

Je sais faire une validation sur une plage continue (toutes les cellules de B1 à B4):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Range("A1").Validation.Add _
Type:=xlValidateList, AlertStyle:=xlValidAlertStop, _
Formula1:="=" & Range("B1:B4").Address

Ca me crée une validation (liste déroulante) dans la cellule A1. Tout va bien.

Mais j'aimerais faire quelque chose du genre :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Range("A1").Validation.Add _
Type:=xlValidateList, AlertStyle:=xlValidAlertStop, _
Formula1:="=" & Union(Range("C1"), Range("C2"), Range("C4")).Address

C'est-à-dire mettre dans la liste déroulante des cellules se trouvant à différents endroits dans un tableau.

Existe-t-il un moyen d'arriver à mes fins ?

Merci mille fois d'avance !

Jerem

[rvtoulon]

Slt,
j'ai lu qu'on ne pouvait utiliser d'union dans une liste de validation.

une solution consiste à utiliser une colonne dont tu n'as pas besoin de faire un lien dans cette colonne avec les cellules qui t'intéresse afin de les regrouper et de faire ta liste de validation et de masquer la colonne.

c'est pas top mais en tout cas ça marche

[aalex_38]

j'ai lu qu'on ne pouvait utiliser d'union dans une liste de validation

C'est d'ailleurs le message qui apparait si on tente de le faire manuellement :

"vous ne devez pas utiliser les unions,intersections, ni les constantes matricielles pour les critères de validation des données"

[Didier Gonard]

Bonjour,

Mets un String

Tu "Union" les plages voulues et tu donnes à la Range obtenue un nom, par exemple strMaString, ensuite, tu appliques ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub ValidOk()
Dim strMaString As String
Dim cell As Range
 
Range("A1").Clear
For Each cell In Range("AllZone")
   strMaString = strMaString & "," & cell.Value
Next cell
Range("A1").Validation.Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:=xlBetween, Formula1:=strMaString
End Sub

rajout :

Ce code est bien meilleur si on n'a pas le besoin d'une plage nommée au par ailleurs...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub ValidOk()
Dim strMaString As String
Dim objPlagesCibles As Range
Dim cell As Range
 
Set objPlagesCibles = Union(Range("B1:B4"), Range("C6:C9"))
 
Range("A1").Clear
For Each cell In objPlagesCibles
   strMaString = strMaString & "," & cell.Value
Next cell
Range("A1").Validation.Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:=xlBetween, Formula1:=strMaString
End Sub

Attention Danger : vois ici des fois que...


cordialement,

Didier