Discussion :

[retraite83]

Bonjour,

mon titre n'est peut être pas très parlant mais voilà (d'après mes recherches on ne peut pas faire)

dans mes modules j'ai souvent besoin d'accèder au dossier parent, je le fais comme ceci dans chaque module

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
twb as String
twb = Left(ThisWorkbook.Path, InStrRev(ThisWorkbook.Path, "\") - 1)

Plutôt que définir dans chaque module je voudrai déclarer "twb" en "Public" dans le module qui contient mes constantes "Public"

Le fait que ce ne soit pas une constante me semble impossible

[joe.levrai]

Bonjour,

tu peux créer une variable publique de type String, et lui affecter le chemin du dossier dans la procédure Workbook_Open()

[mromain]

Bonjour à tous,

Une autre solution consiste à rajouter le code suivant dans le module ThisWorkbook :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Public Property Get ParentFolder() As String
Static sPath As String
    If sPath Like vbNullString Then sPath = Left(Me.Path, InStrRev(Me.Path, "\") - 1)
    ParentFolder = sPath
End Property

Ainsi, tu peux accéder à cette information dans ton projet via ThisWorkbook.ParentFolder.

A+

[retraite83]

Merci à tous

#2 me semble plus simple

Je n'avais pas pensé à cette soluion

[retraite83]

Après tests cela fonctionne très bien

Merci

[Philippe Tulliez]

Bonjour,
Personnellement, je ne suis pas partisan de l'usage de variable publique. Je privilégie, l'usage d'une fonction générique

Exemple d'une fonction qui renvoie le dossier parent du classeur passé par argument (si l'argument est vide, c'est ThisWorkbook (a remplacer éventuellement par AciveWorkbook)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Function GetFolderParent(Optional oWorkbook As Workbook)
  If oWorkbook Is Nothing Then Set oWorkbook = ThisWorkbook
  GetFolderParent = Left(oWorkbook.Path, InStrRev(oWorkbook.Path, "\") - 1)
End Function

Exemple d'une procédure qui l'invoque

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub TestGetFolderParent()
  Dim twb As String
  twb = GetFolderParent()
  Debug.Print twb
End Sub

[Thumb down]

Bonjour,
ThisWorkbook.Path est bien plus pertinent qu'une variables public.
Ce code est absurde ThisWorkbook.Path n'a jamais de "\"

Code absurde :

Sélectionner tout - Visualiser dans une fenêtre à part

Left(ThisWorkbook.Path, InStrRev(ThisWorkbook.pth & "\")

[retraite83]

#6

Je pensai justement que l'utilisation de variables publique étaient faites pour être "Publique" et donc éviter de les définir dans chaque module

Je vais tester la fonction générique

#8

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
twb = Left(ThisWorkbook.Path, InStrRev(ThisWorkbook.path & "\")

Ce code est absurde...

Malgré votre grande expertise il ne faut pas juger. Dans mon cas le / est utile pour atteindre directement tous mes classeurs dans le dossier parent :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
ThisWorkbook.path &  "\" & nomfichier.xlsm

est juste remplacé par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
twb  & nomfichier.xlsm

[Godzestla]

Bonjour,
ThisWorkbook.Path est bien plus pertinent qu'une variables public.
Ce code est absurde ThisWorkbook.Path n'a jamais de ""

Code absurde :

Sélectionner tout - Visualiser dans une fenêtre à part

Left(ThisWorkbook.Path, InStrRev(ThisWorkbook.pth & "\")

Je ne vois pas ce qu'il y a d'absurde à ce code, au contraire.
Si on se donne la peine de le comprendre, et de le recopier juste, il est parfait.

un exemple : Si Thisworkbook.path = C:\Data\IT, il renvoie c:\data\

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Left(ThisWorkbook.Path, InStrRev(ThisWorkbook.path, "\"))

Bonne journée.

[Thumb down]

ThisWorkbook.Path ce n'est pas une définition c'est une variable publique
ThisWorkbook.Path et twb c'est la même chose sauf qu'ils faut définir ta variable et l'initialiser alors que ThisWorkbook.Path est initialiser par défaut a l'ouverture du fichier.

C'est à mon sans inutile de décaler en public, ou en privé dans toutes tes méthodes une variable twb alors que tu disposes en native ThisWorkbook.Path qui tout compte fait fait la même chose.

ThisWorkbook veut dire le classeur qui exécute la macro tu trouveras rien de mieux pour connaître les informations de ce classeur.

[deedolith]

Hello,

Petite correction:
ThisWorkbook est une fonction, qui renvoie une référence vers le classeur contenant le code, ce n'est donc pas une variable.

Ensuite, concernant les chemins, plutôt que se faire chier à gérer manuellement l'antislash de fin, la bibliothèque FSO prend cela en charge (le l'antislash soit présent ou non).
FSO est également capable de construire des chemins, toujours en prenant en charge la presence / absence d'antislash.
Exemples:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Option Explicit
 
Sub test()
    Dim Fso As Scripting.FileSystemObject
    Set Fso = CreateObject("Scripting.FileSystemObject")
 
    Dim ParentFolder As Scripting.Folder
 
    Const Path1 As String = "C:\Projects\Gimp"
    Set ParentFolder = Fso.GetFolder(Path1).ParentFolder
    Debug.Print ParentFolder.Path       '// affiche c:\Projects
 
    Const Path2 As String = "C:\Projects\Gimp\"
    Set ParentFolder = Fso.GetFolder(Path1).ParentFolder
    Debug.Print ParentFolder.Path       '// affiche c:\Projects
 
 
    Dim Path As String
    Path = Fso.BuildPath("C:\Projects", "something.dat")
    Debug.Print Path    '// Affiche C:\Projects\something.dat
 
    Path = Fso.BuildPath("C:\Projects\", "something.dat")
    Debug.Print Path    '// Affiche C:\Projects\something.dat
End Sub

[Thumb down]

Bonjour,
Je confirme c'est absurde.

Maintenant donnes moi ton avis ThisWorkbook.Path retour un \ à la fin ?


right(ThisWorkbook.Path,1)

[deedolith]

D'autant que, toujours grâce à la bibliothèque magique FSO, obtenir le chemin du dossier parent est trivial:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Public Function GetParentFolderPath(ByVal Path As String) As String
    Debug.Assert Path <> vbNullString   '// pas obligatoire mais souhaitable
 
    Dim FSO As Object    '// Scripting.FileSystemObject
    Set FSO = CreateObject("Scripting.FileSystemObject")
 
    Dim Folder As Object    '// Scripting.Folder
    Set Folder = FSO.GetFolder(Path)
    Debug.Assert Not Folder.IsRootFolder    '// pas obligatoire mais souhaitable
 
    GetParentFolderPath = Folder.ParentFolder.Path
End Function

[Thumb down]

Bonjour,
Oui je confirme, si l'idée est de retourner le premier partent on utilisera un outil capable de gérer les fichiers et les répertoires plutôt que d'analyser le chemin de l'arborescence.
ThisWorkbook.Path="\\serveur"