Discussion :

[AirDuster]

Bonjour à tous,

J'aimerais mettre en couleur des lignes suivant leurs valeurs, en réalité, tous les impaires comme dans cet exemple (ici en rouge) :



J'ai donc crée une boucle comme ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
        Ligne = 10 'première ligne à vérifier
        compteur3 = 1
 
 
        Do While Not IsEmpty(Range("A" & Ligne))
 
        If Worksheets("excel").Range("A" & Ligne).Value = compteur3 Then
            Range("A" & Ligne).Font.Color = RGB(255, 0, 0)
        End If
 
 
       compteur3 = compteur3 + 2
        Ligne = Ligne + 1
 
        Loop

Ce code ne fonctionne pas, seulement la ligne 10 est rouge.
Il ne boucle pas correctement dans le IF, pourtant l’algorithme me semble bon...

Merci d'avance.

[Invité]

Bonjour,

A tester :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
 
Sub Test()
 
Dim I As Long, DerniereLigne As Long
 
    With ActiveSheet
         DerniereLigne = .UsedRange.SpecialCells(xlCellTypeLastCell).Row
         For I = 10 To DerniereLigne
             With .Cells(I, 1)
                  .Font.ColorIndex = xlAutomatic
                  If .Value Mod 2 > 0 Then .Font.Color = RGB(255, 0, 0)
             End With
         Next I
    End With
 
End Sub

[Menhir]

Il y a beaucoup plus simple : faire une mise en forme conditionnelle avec la formule =MOD(A10;2)=1.

[AirDuster]

Bonjour Eric,

Merci pour votre réponse, cela fonctionne parfaitement !

Par contre, petite mise à jour de mes besoins, seul colonne A est en rouge, que dois-je modifier si je veux que ce soient les lignes A à I qui soit en rouge ?


Merci beaucoup !

[AirDuster]

Dois-je créer plusieurs FOR ?

[Menhir]

Selon moi, tu n'as même pas besoin de créer de macro.

[Invité]

Par contre, petite mise à jour de mes besoins, seul colonne A est en rouge, que dois-je modifier si je veux que ce soient les lignes A à I qui soit en rouge ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
 
Sub Test()
 
Dim I As Long, J As Long, DerniereLigne As Long
 
    With ActiveSheet
         DerniereLigne = .UsedRange.SpecialCells(xlCellTypeLastCell).Row
         For I = 10 To DerniereLigne
             For J = 1 To 9
                 With .Cells(I, J)
                      If IsNumeric(.Value) Then
                         .Font.ColorIndex = xlAutomatic
                         If .Value Mod 2 > 0 Then .Font.Color = RGB(255, 0, 0)
                      End If
                 End With
             Next J
         Next I
    End With
 
End Sub

[AirDuster]

Bonjour Eric,


Le code que vous m'avez envoyé ne fonctionne pas correctement, j'aimerais que la ligne soit rouge uniquement en fonction de la colonne A comme ceci :


Là le code fait un modulo de toutes les cellules comme ceci :


J'ai bien évidemment essayé de modifier le code avant de revenir demander de l'aide.

[Menhir]

Avec une MFC, ça se fait en 1 min.

[Invité]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
 
Sub Test()
 
Dim I As Long, DerniereLigne As Long
 
    With ActiveSheet
         DerniereLigne = .UsedRange.SpecialCells(xlCellTypeLastCell).Row
         .Range(.Cells(10, 1), .Cells(DerniereLigne, 9)).Font.ColorIndex = xlAutomatic
         For I = 10 To DerniereLigne
             If .Cells(I, 1).Value Mod 2 > 0 Then
                .Range(.Cells(I, 1), .Cells(I, 9)).Font.Color = RGB(255, 0, 0)
             End If
         Next I
    End With
 
End Sub

Bonjour Menhir

[Pierre Fauconnier]

Salut.

Aller plus vite "montre en mains" avec une technique plutôt qu'une autre ne veut rien dire car tout dépend du contexte. Si une MFC (mise en forme conditionnelle) est par essence dynamique et s'applique sans code, il est clair que si le besoin est de créer des feuilles à la volée, éventuellement statiques, la mfc, mise en place par Excel ou par vba (car il est possible de mettre de la mfc par VBA, mais attention aux versions linguistiques du code utilisé), n'a strictement aucun intérêt.

La comparaison d'une méthode Excel et de l'utilisation de VBA n'a de sens que dans un contexte qui permet la comparaison

Cela dit, si les données s'y prêtent, ce qui a l'air d'être le cas ici, la mise en tableau structuré avec l'option "Lignes à bande" résout le problème sans mfc. Tout est donc, comme souvent, une question de contexte.