Discussion :

[cedana]

Bonjour à tous.
Voici mon problème. Dans la feuil1 et dans la plage D230 je saisis un code sous forme de lettre : B, C, D, E, G, PR, STD, mais je souhaite appliquer un code couleur à chacune de ces lettres et de maniére automatique. Avec la mise en forme conditionnelle je suis limité à 3 conditions ,alors il me faut une autre solution. Je compte sur votre aide pour régler ce problème.
En colonne G dans la plage G2:G8 je calcule le nombre de lettres identiques qui se trouvent en D230 avec la formule NB.SI
Merci d'avance pour votre aide.

[rjamin]

Bonjour,
Voyez sur le site ci-dessous dans la rubrique Mise en forme conditionnelle puis cherchez Plus de 3 conditions.

http://boisgontierj.free.fr/


Bon travail

[Gorfael]

Salut cedana et le forum
Il y a toujours la solution d'acheter Office 2007
Sinon, on peut faire une pseudo Mise en Forme Conditionnelle. Mais ce sera une macro, donc le fond devient réellement de la couleur fixée :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Private Sub Worksheet_Change(ByVal Target As Range)
Dim Cel As Range, Plage As Range
Set Plage = Intersect(Target, [D2:D30])
If Plage Is Nothing Then Exit Sub
For Each Cel In Plage
    Select Case Cel
        Case "B"
            Cel.Interior.ColorIndex = 3
        Case "C"
            Cel.Interior.ColorIndex = 4
        Case "D"
            Cel.Interior.ColorIndex = 5
        Case "E"
            Cel.Interior.ColorIndex = 6
        Case "G"
            Cel.Interior.ColorIndex = 7
        Case "PR"
            Cel.Interior.ColorIndex = 8
        Case "STD"
            Cel.Interior.ColorIndex = 9
        Case Else
            Cel.Interior.ColorIndex = xlNone
    End Select
Next Cel
End Sub

Comme je ne connais pas les couleurs désirées, je les ai fixées au hazard.
Si tu ne t'y connais pas en macro :
Clic-droit sur le nom de l'onglet => Menu contextuel>>Visualiser le code
Et tu colles la macro, après tu essaies.
Attention : Seules les valeurs Données seront prises en compte. Ainsi B coloriera la cellule, mais pas b.
A+

[cedana]

Bonjour à tous.

Merci à Rjamin pour m'avoir fait visiter un site très intéressant, merci à Gorfael pour sa macro. J'ai simplement changé Cel.Interior.ColorIndex par Cel.Font.ColorIndex pour la couleur des lettres et ça marche.
Merci beaucoup.