[Débutant] Fonction qui retourne un objet (classe)

in · 30/08/2007, 13h59

Bonjour,

c'est sûrement une question bête mais je coince vraiment ...

J'ai un module de classe "Project".
J'ai un module où j'ai défini une fonction qui doit me retourner ( ~créer) un objet Project.

Voici la fonction :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
' renvoie un objet projet créé à partir des données contenues à la ligne line
' de la feuille sheet (interface_p3e normalement)
Public Function getProject(sheet As Worksheet, line As Integer) As Project
 
    Dim projet As New Project
 
    ' initialisation des membres d'un objet project
 
    With sheet
        projet.Prog = .Cells(line, 16)
        projet.Proj = .Cells(line, 2)
        projet.Init_id = .Cells(line, 14)
        projet.Last_id = .Cells(line, 15)
        projet.OBS = .Cells(line, 12)
    End With
    ' jusqu'à la en débug, tous les champs de l'objet sont correctement initialisés (enfin il y a des valeurs quoi)
 
    ' renvoie le project  --> c'est la que ça coince
    getProject = projet
 
End Function

Quand je l'exécute, au moment de retourner la valeur il me dit :

"Variable objet ou bloc with non définie" (sur le getProject quand je passe la souris dessus)

C'est pas possible ce que je veux faire ?

Merci d'avance pour vos suggestions.

**tirex28** · 30/08/2007, 14h21

Bonjour,

Si la fonction doit retourner un objet alors il faut utiliser le mot-clé Set.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
Public Function getProject(sheet As Worksheet, line As Integer) As Project
 
    Dim projet As New Project
 
    Set getProject = projet
 
End Function

Cordialment,

Tirex28/

in · 30/08/2007, 14h25

J'avais essayé le Set mais pas au bon endroit ...

Merci en tous cas, je me disais bien que c'était faisable ...

in · 30/08/2007, 14h54

Euh, j'ai un petit souci du même ordre, donc je reprends ce sujet ...

j'ai une autre classe Scope avec :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
' la liste des projets
Private liste_projets As New Collection
 
Public Sub addProject(ByRef p As Project)
    liste_projets.Add (p)
End Sub

Dans un module je souhaite ajouter un Projet à au Scope en faisant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
scope.addProject (getProject(ActiveSheet, index))

(scope est préalablement créé)

J'obtiens l'erreur : propriété ou méthode non gérée par cet objet

Désolé je suis peut être trop habituer à la prog objet mais là avec VBA je m'arrache les cheveux ...

**tirex28** · 30/08/2007, 15h20

Re,

Tu peux nous joindre un exemple de ton fichier ?

Cordialement,

Tirex28/

in · 30/08/2007, 15h33

Ben pas vraiment.

Le code important de Scope vous l'avez.
Le code de la méthode getProject vous l'avez.

Voici un morceau de la classe Project :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private lProg As String 
Private lProj As String 
Private lOBS  As String                 
Private lInit_id As Long              
Private lLast_id As Long         
Private lIsProjectMR As Boolean          
Private lInit_typed_WBS As New Collection  'non initialisé lors du getProject
Private lLast_typed_WBS As New Collection 'non initialisé lors du getProject 
 
' suivent les getter/setter associés

Et là le morceau du module qui utilise tous ces trucs :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Global scope As New scope   'Scope du reporting (liste des projets)
 
Public Sub P3E_Init_Dashboard_update()
 
    Dim index As Integer
 
   '...
 
    index = index + 1
 
    ' on récupère la liste des projets (baselines) définis dans le scope, si la liste est vide
    ' pour construire la collection de projet (nécessaire si on a pas utilisé le check baseline)
    If scope.nbProjects = 0 Then
        With Worksheets(Feuille_Interface)
            Do Until .Cells(index, 1).Interior.ColorIndex = Colors.rouge Or .Cells(index, 2) = ""
                scope.addProject (getProject(ActiveSheet, index))  'ERREUR !!
                index = index + 1
            Loop
        End With
    End If
'...

et voilà, c'est tout ce qu'il faut je pense ...

**tirex28** · 30/08/2007, 16h22

Re,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Global scope As New scope

Global je connaissais pas...

Par contre il faudrait peut etre eviter de nommer ta variable comme ta classe.

Sinon essaye ceci, j'ai simplifie mais tu devrais pouvoir adapter.

Dans le module scope:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
Private liste_projets As Collection
 
Property Get ListeProjet() As Collection
    Set ListeProjet = liste_projets
End Property
 
Private Sub Class_Initialize()
    Set liste_projets = New Collection
End Sub

Dans le module project:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
Private Const K_Exemple As String = "exemple"
 
Property Get Exemple() As String
    Exemple = K_Exemple
End Property

Dans un module standard:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
Sub AjouterProjet()
    Dim myscope As New scope
    myscope.ListeProjet.Add getProject
    MsgBox myscope.ListeProjet(1).Exemple
End Sub
 
Public Function getProject() As project
    Dim projet As New project
    Set getProject = projet
End Function

AjouterProjet ajoute un element de type project a la collection listeprojet de myscope.

Bonne chance,
Tirex28/

in · 30/08/2007, 16h35

Effectivement en donnant un accesseur à la liste des projets du scope, je peux ajouter un projet.

Donc ça marche. Merci beaucoup.

Par contre pourquoi ma méthode addProject ne fonctionne pas ???

**tirex28** · 31/08/2007, 03h12

Bonsoir,

Apres avoir mieux regardé il ne s'agissait que d'un probleme de syntaxe, des parentheses en trop.

Dans un module standard:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
Sub AjouterProjet()
    Dim myscope As New scope
    myscope.addProject getProject 'getProject n'est pas entre parentheses
    MsgBox myscope.liste_projets.Item(1).Exemple
End Sub
 
Public Function getProject() As project
    Dim projet As New project
    Set getProject = projet
End Function

Dans le module scope:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
Public liste_projets As New Collection
 
Public Sub addProject(ByRef p As project)
    liste_projets.Add p 'Le p n'est pas entre parentheses
End Sub

Dans le module project:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
Private Const K_Exemple As String = "exemple"
 
Property Get Exemple() As String
    Exemple = K_Exemple
End Property

Cordialement,

Tirex28/

in · 31/08/2007, 09h32

Effectivement c'était bien ça ...

Mais alors je suis un peu perdu ... des fois j'utilise des fonctions avec des paranthèses et ça marche très bien. D'ailleurs quand je mets la paranthèse, l'éditeur de code m'affiche la liste des paramètres ... enfin je veux dire, ça me parait normal de mettre les paranthèses ...

Bref, est ce qu'il y a une règle ?

En tous cas merci bien. Je débute en vba et je ne crois pas qu'on sera super amis lui et moi ...

A+ et merci encore

[Débutant] Fonction qui retourne un objet (classe)

Macros et VBA Excel

Discussions similaires

Partager

Partager