Discussion :

[miko91]

Bonjour,

J'ai une application qui tournent sur 200 sites et qui contient un bug dans le code source. J'aimerai modifier ce bug sur le poste client avec une autre application VBA.

En claire : chez le client, l'application (fichier XLS) contient données et programme VBA.

Pour modifier le workbook, sheets, couleurs, formules .... pas de problème de le faire via une application annexe.

Pour modifier le code source, là je n'arrive pas.

La seule solution a été de faire une moulinette qui contient un exemplaire du programme client, puis qui recupere les données dans la moulinette, supprime la feuille d'accueil moulinette, et l'enregistre sous le format application.


J'ai besoin de trouver le moyen de modifier directement le code programme dans une application.

[kiki29]

A adapter à ton contexte

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
 
Option Explicit
 
'======================================================================================
'   Cocher Outils | Reférence Microsoft Visual Basic for Applications Extensibility 5.3
'======================================================================================
 
'   Détruit Macro nommée Essai dans module nommé ModuleA de ThisWorkbook
Sub DelMacro()
Dim Debut As Long
Dim NbLignes As Long
Dim VBCodeMod As CodeModule
On Error GoTo Erreurs
 
    Set VBCodeMod = ThisWorkbook.VBProject.VBComponents("ModuleA").CodeModule
    With VBCodeMod
        Debut = .ProcStartLine("Essai", vbext_pk_Proc)
        NbLignes = .ProcCountLines("Essai", vbext_pk_Proc)
        .DeleteLines Debut, NbLignes
    End With
    Exit Sub
Erreurs:
    Debug.Print Err.Number & " " & Err.Description
End Sub
 
'   Crée la Macro nommée Essai dans module nommé ModuleA dans ThisWorkbook
Sub CreerMacro()
Dim VBCodeMod As CodeModule
Dim x As Long
 
    Set VBCodeMod = ThisWorkbook.VBProject.VBComponents("ModuleA").CodeModule
    With VBCodeMod
        x = .CountOfLines + 1
        .InsertLines x, ""
        .InsertLines x + 1, "Sub Essai()"
        .InsertLines x + 2, "      Msgbox ""Nouvelle Procedure"""
        .InsertLines x + 3, "End Sub"
    End With
End Sub
 
'   Alternative
'   Crée la Macro nommée Essai dans module nommé ModuleA de ThisWorkbook
Sub CreerMacro2()
Dim VBCodeMod As CodeModule
Dim x As Long, str As String
    str = ""
    Set VBCodeMod = ThisWorkbook.VBProject.VBComponents("ModuleA").CodeModule
    With VBCodeMod
        str = "Sub Essai()" & vbCrLf
        str = str & "      Msgbox ""Nouvelle Procedure""" & vbCrLf
        str = str & "End Sub" & vbCrLf
        x = .CountOfLines + 1
        .InsertLines x, str
    End With
End Sub

[miko91]

Suuuuuuperbe !!!!

J'ai essayé ça marche,



Merci Kiki29.