Discussion :

[Ex-floodeur]

Bonsoir,

je souhaite exporter le résultat d'une requete SQL dans un fichier excel précis. En d'autres termes, je souhaite exporter le résultat de la requete A dans la feuille "Datas" du fichier excel "Report.xls".

J'ai vu vos "cours" ici : http://access.developpez.com/faq/?page=Excel#PilotExcel mais je n'arrive pas à saisir comme faire exactement.

Pourriez-vous m'aider ?

Merci de votre aide,

[LedZeppII]

Bonsoir et bienvenue sur le forum,

cette méthode me paraît plus approprié (DoCmd.TransferSpreadsheet) : Comment exporter le résultat d'une requête sous Excel ?

Exemple :

Code vb :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub ExportDansXL()
Dim strTableOuRequette As String
Dim strXLFile As String, strFeuille As String
 
' Nom de la table ou de la requête
strTableOuRequette = "Marequete"
' Nom completdu fichier excel
strXLFile = "C:\Mes Documents\Reports.xls"
' Nom de la feuille excel
strFeuille = "Data"
 
'Supprimer fichier avant export
If Dir(strXLFile) <> "" Then Kill strXLFile
 
' Exporter en excel (9 (OFF2000) dans cet exemple)
DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel9, strTableOuRequette, _
           strXLFile, True, strFeuille
End Sub

Ensuite tu peux manipuler le fichier excel comme dans le lien que tu as cité.
Un autre exemple:

Code vb :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Sub MiseEnFormeFichierExcel()
Dim xlWbk As Excel.Workbook, xlSheet As Excel.Worksheet
Dim strXLFile As String, strFeuille As String
' Nom du fichier Excel
strXLFile = "C:\Mes Documents\Reports.xls"
' Nom de la feuille
strFeuille = "Data"
' Ouvre classeur
Set xlWbk = GetObject(strXLFile)
' On s'assure qu'il est visible
xlWbk.Windows(1).Visible = True
' référence la feuille
Set xlSheet = xlWbk.Worksheets(strFeuille)
' ajustement automatique largeur colonnes
xlSheet.Columns.AutoFit
' active cellule A2
xlSheet.Range("A2").Select
'ou autre méthode
'xlSheet.Cells(2, 1).Select
' fige les volets
xlWbk.Windows(1).FreezePanes = True
' sauve le classeur
xlWbk.Save
' libère objet feuille excel
Set xlSheet = Nothing
' Ferme classe
xlWbk.Close
' libère objet classeur
Set xlWbk = Nothing
End Sub

A+