Discussion :

[Daniela]

Bonjour a tous, moi j'ai un feuille excel avec 5 colonnes : id, cod_struct, num_prog, nom, prenom

moi je voudrais creer une macro qui me permet de calculer pour chaque cod_struct les valeurs enregistrees.

ex:
id, cod_struct, num_prog, nom, prenom
1, 7200, 42, prest, forbon
2, 7200, 55, karim, degost
3, 1420, 25, fred, vorren


le resultat:

cod_strut valeur
7200 2
1420 1


comment je peux faire?

[Jean-Philippe André]

salut,
je suppose que la "valeur enregistrée" en question correspond au nombre de lignes...

Tu peux faire ca sans code avec

=NB.SI()

ou par code VBA avec une boucle

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
dim cpt As Integer
cpt = 0
For i = 1 To Range("A65536").End(Xlup).Row
If ... Then
cpt = cpt+1
End If
Next i

[Daniela]

en utilisant nb.si dans la premiere case je selection la colonne avec les valeurs mais dans le critere comment je fais pour lui dire de calculer les valeurs?

[Pierre Fauconnier]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=nb.si(plage;critère)

=>

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=nb.si($a$1:$a$10;7200

Si tu le souhaites par VBA

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

worksheetfunction.countif(...)

[Daniela]

oui ça j'avais compris, mais moi je voudrais le faire pour tous les valeurs et pas une a la fois. en vba c'est possibile d'ecrir le cod de la structure et à coté combien il y en a?

[Pierre Fauconnier]

Je comprends que tu veuilles le faire par VBA...

Mais j'insiste quand même...

Un tableau croisé dynamique ne ferait-il pas l'affaire?

Sinon, en VBA, il faut:
- extraire les valeurs sans doublons
- créer la formule qui va bien
- copier coller la formule, par exemple, à droite de la liste des valeurs créées.

S'il y a beaucoup de lignes, le traitement sera +/- long, contre un quasi instantané par TCD...

[Daniela]

no il y a pas assez de valeurs, 1337 et on 20 structure differentes.

[Pierre Fauconnier]

Pas compris... Tu veux en VBA ou tu veux en TCD?

P.S.: Inutile de reprendre le message précédent en citation. Merci

[Daniela]

en vba, je pense que c'est mieux. mais j'arrive pas a faire la macro.

[ikoria]

Bonjour.
En gros tu compte ne nombre d'occurrence...

Dans ce cas, tu peux faire des boucles SOMME.SI( ) avec NBVAL().

En gros:
Pour chaque valeur CODE STRUC,
tu crées un tableau
dans lequel tu enregistre l'id par exemple
Ensuite tu compte le nombre d'élément du tableau
tu écrit ta valeur quelque par
Et tu passe au Code STRUC suivant

Autre chose, via la commande "FORMULA" tu peux enregistrer des formules dans des cellules et avoir le résultat (faire des macro avec commande excel)

[mercatog]

Une proposition:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Option Explicit
 
Public Sub SYNTH()
Dim sht1 As Worksheet, sht2 As Worksheet
Dim Struc As Collection
Dim cel As Range
Dim LastLig As Long, i As Long
 
Set sht1 = Sheets("Data") 'A ADAPTER
Set sht2 = Sheets("Synth") 'A ADAPTER
 
With sht1
    LastLig = .Range("B65536").End(xlUp).Row 'A ADAPTER
    MsgBox LastLig
    Set Struc = New Collection
    On Error Resume Next
    For Each cel In .Range("B2:B" & LastLig)  'cod_struct dans colonne B de la feuille Data
        If cel <> "" Then Struc.Add cel, CStr(cel)
    Next cel
    On Error GoTo 0
End With
 
With sht2
    For i = 1 To Struc.Count
        .Range("A" & i + 1).Value = Struc.Item(i)
        .Range("B" & i + 1).Value = Application.CountIf(sht1.Range("B2:B" & LastLig), .Range("A" & i + 1).Value)
    Next i
End With
Set Struc = Nothing
Set sht1 = Nothing
Set sht2 = Nothing
End Sub

Mais un TCD est fait pour ça; pourquoi chercher à faire en vba?

[Daniela]

c'est quoi un TCD?

[Jean-Philippe André]

salut,
il s'agit d'un tableau croisé dynamique

[laetitia]

bonjour le fil le forum comme je comprends ???
donnees en colonne b . résultat en colonne G. en colonne H le nombre de fois a adapter.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Option Explicit
Dim c As Variant, m As Object
Sub es()
Application.ScreenUpdating = False
Set m = CreateObject("Scripting.Dictionary")
For Each c In Range("b2", [b65000].End(xlUp))
m(c.Value) = IIf(m.exists(c.Value), m(c.Value) + 1, 1)
Next c
[g2].Resize(m.Count, 1) = Application.Transpose(m.keys)
[h2].Resize(m.Count, 1) = Application.Transpose(m.items)
End Sub

idem bisous a toi daniela

[Daniela]

les macros que vous m'avez fourni marchent tres bien, je les ai adapté a mon travail. merci merci merci bisous