Discussion :

[Elsouba]

Bonsoir a vous,
Après de nombreuses recherches et temps sur internet et sur l'ordi, j'ai avancé sur mon fichier.
Ou je bloque :
Quand je lance mon fichier a partir de mon bouton en fuil1, la validation des données n'enregistre rien. Quand je le lance du developpeur la saisie est enregistrée.....
Je bloque sur la possibilité de faire apparaite sur 3 lignes ma saisie des choix d'instrument.
Je suis en train de chercher pour faire un moteur de recherche me permettant d'effectuer une recherche sur l'ensemble des lettres d'un nom mais je verrais aprés.
Merci de votre aide.

[anasecu]

Bonjour,

Quand je lance mon fichier a partir de mon bouton en fuil1, la validation des données n'enregistre rien. Quand je le lance du developpeur la saisie est enregistrée.....

C'est normal car tu n'as pas choisis la feuille d'enregistrement et comme ceci cela fonctionnera correctement.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
 With Sheets("BDD")
     L = .Range("a65536").End(xlUp).Row + 1 'Pour placer le nouvel enregistrement à la première ligne de tableau non vide
 
     .Range("A" & L).Value = TextBox1
     .Range("B" & L).Value = TextBox2
     .Range("C" & L).Value = TextBox3
     .Range("D" & L).Value = TextBox4
     .Range("E" & L).Value = TextBox5
     .Range("F" & L).Value = TextBox6
     .Range("G" & L).Value = TextBox7
     .Range("H" & L).Value = TextBox8
     .Range("I" & L).Value = CheckBox1
     .Range("J" & L).Value = TextBox9
     .Range("K" & L).Value = CheckBox2
     .Range("L" & L).Value = TextBox10
     .Range("M" & L).Value = CheckBox3
     .Range("N" & L).Value = TextBox11
 End With

[Pierre Fauconnier]

Salut.

Perso:

• J'utiliserais un tableau structuré pour stocker mes données;
• Je nommerais correctement mes contrôles.

Je pourrais alors utiliser les références structurées dans mon code au sein d'une procédure placée dans un module standard et appelée par le clic sur le bouton de validation du userform:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub SaveData()
  Dim i As Long
 
  i = Range("t_Contacts").ListObject.ListRows.Add().Index
  With usfContact
    Range("t_Contacts[Prénom]")(i).Value = .tboFirstname.Value
    Range("t_Contacts[Nom]")(i).Value = .tboLastname.Value
    Range("t_Contacts[Date Naissance]")(i).Value = CDate(.tboBirthdate.Value)
  End With
End Sub

Par rapport à Range("a65536").End(xlUp) et à la mise en concordance délicate des colonnes et des textbox, ca n'a que des avantages, car

• je découple ainsi mon code de la plage du tableau dans mon classeur;
• je n'impose pas qu'il y ait une donnée sur chaque ligne de la première colonne. Avec le code .End(xlUp), si ta dernière ligne de données n'est pas remplie en A, tu vas l'écraser par les données du userform. L'utilisation du tableau structuré évite ce problème;
• je ne limite pas ma saisie à 65536 lignes (vieux code obsolète d'avant XL2007 => logique de programmation obsolète selon moi), même si je me doute que ce sera rare de saisir autant de lignes;
• j'écris un code plus lisible car on voit de suite la relation entre la colonne et le contrôle puisque l'on utilise des noms parlants des deux côtés.

Lorsqu'il y a autant de données à transférer, j'utilise une boucle sur une table de mappage pour m'éviter l'énumération de toutes les colonnes dans le code.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Sub SaveData()
  Dim i As Long
  Dim j As Long: j = 1
  Dim Target As Range
 
  i = Range("t_Contacts").ListObject.ListRows.Add().Index
  With usfContact
    Do While j <= Range("t_Mappage").Rows.Count
      Set Target = Range("t_Contacts[" & Range("t_Mappage[Colonne]")(j).Value & "]")(i)
      Select Case Range("t_Mappage[Type]")(j).Value
        Case "T", "B"
          Target.Value = .Controls(Range("t_Mappage[Contrôle]")(j).Value).Value
        Case "N"
          Target.Value = .Controls(Range("t_Mappage[Contrôle]")(j).Value).Value * 1
        Case "D"
          Target.Value = CDate(.Controls(Range("t_Mappage[Contrôle]")(j).Value).Value)
      End Select
      j = j + 1
    Loop
  End With
End Sub

On peut ainsi tendre vers du code générique qui transfère les données de n'importe quel couple tableau/userform apparié, pour ne pas réinventer la roue à chaque fois.

[Elsouba]

Bonjour,
Merci pour vos message

@anasecu : merci effectivement ca fonctionne. Nickel
@ Pierre Fauconnier : merci de ton détail, avec ton exemple, ce la voudrait-il dire que mon fichier BDD serait le tableau structuré qui pourrait se trouver en feuil2 et toujours avoir sur la feuil 1 un bouton pour lancer mon formulaire?

[Pierre Fauconnier]

Oui. Il faut qu'il y ait un tableau structuré et dans ton classeur, ce serait effectivement sur la feuille 2, mais tu peux en fait le placer n'importe où, puisque dans le code que j'ai donné, on remarque qu'à aucun moment je ne parle de la place du tableau (sa feuille, la plage qui le recouvre, etc), car son nom suffit à pouvoir le manipuler. C'est LA raison pour laquelle il faut utiliser le tableau structuré en VBA plutôt que les vieilles méthodes avec End(xlUp) ou plages nommées avec DECALER qui sont devenues obsolètes.

Quelques liens:

• Mon tuto sur les tableaux structurés;
• Une contribution sur les échanges de données entre userform et tableau structuré (dans l'exemple de la présente discussion, j'ai ajouté la notion de type de données);
• Mon tuto (non terminé) sur les tableaux structurés en VBA.

[Elsouba]

Ok, merci a toi.
Je peux me permettre de revenir vers toi pour completer mon fichier?

[Elsouba]

Bonjour a tout le monde


Je vais essayé d’etre plus clair dans ma saisie.
Mon fichier a pour but de saisir des infos concernant des éléves pour differents instruments.
en ouvrant mon fichier, je peux saisir, transferer et recherche des infos.
Ce que je n’arrive pas a faire :

dans la recherche, je voudrais saisir n’importe quelle lettre ou chiffre et faire apparaitre des résultats dans la liste deroulante (dans mon exemple, saisr bu pour me faire apparaitre Ducobu)
si je saisie des infos concernant un instrument que toutes les infos avant les noms d’instruments soit identique et qu’une ligne se crée par rapport à l’instrument (j’ai fait un exemple dans la base de données.

Merci de votre aide

[TOFatJOB]

bonjour,

un exemple de recherche mutli colonnes (ce n'est pas de moi, je n'ai pas noté la source désolé) qui doit répondre à ton besoin.

Cordialement,


Intuitif2colonnesCodeDescription.xls

[Elsouba]

Bonjour TOFatJOB,

Merci de ton message.
Pourrais-tu m'aider à l'inserer dans mon code?

Merci à toi

[ese1212]

Intéressant, serait il possible d'avoir un formulaire semblable avec un choix multiple?

[TOFatJOB]

Bonjour,

un exemple que j'ai trouvé sur le forum (je crois) qui doit vous aider à concrétiser votre développement.

cordialement,

RechercheMultiMotsMultiColonnes.xls