Discussion :

[roulax]

Bonjour,

J’ai créé un userform dans ma macro et une variable. Cette variable va être alimentée lors du déroulement de la procédure du userform. Je voulais savoir si je pouvais stocker cette valeur dans le code, et l’utiliser dans une autre procédure d’un module du même fichier. Quand la procédure de mon userform s’arrête, la valeur n’est plus définie. Comment faire ? Merci par avance pour votre aide.

[Garuda]

Il faut déclarer dans un de tes modules des variables "globales" (publiques) dans la partie [general] : tu pourras les utiliser dans tous tes modules de l'application

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
Option Explicit
Public g_mon_entier As Integer, g_ma_chaine As String

[Pierre Fauconnier]

Salut.

Je n'aime pas les variables globales... Avoir besoin de variables globales dans son code relève presqu'à coup sûr d'un défaut de conception/architecture. Les variables globales rendent les procédures/fonctions de l'appli dépendantes de ce que le code a réalisé avant qu'elles soient appelées. On comprend vite que les tests sont très difficiles à réaliser avec des variables globales et que le moindre arrêt de code sur débogage, par exemple, vide les variables globales, rendant obligatoire le fait de relancer tout le code alors que les manipulations effectuées rendent probablement un "run global" impossible. Il faut fuir les variables globales.

Voici comment procéder pour récupérer une valeur de userform:

Imaginons un userform usfTest muni d'un textbox tboName et d'un bouton btnValidate. En plus il dispose d'une propriété Choice qui permettra de savoir si on a fermé le usf par clic sur le bouton. Ce userform va être appelé par une procédure qui initialise la valeur du textbox. Après fermeture du userform, s'il a été fermé par clic sur le bouton btnValidate la valeur du textbox est récupérée dans une variable avant le déchargement du userform. Ta procédure continue alors en utilisant la valeur récupérée. Le code que j'expose ici montre donc deux techniques: la récupération d'une propriété publique du userform (Choice) et la récupération de la valeur d'un contrôle du userform que l'on passe à une variable. Lorsque la valeur a été affectée à la variable, le userform peut être déchargé puisque ce dont on avait besoin a été stocké ailleurs.

Voici le code du userform

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Option Explicit
 
Public Choice As String
 
Private Sub btnValidate_Click()
  Choice = "Validate"
  Me.Hide
End Sub

Et voici le code de la procédure appelante

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub Test()
  Dim Name As String
  Dim Choice As String
 
  With usfTest
    .tboName.Value = "Pierre"
    .Show
    If .Choice = "Validate" Then Name = .tboName.Value
  End With
  Unload usfTest
  MsgBox "Vous avez saisi le nom: " & Name
End Sub

[ulyssep]

Je ne comprends pas pourquoi Choice est déclaré dans l'UF en public et dans le module en normal. Quelle est l'utilité de ce dernier ?

[Pierre Fauconnier]

Salut.

En fait la ligne Dim Choice As String dans le module standard est de trop, puisque pas utilisée par la suite. On utilise juste la propriété Choice du userform. Il faut noter au passage que la ligne Public Choice As String dans le module du userform n'en fait pas une variable publique (ou globale), mais une propriété (publique, autoimplémentée en lecture/écriture) du userform.

[ulyssep]

Je ne suis pas sûr de comprendre pourquoi c'est une propriété et non une variable mais ça m'a permis de comprendre ce que tu expliquais précédemment et m'incite à modifier mon code pour supprimer les variables globales que j'utilisais massivement... Merci !