Discussion :

[chamus]

Salut a tous,

G un dossier contenant trente classeurs.
dans chacun de ces classeurs, se trouve sur la première feuille un tableau recapitulatif

mon but serait de réunir sur une feuille d un nouveau classeur,
tous les tableaux récapitulatif figurant sur la premieres feuille de chacun de mes 30 classeurs.

les tableaux récapitulatif en question ont toujours les memes coordonnées sur la premiere Feuille

Quelqu un a une idée, conseil, code ?

[SilkyRoad]

bonjour

j'espere que cet exemple pourra t'aider

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
Sub CompilationClasseurs()
Dim Repertoire As String, Fichier As String
Dim Wb As Workbook
Dim Ws As Worksheet
Dim x As Integer
 
Repertoire = "C:\Documents and Settings\mimi\dossier"
 
'Fige l'écran pendant l'opération
Application.ScreenUpdating = False
 
Fichier = Dir(Repertoire & "\*.xls")
'Boucle sur les classeurs du répertoire
Do While Fichier <> ""
    'ouverture des classeurs
    Set Wb = Workbooks.Open(Repertoire & "\" & Fichier)
    'Spécifie la 1ere feuille du classeur
    Set Ws = Wb.Sheets(1)
    Ws.Range("A1:E17").Copy
 
    'Recherche la 1ere ligne vide dans la 1ere feuille
    'contenant cette macro. (pour indiquer l'emplacement
    'du collage)
    x = ThisWorkbook.Sheets(1).Range("A65536").End(xlUp).Row + 1
 
    'collage
    ThisWorkbook.Sheets(1).Cells(x, 1).PasteSpecial
    'Désactive le mode Copier/Couper
    Application.CutCopyMode = False
 
    'Ferme le classeur
    Wb.Close False
 
    Fichier = Dir
Loop
 
Application.ScreenUpdating = True
MsgBox "Opération terminée."
End Sub

Sinon il est aussi possible de récupérer les données sans ouvrir les classeurs.

http://silkyroad.developpez.com/VBA/ClasseursFermes/



bon après midi
michel

[chamus]

Magnifique !

tu m a fait gagné 1 journée de boulot !