Discussion :

[laure26500]

bonjour a tous

en premier lieu je tiens a m'excuser car je suis complètement novice en macro
et votre mission si vous l'acceptez ne sera pas de trouver une solution a mon problème, pour vous du gâteau mais de réussir a me la faire appliquer

il s'agit donc d'une macro pour insérer des images via un chemin d’accès (faite par quelqu'un d'autre que moi ) et cela fonctionne bien
mais lorsque j'envoie le fichier a une tierce personne, l'image est remplacée par une croix rouge

j'ai lu que l'on pouvait fixer une image

vu sur un forum" il faut définir le paramètre linktofile sur msofalse et le paramètre savewithdocument sur msotrue pour que l'image reste liée au fichier (et donc devienne indépendante de son chemin d'accès)."

sauf que je ne sais pas comment faire

Sub LinkToImage()

Range("I7").Select
Range(Selection, Selection.End(xlDown)).Select
Selection.Copy
' les lignes du haut selectionnent les cellules contenant la concatenation (1)

Range("J7").Select
Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
:=False, Transpose:=False
'colle en tant que valeur les resultats de la formule concatennee (2)

Range("J7").Select
' selectionne les cellules collees (2) en tant que valeur

Range(Selection, Selection.End(xlDown)).Select


For Each cel In Selection
cel.Offset(0, -9).Select
cel.Offset(0, -9).RowHeight = 100
cel.Offset(0, -9).ColumnWidth = 40
'ajuste la taille des cellules ou seront collees les photos



Set image = ActiveSheet.Pictures.Insert(cel.Value)

With image
.ShapeRange.LockAspectRatio = msoTrue
.Width = cel.Offset(0, -9).Width
.Height = cel.Offset(0, -9).Height
.Left = cel.Offset(0, -9).Left
.Top = cel.Offset(0, -9).Top
'-9 correspond au decalage de l'image ( ici en colonne 1)par rapport au chemin d acces ici en colonne 10 (ramene a 9)


End With

Next cel

End Sub


merci d'avance a l’âme charitable qui prendra le temps de me répondre

[EricDgn]

Bonjour,


Pour disposer de la propriété LinkToFile, il faut utiliser l'instruction Shapes.AddPicture() plutôt que l'instruction Pictures.Insert(). Sans doute quelque chose de ce genre:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Option Explicit
 
Sub LinkToImage()
    Dim cel As Range
    Range("I7").Select
    Range(Selection, Selection.End(xlDown)).Copy
    ' les lignes du haut selectionnent les cellules contenant la concatenation (1)
    Range("J7").PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks:=False, Transpose:=False
    'colle en tant que valeur les resultats de la formule concatennee (2)
    Range("J7").Select
    ' selectionne les cellules collees (2) en tant que valeur
    Range(Selection, Selection.End(xlDown)).Select
    For Each cel In Selection
        cel.Offset(0, -9).Select
        cel.Offset(0, -9).RowHeight = 100
        cel.Offset(0, -9).ColumnWidth = 40
        'ajuste la taille des cellules ou seront collees les photos
        ActiveSheet.Shapes.AddPicture _
            Filename:=cel.Value, _
            LinkToFile:=msoFalse, _
            SaveWithDocument:=msoTrue, _
            Width:=cel.Offset(0, -9).Width, _
            Height:=cel.Offset(0, -9).Height, _
            Left:=cel.Offset(0, -9).Left, _
            Top:=cel.Offset(0, -9).Top
            '-9 correspond au decalage de l'image (ici en colonne 1)par rapport au chemin d acces ici en colonne 10 (ramene a 9)
        ActiveSheet.Shapes(ActiveSheet.Shapes.Count).LockAspectRatio = msoTrue
    Next cel
End Sub

Cordialement.