Discussion :

[JLDpilot]

Bonjour à tous

Avec le code ci-après j'importe dans une listbox les fichiers trouvés dans un répertoire et qui répondent à certains critères. Comment puis-je obtenir un tri alphabétique des fichiers apparaissant ainsi dans la listbox ?

Merci de votre aide

JLDpilot

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
'-----------------------------------------------
Private Sub UserForm_Initialize()
 
Application.ScreenUpdating = False
    'intègre dans les listes déroulantes tous les fichiers Excel situés dans le répertoire "Mes Documents"
monChemin = Application.DefaultFilePath
 
    Frame1.Caption = monChemin
    Set fs = CreateObject("Scripting.FileSystemObject")
    Set f = fs.GetFolder(monChemin)
 
    Set fc = f.Files
    For Each f1 In fc
        If Left(f1.Name, 7) = "EAS 04-" _
          And f1.Type = "Feuille de calcul Microsoft Excel" And Len(f1.Name) > 13 Then
 
        CboFiles.AddItem f1.Name
 
        End If
    Next
 
    CboFiles.ListIndex = 0
    CboFiles.SetFocus
    Application.SendKeys ("{F4}")
 
Set fs = Nothing
Set f = Nothing
Set fc = Nothing
Application.ScreenUpdating = True
End Sub

[Invité]

Bonjour,

Je crois que la solution la plus simple est d'affecter vos noms de fichiers dans une plage de cellules, de trier cette plage et d'affecter ensuite à votre ComboBox.

[JLDpilot]

Merci. j'avais également pensé à cette manip. Mais il n'y aurait donc pas de commande "en direct" ?

[ucfoutu]

Bonjour,

pourquoi ne pas utiliser plus simplement une ListView, qui, elle :
- a une propriété Sorted
- te permet d'afficher les dates de tes fichiers
- te permet d'afficher leur taille
- te permet même de trier par date (avec une colonne cachée supplémentaire)
etc...
Ce serait quand-même beaucoup plus propre !

Je crois même qu'il m'est arrivé de donner un exemple sur ce forum (pas sûr) et sans utiliser FSO, en plus !

[SilkyRoad]

bonjour


Tu peux stocker les fichiers dans un tableau, y appliquer un tri et alimenter la listbox ensuite ( propriété List() ).

Un exemple qui tri par date de création:
Comment lister les fichiers d'un répertoire par ordre décroissant de date de création ?



Par listView comme proposé par ucfoutu:

http://silkyroad.developpez.com/VBA/ListView/#LII-I
"exemple liste les fichiers d'un répertoire ainsi que certaines de leurs propriétés."

ftp://ftp-developpez.com/silkyroad/f...tViewExcel.zip



bonne journée
michel

[JLDpilot]

Merci ucfoutu mais j'avoue que je suis largué !
comment une listview ? sans FSO ????

Ici j'utilise une combobox pour permettre à l'utilisateur d'y rechercher un fichier particulier. La liste pouvant être longue j'aurai souhaiter que ces fichiers soient classés par ordre alpha !

Désolé mais je ne possède pas ton niveau pour comprendre ces abréviations.

Merci pour l'éclairage

Jean-Luc

[JLDpilot]

Ma dernière réponse s'est en fait croisée avec celle de Michel !
Je me suis donc inspiré du premier lien qu'il m'a indiqué et obtenu la création d'un tableau (enfin je pense si j'en juge par le contenu de l'espion express !).
Ce tableau ne reprend en fait que le nom du fichier (seule info qui m'intéresse)

Mais maintenant je coince
1) sur la façon d'en trier le contenu par ordre alpha puis
2) sur la méthode pour l'incorporer à ma combobox afin que l'utilisateur puisse faire sa sélection unique avant de valider la boîte de dialogue - userform (Michel parle de List !!!!!!!).

Enfin je suis content de l'exemple de Michel qui m'a fait avancer mais reste encore un bout de chemin !!!!!

Merci de votre aide
Jean-Luc

[SilkyRoad]

Rebonjour


Une adaption avec une listBox :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
Option Explicit
Option Compare Text
Option Base 1
 
Private Sub CommandButton1_Click()
    Dim Fichier As String, Chemin As String
    Dim Tableau()
    Dim m As Integer, i As Integer
    Dim Valeur As Byte
    Dim Cible As String
 
    '---liste les fichiers du répertoire ---
    Chemin = "C:\Documents and Settings\mimi\dossier"
    Fichier = Dir(Chemin & "\*.*")
    'pour filtrer sur un type de fichiers (par exemple xls)
    'Fichier = Dir(Chemin & "\*.xls")
 
    'Boucle sur les fichiers
    Do
        m = m + 1
        ReDim Preserve Tableau(m)
        Tableau(m) = Fichier
 
        Fichier = Dir
    Loop Until Fichier = ""
 
 
    '---Trie les fichiers par ordre alphabétique ---
    Do
        Valeur = 0
        For i = 1 To m - 1
            If Tableau(i) > Tableau(i + 1) Then
                Cible = Tableau(i)
                Tableau(i) = Tableau(i + 1)
                Tableau(i + 1) = Cible
 
                Valeur = 1
            End If
        Next i
    Loop While Valeur = 1
 
 
    '--- Transfère les données dans la ListBox ---
    ListBox1.List() = Tableau()
 
End Sub

bon après midi
michel

[JLDpilot]

Merci Michel ça marche super !

Jean-luc

Bonne fin de journée en France ...