Discussion :

[VBANoJutsu]

Hello tout le monde,

Je me permets d'ouvrir un topic car je tente de réaliser une macro mais j'ai un petit problème .
L'idée : ouvrir tous les classeurs de mon dossier (c'est ok), copy / paste les lignes 14 à 27 des classeurs que j'ai open , refermer tous les classeurs (c'est ok) .

J'explique ce que je souhaite réaliser : copy / paste les lignes 14 à 27 de tous les classeurs ouverts dans un classeur vierge (celui contenant la macro) le problème est que je copy / paste les lignes du premier workbook puis du second mais le second écrase les données précédentes ! Je n'arrive pas à boucler de sorte que à chaque copy / past pour avoir l'intégralité des données de chaque classeur dans une feuille du new. Je pense qu'il faut utiliser un copy/paste au niveau de la destination qui stipulerait à partir de la derniere cellule vide mais j'ai un peu de mal .

Si quelqu'un peut m'aider et surtout m'expliquer , par avance merci !!

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Sub OpenFiles()
Dim MyFolder As String
Dim MyFile As String
Dim lig As Integer
Dim i As Integer
Dim Wb As Workbook
 
MyFolder = "C:\*****\Extract"
MyFile = Dir(MyFolder & "\*.xls")
Do While MyFile <> ""
Workbooks.Open Filename:=MyFolder & "\" & MyFile
    For Each Wb In Application.Workbooks
     For lig = 14 To 27
        Wb.Sheets(1).Cells(lig, 1).EntireRow.Copy
        For i = 1 To (27 - 14) * 4
        ThisWorkbook.Sheets(1).Cells(i, 1).PasteSpecial Paste:=xlPasteValues
        Next i
     Next lig
    Next
 
ActiveWorkbook.Close SaveChanges:=False
MyFile = Dir
Loop
End Sub

[Patrice740]

Bonjour,

Essaies comme ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Option Explicit
Sub OpenFiles()
Dim wbk As Workbook
Dim rng As Range
Dim cel As Range
Dim MyFolder As String
Dim MyFile As String
 
  MyFolder = "C:\*****\Extract"
  MyFile = Dir(MyFolder & "\*.xls")
  With ThisWorkbook.Worksheets(1)
    .Cells.Clear
    Set cel = .Range("A1")
  End With
  Do While MyFile <> ""
    Set wbk = Workbooks.Open(Filename:=MyFolder & "\" & MyFile)
    Set rng = wbk.Worksheets(1).Range("14:17")
    rng.Copy Destination:=cel    'copier tout (avec les formats)
    cel.Resize(rng.Rows.Count, rng.Columns.Count).Value = rng.Value    'copier les valeurs (sans les formats)
    Set cel = cel.Offset(rng.Rows.Count, 0)
    wbk.Close SaveChanges:=False
    MyFile = Dir
  Loop
End Sub

[VBANoJutsu]

Hello , merci beaucoup ça fonctionne très bien ! Je me permets de te poser deux questions afin de bien comprendre si tu es d'accord !

1 ) le with était il nécessaire n'ayant qu'une instruction avec ?
2 ) le set suivi du offset permet de réinitialiser la plage de destination à chaque tour de boucle ?

Par avance merci et sorry si mes questions semblent évidentes !

Thanks.

[Patrice740]

1 ) le with était il nécessaire n'ayant qu'une instruction avec ?

Il y a deux instructions "avec", lignes 2 et 3 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
  With ThisWorkbook.Worksheets(1)
    .Cells.Clear
    Set cel = .Range("A1")
  End With

Le With n'est pas indispensable mais cette structure permet non seulement d’alléger l'écriture, mais surtout plus de clarté et une meilleure architecture du code en regroupant toutes les instruction concernant cet objet (cette feuille).
A la place j'aurais pu écrire ces 2 lignes :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
  ThisWorkbook.Worksheets(1).Cells.Clear
  Set cel = ThisWorkbook.Worksheets(1).Range("A1")

2 ) le set suivi du offset permet de réinitialiser la plage de destination à chaque tour de boucle ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set cel = cel.Offset(Rng.Rows.Count, 0)

Cette ligne ne réinitialise pas (ne revient pas au point départ) la plage mais défini la prochaine cellule de destination à la fin de chaque boucle.

[VBANoJutsu]

Merci beaucoup Patrice pour ton explication et le temps que tu m'as accordé !

J'ai compris et ça fonctionne .

Très cordialement.