Discussion :

[Kestion100]

Bonjour,
Je cherche à faire ouvrir un fichier word sous Excel puis vérifier si un texte contenu dans une cellule est présent dans le fichier word.

Ouvrir et fermer le fichier Word ne me pause pas de problème mais je n'arrive pas à trouver un code qui me permette de vérifier la présence d'un texte.

Le code que j'utilise:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
Sub ouvrirWord()
 
 
 
FichWrd = Range("C2").Value
 
Dim WordApp As Word.Application
 
Set WordApp = CreateObject("Word.Application")
 
Dim objWord As Word.Document
Set objWord = GetObject(FichWrd, "Word.Document")
 
Set objWord = WordApp.Documents.Open(FichWrd, ReadOnly:=True)
 
' Rend Word visible important car la fusion ne se fait pas si pas visible
objWord.Application.Visible = True
NomFichier = objWord.Name
'Remplacement = "Mot De Remplacement"
 
motRecherché = Range("A2").Value
 
 
objWord.Content.Find.Execute FindText:="motRecherché" ', ReplaceWith:=Remplacement, Replace:=wdReplaceAll
 
 
 
Exit Sub
 
 
 WordApp.Quit
 
 
Set WordApp = Nothing
 
 
End Sub

Je pensais passer par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

objWord.Content.Find.Execute FindText:

Mais je ne trouve pas comment tester.

Merci pour votre aide

[BENNASR]

bonjour
je sais pas si ça va t'aider mais ...une tentative
avec CTRL + touche H et l'enregistreur automatique peut être ça amène à une début de piste
BONNE CONTINUATION

[Kestion100]

Je ne pense pas que l'enregistreur de macro enregistre ce que je demande au code de faire sous Word????

[Menhir]

je n'arrive pas à trouver un code qui me permette de vérifier la présence d'un texte.

Le Find de Word est très différent de celui d'Excel.
Contrairement au Find d'Excel qui est une méthode, celui de Word est un Objet, propriété du contenu du document.
Il ne suffit pas de lui transmettre des paramètres comme dans Excel, il faut renseigner les propriété de l'Objet Find avant de lui appliquer sa méthode Execute.
Lire l'aide VBA Word sur ce sujet : https://docs.microsoft.com/fr-fr/off.../api/word.find

Je ne pense pas que l'enregistreur de macro enregistre ce que je demande au code de faire sous Word????

Pour info, Word aussi a un enregistreur de macro.
Autre info : les questions concernant les objets Word sont à poser de préférence dans la rubrique Word du forum.

[Kestion100]

OK, comme le code est sous Excel, je pensais....
Je ne sais pas comment déplacer ce sujet.

Peut-être existe-t-il une autre façon de faire que Find sous Word?


Merci

[Menhir]

OK, comme le code est sous Excel, je pensais....

Ce n'est pas l'application qui supporte le code qui représente la difficulté mais les objets manipulés.

Peut-être existe-t-il une autre façon de faire que Find sous Word?

Pour rechercher un élément dans un texte Word ? Je ne vois pas plus simple que Find.

[Kestion100]

Avec l'enregistreur sous Word, j'obtiens:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Selection.Find.Execute
    With Selection.Find
        .Text = "fbgbh"
        .Replacement.Text = "teyyhtr"
        .Forward = True
        .Wrap = wdFindContinue
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With

Avec

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

.Text=

n'importe quoi, j'espérais obtenir un retour d'erreur et pouvoir travailler dessus mais aucun retour.

????

[Invité]

Bonjour,

Vous cherchez à vérifier la présence d'une chaine ou bien à remplacer cette chaine ?

[Kestion100]

Je cherche à en vérifier la présence.

J'ai trouvé une autre possibilité, compter le nombre d’occurrence du mot que je cherche, à 0, l n'est pas dans le texte.

Le code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub Tst()
Dim Cpt As Long
    Cpt = 0
    Selection.HomeKey Unit:=wdStory
    With Selection.Find
        .Text = "gfdfdhdhb"
       .Forward = True
       .Wrap = wdFindStop
 
    End With
 
    Do While Selection.Find.Execute
       Cpt = Cpt + 1
    Loop
 
    Debug.Print Cpt
End Sub

fonctionne parfaitement.

Comment puis-je l'intégrer dans Excel?????

[Invité]

Bonjour,

Testez cette fonction

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
 
Option Explicit
 
Sub TesterPresenceChaine()
 
    MsgBox PresenceChaine("C:\XXXXXXX\Doc1.docx", "teyyhtr") ' A adapter
 
End Sub
 
Function PresenceChaine(ByVal CheminComplet As String, ByVal TexteATrouver As String) As Boolean
 
Dim wApp As Object
Dim DocAModifier As Object
Dim MaSelection As Object
 
    Application.ScreenUpdating = False
    PresenceChaine = False
 
    Set wApp = CreateObject("Word.Application")
    With wApp
 
         Set DocAModifier = .Documents.Open(Filename:=CheminComplet)
         With DocAModifier
              Set MaSelection = wApp.Selection
              With MaSelection.Find
                   .ClearFormatting
                   .Text = TexteATrouver
                   .Execute Forward:=True
              End With
              If MaSelection.Find.found = True Then PresenceChaine = True
              .Close
        End With
        .Quit
    End With
 
    Set MaSelection = Nothing
    Set DocAModifier = Nothing
    Set wApp = Nothing
 
    Application.ScreenUpdating = True
 
 
End Function

[Kestion100]

PARFAIT, MERCI!!!!!!!!!!!!!!!!!!!!!!!!

[Marco26]

Merci beaucoup je teste ceci dès demain. Bonne soirée.