Discussion :

[yoann_deygas]

Bonjour a tous

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub importDonnees_DAO()
    Dim Db As DAO.Database
    Dim Rs As DAO.Recordset
    Dim strSQL As String
 
    Set Db = DAO.OpenDatabase("C:\dossier\base de tarif.mbd", False, False)
    strSQL = "SELECT * FROM [Tarif] WHERE [Reçu Le ] BETWEEN #01/01/06# AND #31/12/07#"
    Set Rs = Db.OpenRecordset(strSQL, DAO.dbOpenSnapshot)
 
    Range("A1").CopyFromRecordset Rs
 
    Db.Close
End Sub

le code ci-dessus me permet de recuperer lesdonnées d'une base de données access et de les copier dans exel. Le seul problème est que cette routine me renvoie uniquement les différentes valeurs des champs et pas le nom du champ :

exemple :

Cela va me donner

21/12/06
21/09/07

et moi j'aimerais

Reçu le (nom du champ)
21/12/06
21/09/07

Merci par avance pour votre aide

[SilkyRoad]

bonsoir

Tu peux adapter la procédure ainsi

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub importDonnees_DAO()
    Dim Db As DAO.Database
    Dim Rs As DAO.Recordset
    Dim strSQL As String
    Dim i As Integer
 
    Set Db = DAO.OpenDatabase("C:\dossier\base de tarif.mbd", False, False)
    strSQL = "SELECT * FROM [Table1] WHERE [Reçu Le ] BETWEEN #01/01/06# AND #31/12/07#"
    Set Rs = Db.OpenRecordset(strSQL, DAO.dbOpenSnapshot)
 
    For i = 0 To Rs.Fields.Count - 1
    Cells(1, i + 1) = Rs.Fields(i).Name
    Next i
 
    Range("A2").CopyFromRecordset Rs
 
    Db.Close
End Sub

bonne soirée
michel