Discussion :

[ecleenew]

Bonjour,

Dans une tableau Excel, je dois rechercher une séquence de texte de type xx-xxxx dans une cellule, où x est un entier de 0 à 9.
Cette séquence peut être mélangée à du texte, on peut donc avoir dans la cellule Excel :
- seulement la séquence de type xx-xxxx
- cette séquence précédée et/ou suivie par du texte : blabla xx-xxxx blabla

J'arrive à trouver la séquence en balayant chaque ligne à l'aide du macro vba et en utilisant une expression régulière (0-9){2}-(0-9){4}.

Mais je voudrai exclure les cas où la séquence est précédée par "I" ou "I-".
Je ne sais pas comment intégrer cette restriction dans mon expression régulière.

Je me suis dis qu'une macro et les expressions régulières pouvaient résoudre ce besoin, mais si vous voyez d'autres méthodes, je suis également preneur.

Merci d'avance si vous pouvez m'aider à résoudre cette difficulté.

Bien cordialement,
Emmanuel

[Jean-Philippe André]

Salut,

de combien de lignes x colonnes serait-il question dans ton tableau ?

Un expression régulière soit, mais si ton tableau fait 100 lignes ou 100 000 lignes, ca sera un sacré paquet de recherche.

Peux tu nous en dire plus ?

[Pierre Fauconnier]

Salut.

Le pattern à utiliser est le suivant: "^((?!I|I-).)*\d{2}-\d{4}.*$"

Par exemple, dans une fonction perso qui validerait une regexp:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Function MatchRegExp(Value As String, Pattern As String)
  Dim RegExp As Object
 
  Set RegExp = CreateObject("VBScript.RegExp")
  RegExp.Pattern = Pattern
  RegExp.Global = True
  MatchRegExp = RegExp.Test(Value)
  Set RegExp = Nothing
End Function

Il faudrait voir si I ou I- peuvent se trouver avant la séquence de chiffres mais non collés. Avec mon pattern, "I- bonjour 12-1234 au revoir" va renvoyer FAUX...

Peut-être faudrait-il que tu précises les possibilités?

[ecleenew]

Bonjour,

Un grand merci pour cette réponse.

Dans les données que j'ai à traiter, je n'ai jamais rencontré de cas où il y avait un espace entre I / I- et la séquence à détecter, mais si la réponse peut aussi couvrir ce cas, je serai certain de couvrir tous les cas de figure.
Petite précision sur mon besoin : dans le retour de la fonction, je voudrai extraire la séquence détectée :



Pour supprimer le texte après la séquence, j'ai trouvé comment modifier le Pattern = "^((?!I|I-).)*\d{2}-\d{4}". En tout cas, ça a l'air de fonctionner.
Mais je ne sais pas comment supprimer le texte précédant la séquence.

Merci d'avance pour votre aide.

Emmanuel

[Pierre Fauconnier]

Dans ce cas, tu peux créer des groupes dans ton pattern, puis extraire le énième groupe. Les groupes sont séquencés par des parenthèses et commencent à 1. Le groupe d'exclusion n'est pas pris en compte, puisqu'il est vide, par définition. L'objet RegExp permet le remplacement de chaines de caractères, et les groupes sont repris dans la chaine de remplacement par $ suivi du rang du groupe. Dans ton cas, il suffit donc de renvoyer le groupe du rang souhaité.

Voici la fonction que tu peux utiliser pour cela:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Function ExtraireTexte(Value As String, Pattern As String, Index As Long) As String
  Dim RegExp As Object
 
  Set RegExp = CreateObject("VBScript.RegExp")
  RegExp.Pattern = Pattern
  If RegExp.test(Value) Then ExtraireTexte = RegExp.Replace(Value, "$" & Index)
End Function

Pour ton cas, tu utiliseras le pattern suivant: "^((?!I|I-).)*(\d{2}-\d{4})(.*)" => le groupe (\d{2}-\d{4}) est donc le deuxième. Il est important ici de regrouper ce qui suit le code dans un groupe pour pouvoir l'exclure du remplacement. Tu peux utiliser la fonction dans une feuille de calcul:




Le tuto de Caféine sur le sujet: https://cafeine.developpez.com/access/tutoriel/regexp/

[Pierre Fauconnier]

En fait, tes exemples ont confirmé mes craintes. Avec le pattern que je t'ai donné, une cellule qui contiendrait un I ou I- n'importe où AVANT le code à extraire serait rejeté. Dans l'illustration suivante, Incident F12-7858 sera rejeté alors qu'il devrait normalement être repris. C'est ce que je voulais exprimer, probablement de façon maladroite, dans le message #3.



Je pense que la bibliothèque utilisée ne permet pas la recherche arrière. Du coup, il va falloir ruser et passer par une fonction spécifique pour extraire le code, et non plus une fonction générique comme celle que j'avais proposée.

Le but est de créer des groupes de captures que l'on peut isoler avec Execute. Un groupe est englobé dans des parenthèses et est repris dans la collection Matches liée à la RegExp. L'idée est donc de tester si, juste avant le code, on a I ou I- et d'isoler cela dans un groupe. On isole le code dans un second groupe. Le pattern particulier devient alors : (I|I-)?(\d{2}-\d{4}) et on peut extraire le groupe capturé (\d{2}-\d{4}). il reste à tester si le premier groupe capturé est vide. Si oui, on récupère le code, sinon c'est qu'il contient I ou I- et on ne récupère rien...

Code vba :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Function ExtraireCode(Value As String) As String
  Dim Matches As Object
  Dim Pattern As String
  Dim RegExp As Object
 
  Pattern = "(I|I-)?(\d{2}-\d{4})"
  Set RegExp = CreateObject("VBScript.RegExp")
  With RegExp
    .Pattern = Pattern
    Set Matches = RegExp.Execute(Value)
    If RegExp.test(Value) Then
      If Matches.Item(0).submatches(0) = "" Then ExtraireCode = Matches.Item(0).submatches(1)
    End If
  End With
  Set RegExp = Nothing
  Set Matches = Nothing
End Function

[ecleenew]

Bonsoir Pierre,

Effectivement, on peut avoir des "I" dans le texte précédent la séquence, qui seraient venus perturber l'analyse.
Je viens de tester la dernière proposition, j'ai l'impression qu'elle répond parfaitement à mon besoin.

Merci beaucoup, ça va singulièrement faciliter mon analyse.

Je marque le sujet comme résolu.

Bonne soirée,
Emmanuel

[Pierre Fauconnier]

Super...

Les RegEx, c'est toujours un peu délicat, surtout avec la bibliothèque utilisée en VBA, car elle ne permet pas toutes les finesses des bibliothèques C#, Java ou php...

Bon boulot pour la suite et bonne soirée