Discussion :

[Gwenna]

Bonjour,
j'ai besoin d'aide....
J'ai créé une macro qui envoie un mail. Pour ce faire, j'ai créé un bouton. Ca fonctionne.
Mais ce que je souhaiterais, c'est que cette macro se lance d'elle même si dans n'importe quelle cellule de la colonne N de ma feuille "multiservice" est indiqué le mot "Oui".

Un grand merci pour votre aide.

[Philippe Tulliez]

Bonjour,
Pour lancer une procédure si une valeur est modifiée dans une feuille, on passe par une procédure événementielle soit Worksheet_Change si le changement ne se passe que dans une feuille soit par Workbook_SheetChange si l'événement peut avoir lieu dans plusieurs feuilles

Pour en savoir plus, je conseille la lecture de

• Les évènements dans la feuille de calcul Excel
• Les évènements du module objet ThisWorkbook, dans Excel

[Gwenna]

Bonjour,
un grandmerci.

J'ai déjà testé plusieur marcro utilsant worksheet change. Mais je n'arrive pas à trouver celle qui recherche la valeur "oui" dans chaque cellule de la collonne n (cf. Mon expemple) et qui executerait ma ma macro MailOut

Encore merci pour votre aide.

bien à vous

[Philippe Tulliez]

Bonjour,
La procédure événementielle Worksheet_Change a un argument nommé Target qui représente l'objet Range où a eu lieu le changement.

Exemple d'une procédure qui affiche le message "Lancer l'envoi du mail" si la cellule (Target) où a eu lieu la modification dans la feuille où se trouve la procédure événementielle Worksheet_Change répond aux conditions énumérée ci-dessous
L'objet Target

• représente bien une seule cellule
• se trouve dans un tableau structuré (ListObject)
• se trouve dans la bonne colonne (étiquette "Mail" du tableau
• sa valeur est Oui (non sensible à la casse)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Private Sub Worksheet_Change(ByVal Target As Range)
  Dim olist As ListObject
  Dim FirstColumn As Integer ' N° de colonne où débute le tableau
  With Target
    If .Count = 1 Then
       Set olist = .ListObject
       If Not olist Is Nothing Then
          FirstColumn = olist.Range.Column
          If .Column - FirstColumn + 1 = olist.ListColumns("Mail").Index Then
             If StrComp(.Value, "Oui", vbTextCompare) = 0 Then
               ' Ici la ligne de code pour invoquer la procédure d'envoi de mail
                MsgBox "Lancer l'envoi du mail"
             End If
          End If
       End If
    End If
  End With
  Set oList = Nothing
End Sub

Il suffit de remplacer la ligne 12

Ces lignes de code auraient pu faire l'objet d'une procédure indépendante

[EDIT]

Ces lignes de code auraient pu faire l'objet d'une procédure indépendante

Voici donc une proposition avec une procédure générique qui vérifie si la cellule (Target) où a eu lieu le changement de valeur se trouve bien dans un tableau structuré et dans la colonne nommé Mail

Procédure à placer dans un module standard

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Function IsTargetOk(Target As Range, Label As String) As Boolean
  Dim olist As ListObject
  Dim FirstColumn As Integer ' N° de colonne où débute le tableau
  With Target
    If .Count = 1 Then
       Set olist = .ListObject
       If Not olist Is Nothing Then
          FirstColumn = olist.Range.Column
          If .Column - FirstColumn + 1 = olist.ListColumns(Label).Index Then IsTargetOk = True
       End If
    End If
  End With
  Set olist = Nothing
End Function

Code allégé de la procédure événementielle Worksheet_Change

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Private Sub Worksheet_Change(ByVal Target As Range)
  If IsTargetOk(Target, "Mail") Then
     If StrComp(Target.Value, "Oui", vbTextCompare) = 0 Then
        MsgBox "Lancer l'envoi du mail"
     End If
  End If
End Sub

[Pierre Fauconnier]

Salut Gwenna (ça vient de faire tilt... J'espère que tu vas bien )

L'énoncé n'est pas forcément très clair. De ce que j'en comprends, le "OUI" ne doit pas forcément être sur la cellule qui est modifiée. Pour coller à la demande initiale => Envoyer un mail si OUI se trouve dans une colonne, voilà comment j'agirais.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Private Sub Worksheet_Change(ByVal Target As Range)
  If Evaluate("Countifs(tableau1[Mail],""OUI"")") > 0 Then SendMail
End Sub
 
Sub SendMail()
  MsgBox "Mail Envoyé"
End Sub

Le problème est que le "OUI" peut être le résultat d'une formule et donc la modification en "OUI" ne déclenche pas forcément l'évènement "Change". Pourrais-tu détailler ta situation et ton besoin? Une copie d'écran pourrait-être intéressante.

[Gwenna]

Je viens d'essayer et c'est ok ...ca marche...et ce Malgré la formule si qui amène le "oui"...Quel est le risque pour que ca ne fonctionne pas...?

En tout cas un énorme merci