Discussion :

[olivepao]

Hello le forum

J'ai créé une petite macro me permettant d'insérer une ligne vide entre deux lignes de données

Le style n'est peut-être pas trop académique mais le résultat est conforme à mes attente.

Le seul problème est que j'ai une erreur N° 9 à la fin de ma macro, lorsque je sors de la boucle.

Un grand merci pour votre aide

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
Sub Ins_Lign_1Sur2()
'Macro permettant d'insérer une ligne vide entre chaque ligne de données
 
Dim i As Integer 'Boucle
Dim Ligne_Tab As Long 'Nombre de ligne dans le tableau
Dim Tableau As ListObject 'Définition du tableau
Dim Ligne_Vide As Long 'Lignes vides insérées entre chaque ligne
 
Set Tableau = ActiveSheet.ListObjects(1)
 
Ligne_Tab = Tableau.Range.Rows.Count 'Les lignes du tableau sont comptées
 
Ligne_Vide = (Ligne_Tab + Ligne_Tab)
 
For i = 2 To Ligne_Vide Step 2
 
   Tableau.ListRows(i).Range.Insert Shift:=xlDown
 
Next i
 
End Sub

[Pierre Fauconnier]

Salut.

Les insertions et suppressions en chaine, il vaut mieux les commencer par le bas du tableau pour éviter de se mêler les pinceaux avec le comptage des lignes.

Voici pour ajouter une ligne vide entre les lignes de données. Avec .Count+1, on ajoute aussi une ligne après la dernière ligne. Si on ne veut ajouter que entre les lignes existantes, il faut supprimer le -1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub Test()
  Dim l As ListObject
  Dim i As Long
 
  Set l = Range("tableau1").ListObject
  For i = l.ListRows.Count + 1 To 2 Step -1
    l.ListRows.Add i
  Next
End Sub

Au delà de cette précision, je suis curieux de savoir à quoi ça sert. Normalement, dans un tableau structuré, on n'a pas de lignes entièrement vides et l'ordre des lignes, à de rares exceptions près, ne devrait pas avoir d'importance. Insérer des lignes vides puis trier va bien foutre la pagaille dans le tableau. Quelle est la finalité de l'opération?

[olivepao]

Merci Pierre d'avoir éclairé ma lanterne.

L'insertion a pour but d'insérer des infos complémentaires à la ligne précédente.

Très bonne fin de journée

[Pierre Fauconnier]

[...]
L'insertion a pour but d'insérer des infos complémentaires à la ligne précédente.[...]

Et donc, comme je le disais, bonjour le chaos en cas de tri des lignes

La raison d'être des tableaux structurés est de stocker TOUTE l'information relative à une donnée sur LA ligne de cette donnée, et pas sur plusieurs lignes pour UNE donnée. De plus, dans un TS, une colonne ne contient que des données d'une seule nature (prénom, ID, ...). En ajoutant des lignes pour "compléter" l'info, tu vas casser la structure de ton tableau, tant pour les lignes que pour les colonnes.

Ca n'a pas de sens. Il serait plus intéressant d'ajouter des colonnes pour permettre l'ajout d'infos.

[olivepao]

Merci Pierre pour ces précisions
Je vais y penser
Bonne soirée