Discussion :

[Rioflane]

Bonjour,

Je ne m'y connais pas en VBA et je tatonne avec quelques bribes de codes trouvées sur des forums.

Voici ma problématique :

J'ai un classeur comprenant une dizaine de feuilles (catégorie)
Sur chaque feuille il y a plusieurs fiches opérations
Chaque fiche a le même format

Jusqu'à présent nous faisions des éditions papiers pour présenter les projets aux collectivités partenaires. Mais avec la crise sanitaire les prochaines présentations se feront en visio. Je suis chargée de créer un document PDF. Une table des matières avec des liens vers les fiches classées par filière et non par catégorie...

Gros casse-tête pour l'amatrice que je suis. Et surtout si export PDF manuel j'en ai pour un moment !

Je voudrais pouvoir exporter chaque fiche au format PDF dans un dossier pour ensuite les organiser dans le bon ordre du document final.

La macro que j'ai adaptée ne fonctionne que pour 5 zones d'impression définies. J'obtiens bien 5 PDF, que je dois nommer manuellement. Mais pour les feuilles où j'aurais 20 fiches opérations, je ne sais pas comment m'en sortir. Une macro par feuille ? je vous joins un extrait de 2 onglets de mon tableau FICHES_OPERATIONS.xlsm

Et ci-dessous la mini-macro que je voudrais pouvoir développer et utiliser sur toutes mes feuilles.




Dans l'idéal j'aimerais qu'au moment de l'export un nom automatique soit attribué (le contenu de la colonne 3 de la 2ème ligne de chaque fiche)

Merci d'avance si vous avez une idée à me proposer.

Rioflane

[Invité]

Bonjour,

Important : Votre fichier contient des données confidentielles.

J'ai ajouté un onglet "Paramètres" pour identifier les différentes zones à imprimer pour chaque onglet. Cet onglet contient un tableau structuré nommé TableDesZones.

Pièce jointe 599674

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
 
Sub ImprimerEnPdf()
 
Dim AireOnglets As Range, AireAdresses As Range, AireNomPdf As Range, AireAImprimer As Range
Dim I As Long
Dim OngletChoisi As String, RepertoireFichiersPdf As String, CheminComplet As String
 
 
   OngletChoisi = Sheets("Paramètres").Range("NomDeLOnglet")
   RepertoireFichiersPdf = ActiveWorkbook.Path & "\Fichiers pdf\"
 
   Set AireOnglets = Range("TableDesZones[Onglets]")
   Set AireAdresses = Range("TableDesZones[Adresses]")
   Set AireNomPdf = Range("TableDesZones[Nom des fichiers pdf]")
 
   For I = 1 To AireOnglets.Count
        With AireOnglets(I)
             If .Value = OngletChoisi Then
                CheminComplet = RepertoireFichiersPdf & AireNomPdf(I) & " " & Gdh
                Set AireAImprimer = Sheets(AireOnglets(I).Value).Range(AireAdresses(I).Value)
                AireAImprimer.ExportAsFixedFormat Type:=xlTypePDF, Filename:=CheminComplet & ".pdf", _
                              quality:=xlQualityStandard, includedocproperties:=True, _
                              ignoreprintareas:=False, openafterpublish:=False
                Set AireAImprimer = Nothing
             End If
        End With
   Next I
 
   Set AireOnglets = Nothing: Set AireAdresses = Nothing: Set AireNomPdf = Nothing
 
 
End Sub
 
 
 
Function Gdh() As String
 
Dim DateExport As String, HeureExport As String
Dim TableDate As Variant, TableHeure As Variant
 
       TableDate = Split(CStr(Date), "/")
       DateExport = TableDate(2) & "-" & TableDate(1) & "-" & TableDate(0)
       TableHeure = Split(CStr(Time), ":")
       HeureExport = TableHeure(0) & TableHeure(1) & TableHeure(2)
       Gdh = DateExport & " " & HeureExport
 
End Function

Nb : Le tableau structuré a été construit à l'aide d'un code.

[Rioflane]

Merci beaucoup Eric,

Je vais avoir besoin de temps pour mettre en pratique et "décoder" votre code mais si j'obtiens le résultat de votre capture d'écran ça devrait ressembler à ce que je cherche à obtenir !

Je reviendrais clôturer cette discussion quand j'aurais réussi.

Merci encore !

Floriane