Discussion :

[rossemma]

Bonjour à tous,

j'ai ce code adapté par moi d'internet qui coince et je ne comprends pas pourquoi.
cela coince à la ligne : For Each ligne In .ListRows.Count
qui peut m'aider.

merci d'avance

Co1, col4 et T1 sont les numéros de colonne donnés par un autre code qui fonctionne très bien.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
With ws.ListObjects("TAB3")
        For Each ligne In .ListRows.Count
           If ligne.Cells(col1).Value <> "" And ligne.Cells(col4).Value = "" Then
                ligne.Cells(T1).Value = "x"
            Else
                ligne.Cells(T1).Value = ""
            End If
        Next ligne
End With

[MarcelG]

Bonjour à toi, Bonjour au Forum,

Houlà!

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

For Each ligne In .ListRows.Count

Cette ligne ne veut absolument rien dire

Pour un tel balayage, il te faudrait utiliser un indice (exemple i) et le borner au sein d'une boucle

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Dim i As Long
 
For i = 1 to .Listrows.Count

D'autre part, tu ne retournes pas l'intégralité de ta procédure.

Quoi qu'il en soit, l'objet Cells doit être défini selon 2 paramètres

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Worksheets(1).Cells(Rowindex:=ligne, Columnindex:=colonne)

Mais au delà du code VBA, pourquoi ne pas utiliser une formulation au sein même du tableau structuré.

Les avantages:
- Report automatique de la formule à références structurées sur toutes les lignes (enregistrements) de la table de données
- Recalcul automatique lors d'une modification des dépendants

Un conseil enfin, affecter des noms de colonnes explicites ("Voiture" et non "Col14")

2 tutoriels incontournables
Les tableaux structurés
VBA sur tableaux structurés

[rossemma]

super
merci pour ton aide
j'ai voulu trop compliqué
je vais utiliser ton conseil ==> formule

[Pierre Fauconnier]

Salut

J'ai un gros doute sur le nom de ton tableau, car il n'est normalement pas possible de nommer un tableau TAB3, puisque c'est une adresse de cellule. Du coup, que vaut le code que tu as montré?


Tu peux boucler avec un for Each, mais tu dois le faire correctement. De plus, perso, j'éviterais de préfixer le tableau du nom de la feuille, ça ne sert à rien et c'est accidentogène.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub Test()
  Dim t1 As Long, col1 As Long, col4 As Long
  Dim Ligne As ListRow
 
  col1 = 1
  col4 = 4
  t1 = 7
 
  With Range("Tableau3").ListObject
    For Each Ligne In .ListRows
      If Ligne.Range(col1).Value <> "" And Ligne.Range(col4).Value = "" Then
        Ligne.Range(t1).Value = "x"
      Else
        Ligne.Range(t1).Value = ""
      End If
    Next Ligne
  End With
End Sub

Le bloc With ne sert à rien. On s'en sert lorsque l'on a plusieurs lignes qui se raccorde à l'objet déclaré sur le With, mais ici, tu ne l'utilise que sur la ligne suivante... Du coup, tu peux utiliser ceci:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub Test()
  Dim t1 As Long, col1 As Long, col4 As Long
  Dim Ligne As ListRow
 
  col1 = 1
  col4 = 4
  t1 = 7
 
  For Each Ligne In Range("tableau3").ListObject.ListRows
    If Ligne.Range(col1).Value <> "" And Ligne.Range(col4).Value = "" Then
      Ligne.Range(t1).Value = "x"
    Else
      Ligne.Range(t1).Value = ""
    End If
  Next Ligne
End Sub

Tu peux aussi te passer de boucler et placer une formule puis réaliser un collage spécial valeurs à la mode VBA: Range.Value = Range.Value

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub Test1()
  Dim Cellule As Range
  Dim t1 As Long, col1 As Long, col4 As Long
 
  Range("tableau3").ListObject.ListColumns(7).DataBodyRange.FormulaR1C1 = _
    "=IF(AND(RC[-6]<>"""",RC[-3]=""""),""x"","""")"
  Range("tableau3").ListObject.ListColumns(7).DataBodyRange.Value = _
    Range("tableau3").ListObject.ListColumns(7).DataBodyRange.Value
End Sub

Comme on n'a pas tout le code intéressant, notamment celui qui valorise T1, col1 et col4, difficile de t'aider mieux, mais perso, je préfères travailler avec les noms des colonnes dans un tableau structuré. C'est souvent plus intéressant.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub Test1()
  Dim Cellule As Range
  Dim t1 As Long, col1 As Long, col4 As Long
 
  With Range("tableau3").ListObject.ListColumns("Test")
    .DataBodyRange.Formula = _
      "=IF(AND([@ID]<>"""",[@Donnée]=""""),""x"","""")"
    .DataBodyRange.Value = _
      .DataBodyRange.Value
  End With
End Sub

[rossemma]

j'ai finalement utiliser des formules
Merci à tous.