Discussion :

[calagan99]

Bonjour à tous,

je cherche à identifier le nombre d'occurrences de cellules d'une ligne qui matchent avec deux critères combinés.
J'ai essayé plusieurs choses avec SOMMEPROD et NB.SI.ENS sans parvenir à mes fins.

Mon fichier est structuré ainsi :


Je cherche à identifier le nombre de cellules dont le type est "RR" au cours de l'année 2019.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=NB.SI.ENS(B2:M2;"=RR";B2:M2;">"&DATE(31;12;2018))

me renvoie 0

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=NB.SI.ENS(B2:M2;"=RR";B2:M2;">31/12/2018")

me renvoie 0

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD((B2:M2="RR")*(B2:M2 > "31/12/2018"))

me renvoie 3 là où seules 2 cellules devraient matcher

Je ne vois pas ce que je loupe.
Si quelqu'un a une idée, je suis preneur

Merci d'avance.

[Patrice740]

Bonjour,

Tu peux utiliser BDNB()

[calagan99]

Merci pour cette réponse Patrice740 mais je ne vois pas comment utiliser BDND puisque je cherche à ce que mon critère de date soit appliqué sur plusieurs colonnes.

[Patrice740]

Bonjour,

Merci pour cette réponse Patrice740 mais je ne vois pas comment utiliser BDND puisque je cherche à ce que mon critère de date soit appliqué sur plusieurs colonnes.

C'est justement le rôle de la fonction BDNB : compter, dans une base de données (un tableau), le nombre de lignes répondant à des critères multiples, sans limite du nombre de critères.
Pour l'utiliser, le plus simple est de créer une zone de critères sur une autre feuille dédiée.

C'est simple à utiliser, si comme c'est demandé, il s'agit de compter le nombre d'occurrences de cellules d'une ligne qui matchent avec deux critères combinés.

C'est moins évident lorsque la formule doit être tirée sur toutes les lignes d'un tableau : il faut alors utiliser des critères formulés dont la syntaxe n'est pas des plus évidentes (mais, à priori ce n'est pas le cas).

Un vieil exemple d'utilisation : Recherche dans une base de données.xls

[papouclo]

Bonjour,

=NB.SI.ENS(B2:M2;"=RR";B2:M2;">"&DATE(31;12;2018)) me renvoie 0

Il y a une première erreur sur la syntaxe de la fonction DATE dont les paramètres doivent être dans l'ordre année,mois et jour en dernier.
Il faut donc écrire DATE(2018;12;31).
Mais surtout, Excel parcourt la plage 1 et la plage 2 dans le même ordre pour tester si, simultanément, la première cellule de la plage 1 vérifie le critère 1 et la première cellule de la plage 2 vérifie le critère 2, puis Excel passe à la deuxième cellule de chaque plage ...
Or dans la formule les deux plages sont identiques; cela revient donc à se demander si une même cellule peut être simultanément du texte égal à RR et une date supérieure au 31/12/2018.
On comprend le résultat de la formule.
La formule la plus simple serait :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=NB.SI.ENS(D2:M2;"RR";C2:L2;">"&DATE(2018;12;31))

Si l'on a la plage globale B2:M2 sur laquelle doit se faire le travail et que l'on sait seulement que la date est écrite une colonne avant le type, on peut écrire aussi :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=NB.SI.ENS(B2:M2;"RR";DECALER(B2:M2;0;-1);">"&DATE(2018;12;31))

Cordialement
Claude

[Patrice740]

Bonjour,

Une autre possibilité avec DECALER(), qui ne teste que les cellules concernées :
=SOMME(NB.SI.ENS(DECALER(D2;0;{0;3;6;9});"RR";DECALER(C2;0;{0;3;6;9});">"&DATE(2018;12;31)))