Discussion :

[Krimo_48]

Bonjour à tous,

Débutant en VBA, je rencontre le problème cité en objet. Lorsque je clique sur le bouton "Générer Fiche d'Accompagnement" l'aperçu qui m'en ressort et différent de celui que j'ai lorsque je clique que sur fichier>imprimer>aperçu. Dans l'idéale, j'aimerais ne conserver en zone d'impression que les lignes pleines en conservant les tableaux tels qu'ils apparaissent sur la Feuille "FICHE D'ACCOMPAGNEMENT" avec les titres, les en-têtes et pieds-de-page.

A terme, j'aimerais créer une macro qui m'enregistrerait le fichier sous le format "date"+ le texte contenu en cellule D5 de la fiche d'Accompagnement sous un format dans le cas présent "061219-Prélèvement(s) sur chantier n°19186". Une fois le fichier enregistré, j'aimerais pouvoir l'envoyer par mail.

Votre aide me serait très précieuse.

Merci beaucoup par avance.

Karim

[EricDgn]

Bonjour,

Quelques possibilités, à adapter.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub GENERER_FICHE_D_ACCOMPAGNEMENT()
    Dim wsBord As Worksheet, wsFich As Worksheet
    Set wsBord = ThisWorkbook.Sheets("BORDEREAU D'ACCOMPAGNEMENT")
    Set wsFich = ThisWorkbook.Sheets("FICHE D'ACCOMPAGNEMENT")
    '--- vérification
    If wsBord.Range("O2") = "" Or wsBord.Range("Q2") = "" Then
        MsgBox "Indiquer la Référence Chantier et la Date de dépose pour pouvoir envoyer votre Fiche d'Accompagnement"
         Exit Sub
    End If
    '--- vider fiche d'accompagnement
    wsFich.Select
    wsFich.Range("A4:L1000").Clear
    '--- copier données filtrées
    wsBord.Columns("A:L").AdvancedFilter Action:=xlFilterCopy, _
                                      CriteriaRange:=wsBord.Range("O1:Q2"), _
                                      CopyToRange:=Range("A4"), _
                                      Unique:=True
    '--- aperçu
    wsFich.PrintPreview
End Sub

Proposition faite sur base de la présentation présente dans le fichier attaché qui n'est plus tout à fait celle que vous avez envoyée.

Un début de solution pour ce qui est de sauver la feuille "Fiche d'accompagnement" avec la date et le n° de chantier:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub PrintPdf()
    '--- sauvegarder en pdf
    Dim sDossier As String, sFichier As String
    sDossier = ThisWorkbook.Path & "\"
    sFichier = Format(Date, "yymmdd") & "-Prélèvements chantier n°" & Range("E3")
    ActiveSheet.ExportAsFixedFormat _
        Type:=xlTypePDF, _
        Filename:=sDossier & sFichier, _
        Quality:=xlQualityStandard, _
        IncludeDocProperties:=True, _
        IgnorePrintAreas:=False, _
        OpenAfterPublish:=True
End Sub

Pour ce qui est de l'envoi par mail, vous trouverez facilement d'autres discussions qui traitent ce ce sujet. Il faut pour commencer par savoir si cet envoi utilise Outlook ou pas.

Bonne continuation.

[Krimo_48]

Bonjour Eric, Merci beaucoup pour ces propositions qui fonctionnent parfaitement