Discussion :

[MarcelG]

Bonjour à tous,

Je fais suite à une discussion menée conjointement avec Menhir.

Le but était de parcourir un Range SpeciallCells, ici sur 1 colonne, depuis sa dernière cellule.

Celle-ci peut s'obtenir par ailleurs en considérant la chaine de caractères de son adresse.
C'est la "ruse" que j'ai adoptée.

Mais.

Ma 1ère idée était donc de combiner 2 retours de cellules spéciales.

SpecialCells(lignes vides).SpcialCells(la dernière cellule)

Le résultat retourné est faux.

Ma question est de savoir pourquoi.

Merci par avance pour vos retours.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
Sub remplit_vides()
 
Dim lastrow As Long
Dim rngspéc As Range
Dim premspéc_row As Integer
Dim dernspéc_row As Integer
Dim i As Integer
 
Dim lacolonne As String
lacolonne = "C"
 
Application.ScreenUpdating = False
 
With Worksheets("LAFEUILLE")
 
        lastrow = .Cells(.Rows.Count, 2).End(xlUp).Row
 
        With .Range(lacolonne & "3:" & lacolonne & lastrow)
 
                On Error Resume Next
                Set rngspéc = .SpecialCells(xlCellTypeBlanks)
                On Error GoTo 0
 
                If rngspéc Is Nothing Then GoTo lend_de_lasub
 
                Debug.Print rngspéc.Address
                premspéc_row = rngspéc.Cells(1, 1).Row
                Debug.Print premspéc_row
 
                'Ne fonctionne pas!?
                dernspéc_row = rngspéc.SpecialCells(xlCellTypeLastCell).Row
                Debug.Print dernspéc_row
 
                With rngspéc
                        dernspéc_row = Right(.Address, Len(.Address) - InStrRev(.Address, "$"))
                End With
                Debug.Print dernspéc_row
 
 
        End With
 
 
        For i = dernspéc_row To premspéc_row Step -1
 
                If Not (Intersect(rngspéc, .Cells(i, 3)) Is Nothing) Then
 
                        With .Cells(i, 3)
                            Debug.Print .Address
                            .Value = .Offset(1, 0).Value
                        End With
 
                End If
 
        Next i
 
lend_de_lasub:
 
        Set rngspéc = Nothing
 
End With
 
End Sub

[unparia]

Bonjour
je te rappelle que la constante xlCellTypeLastCell concerne non pas la dernière cellule d'une plage spécifiée, mais celle du UsedRange

[MarcelG]

Bonjour,

Sur un exemple

B4, B5 informées
B6 Vide
B7 informées
B8 vide
B9 informée

Le code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Debug.Print Worksheets(1).Range("B4:B7").SpecialCells(xlCellTypeBlanks).Address

retourne

$B$6

Le code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Debug.Print Worksheets(1).Range("B4:B9").SpecialCells(xlCellTypeBlanks).Address

retourne bien

$B$6,$B$8

Le code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Debug.Print Worksheets(1).Range("B4:B9").SpecialCells(xlCellTypeBlanks).SpecialCells(xlCellTypeLastCell).Address

retourne

B9

Pour ma part, je m'attendais à

B8

.
Ce qui signifie que la 2ème méthode SpecialCells(xlCellTypeLastCell) rend la 1ère inefficace.

Et c'est cela qui m'étonne.

[Theze]

Bonjour,

la constante xlCellTypeBlanks de "SpecialCells()" retourne un plage de cellules vides (contiguës ou pas) donc, si tu appliques une recherche de dernière cellule utilisée (xlCellTypeLastCell) ça ne peut rien donné de concluant puisque la plage retournée avec xlCellTypeBlanks n'est justement pas utilisée !
Une piste (il y a sûrement mieux) pour trouver la ligne de la dernière cellule vide de la plage :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
 
Sub remplit_vides()
 
    Dim Plage As Range
    Dim DerPlage As String
    Dim DerCel As String
 
    Dim lastrow As Long
    Dim rngspéc As Range
    Dim premspéc_row As Integer
    Dim dernspéc_row As Integer
    Dim i As Integer
 
    With Worksheets("Feuil1")
 
        'en inversant le numéro de colonne 'ici, 3 et 2) la plage est définie
        'sur la dernière cellule non vide de la colonne 2
        Set Plage = .Range(.Cells(1, 3), .Cells(.Rows.Count, 2).End(xlUp))
 
        With Plage.Columns(2)
 
            On Error Resume Next
            Set rngspéc = .SpecialCells(xlCellTypeBlanks)
            If Err.Number <> 0 Then Exit Sub
            On Error GoTo 0
 
            premspéc_row = rngspéc.Cells(1, 1).Row
 
            'extrait la dernière plage
            DerPlage = Split(rngspéc.Address, ",")(UBound(Split(rngspéc.Address, ",")))
            'extrait la dernière cellule
            DerCel = Split(DerPlage, ":")(UBound(Split(DerPlage, ":")))
            'extrait le numéro de ligne
            dernspéc_row = Split(DerCel, "$")(2)
 
            Debug.Print "Première : " & premspéc_row; " --- Dernière : "; dernspéc_row
 
        End With
 
    End With
 
End Sub

[Theze]

B4, B5 informées
B6 Vide
B7 informées
B8 vide
B9 informée

Ta recherche de cellules vides c'est sur la colonne B ou C car dans ton premier code c'est la colonne C qui est visée

[MarcelG]

Salut Thézé,

J'ai juste voulu reporter un autre exemple dans mon post de réponse pour illustrer mon propos.
Pas de problème.

OK pigé.
C'est ce que voulait signifier Unparia, je pense.

OK pour ta méthode.
Tu peux regarder la mienne.
Nos deux méthodes ont en commun de traiter la chaine de caractères retournée par l'adresse.

Merci à vous et Bon Week-End.

[Theze]

Bonjour Marcel,

OK pour ta méthode.
Tu peux regarder la mienne.
Nos deux méthodes ont en commun de traiter la chaine de caractères retournée par l'adresse.

Je pensais que c'était ce que tu cherchais, j'ai juste donné une autre façon maintenant, il y a plus rapide pour avoir la première et dernière cellule vide d'un colonne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
 
Sub Test()
 
    'première cellule vide de la colonne C
    MsgBox Cells(1, 3).End(xlDown).Row + 1
 
    'dernière cellule vide de la colonne C
    MsgBox Cells(Rows.Count, 3).End(xlUp).End(xlUp).Row - 1
 
End Sub

Il faut juste gérer l'absence de cellules vides et de valeurs !