Discussion :

[gdmeunier]

Bonjour,
J'ai un code qui me permet de supprimer des lignes dans un tableau de mise à jour avant de coller ce qui reste dans la base général Excel. Voir ci-dessous.
Ce code supprime uniquement la ligne si la colonne T est = 0 ou vide (mais parfois, il peut y avoir des données dans d'autres colonnes U, V, etc.). Je veux le modifier pour qu'il supprime la ligne uniquement si les colonnes T, U, V, W, X, Y, Z AA et AB remplissent les mêmes conditions, toutes ensembles. En clair, sir une seule cellule est remplie dans ces colonnes la ligne n'est pas supprimée.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
Sub FCMC1C2_SuppressionLigne()
'Suppression des lignes vides (toutes ensemble)
Dim i As Long
  Sheets("FCMC1C2_Data").Select
  Range("Ta_FCMC1C2_Data").Select
  Dim rPlageASupprimer As Range
For i = Selection.Cells(Selection.Cells.Count).Row _
To Selection.Cells(1).Row Step -1
   If Cells(i, "T").Value = 0 Or _
      IsEmpty(Cells(i, "T").Value) Then
      If rPlageASupprimer Is Nothing Then
     Set rPlageASupprimer = Rows(i).Resize(1, Range("Ta_FCMC1C2_Data").ListObject.DataBodyRange.Columns.Count)
      Else
     Set rPlageASupprimer = Union(rPlageASupprimer, Rows(i).Resize(1, Range("Ta_FCMC1C2_Data").ListObject.DataBodyRange.Columns.Count))
      End If
      End If
Next i
'rPlageASupprimer.Select
 
rPlageASupprimer.Delete
End Sub

C'est au dessus de mon niveau!
Merci d'avance!
GDM.

[Nain porte koi]

Hello

je propose

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub FCMC1C2_SuppressionLigne()
'Suppression des lignes vides (toutes ensemble)
Dim i As Long
Sheets("FCMC1C2_Data").Select
Range("Ta_FCMC1C2_Data").Select
Dim rPlageASupprimer As Range

For i = Selection.Cells(Selection.Cells.Count).Row To Selection.Cells(1).Row Step -1
    If WorksheetFunction.Sum(Range(Cells(i, "T"), Cells(i, "AB"))) = 0 Then
        If rPlageASupprimer Is Nothing Then
            Set rPlageASupprimer = Rows(i).Resize(1, Range("Ta_FCMC1C2_Data").ListObject.DataBodyRange.Columns.Count)
        Else
            Set rPlageASupprimer = Union(rPlageASupprimer, Rows(i).Resize(1, Range("Ta_FCMC1C2_Data").ListObject.DataBodyRange.Columns.Count))
        End If
    End If
Next i
'rPlageASupprimer.Select

rPlageASupprimer.Delete
End Sub

[Franc]

Bonjour, moi j'utiliserais plutôt:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If Application.CountA(Range(Cells(i, "T"), Cells(i, "AB"))) = 0

En effet, par un coup de malchance extraordinaire, .sum pourrait retourner 0 alors qu'il y a des valeurs dans les cellules qui s'additionnent et donnent 0.
Alors que countA compte le nombre de cellules non vides.

[Nain porte koi]

Alors que countA compte le nombre de cellules non vides.

Bien vu, merci pour la correction

[gdmeunier]

Merci à tous pour les propositions de code. Je vais appliquer et confirmer.
GDM

[Philippe Tulliez]

Bonjour,
COUNTA ne peut pas non plus répondre à sa demande puisque si je lis bien "Ce code supprime uniquement la ligne si la colonne T est = 0 ou vide".
Pour moi la question n'est pas suffisamment précise. Que peuvent contenir les cellules de T à AB ? si ce ne sont que des nombres et la condition est de supprimer si ces cellules contiennent une valeur nulle ou rien la fonction SUM est bien la bonne réponse.

De plus, il semble que les données se trouvent dans un tableau structuré donc il n'y a aucune raison de sélectionner la feuille. Range("Nomdutableau") est suffisant

[EDIT]
Si la condition de suppression des lignes du tableau est bien que les cellules de T à AB soient nulles ou vides, voici une autre proposition

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub T()
  Const TableName As String = "t_Data"
  Dim t As ListObject
  Dim sumRange As Range
  Dim fx As WorksheetFunction
  Dim r As Long
  Set t = Range(TableName).ListObject
  Set fx = Application.WorksheetFunction
  ' Itérer à travers les lignes du tableau de bas en haut
  For r = t.ListRows.Count To 1 Step -1
    ' Définir la plage à sommer (colonnes 19 à 27 du tableau)
    Set sumRange = t.ListRows(r).Range(, 19).Resize(, 9)
    ' Supprimer la ligne si la somme est égale à 0
    If fx.Sum(sumRange) = 0 Then t.ListRows(r).Delete
  Next r
  Set fx = Nothing: Set sumRange = Nothing: Set t = Nothing
End Sub

[gdmeunier]

Merci à tous,
J'ai appliqué la première solution (Nan) car il ne peut pas y avoir de nombre négatif (risque de Sum = 0) et ça marche! Je garde en réserve la proposition (mieux structurée) de Philippe.
Ca progresse!
En attendant d'autres questions, merci encore!
GDM