Discussion :

[conconbrr]

Bonjour le forum,

Je me demandais s'il était possible d'empêcher l'ouverture de plus d'un fichier à la fois?
Je m'explique, j'ai créé un "logiciel" et pour avoir une interface sympa, lorsqu'on l'ouvre, il y a passage en plein écran, création de barres d'outils tt en enlevant celles par défaut, suppression de la barre Windows etc etc

Pour que l'utilisateur puisse quand même ouvrir Word ou une autre appli en même temps que le logiciel, j'ai rajouté un bouton sur une BO qui permet de faire tour à tour disparaître et apparaître la barre Windows.

La seule chose que je veux empêcher c'est que l'utilisateur ouvre un autre fichier Excel parce que dans ce cas là il n'aura plus accès aux barres d'outils standard ni au logiciel (en arrière plan) et sera obligé de quitter de manière non conventionnelle, enfin bon bref ça fout la merde

Est-ce possible?

[conconbrr]

Personne n'a d'idée??

[SfJ5Rpw8]

Personne n'a d'idée??

ben si finalement.. le principe une fois mon classeur ouvert... avec toutes sa mise en forme.. (barre d'outils...) ... sur ouverture d'un nouveau classeur on ferme le classeur et on l'ouvre à nouveau dans une nouvelle session d'excel (sans la mise en forme des menus ...) ..

pour cela on as besoin des événements d'application ... il faut créer un module de classe dans ton classeur excel ..., dans l'éditeur VBE, Menu Insertion/Module de classe .. le renommer

WithEventsClasseApp

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
 
'
' Module de classe : WithEventsClasseApp
'
Public WithEvents App As Application
 
Private Sub App_WorkbookOpen(ByVal Wb As Workbook)
Dim AppEx As Excel.Application
 Dim st As String
 If Wb.Name <> ThisWorkbook.Name Then
   st = Wb.Path & "\" & Wb.Name
   Wb.Close False
   Set AppEx = CreateObject("Excel.Application")
   AppEx.Visible = True
   AppEx.Workbooks.Open (st)
 End If
End Sub

ensuite dans un module standard (menu insertion module ) la variable de classe MonApp, et le code d'initialisation :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
 
Public MonAPP As New WithEventsClasseApp
Sub InialiseEventAPP()
 Set MonAPP.App = Application
End Sub

dans le ThisWorbook .. l'appel à la procédure d'initialisation

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
Private Sub Workbook_Open()
  InialiseEventAPP
End Sub

[conconbrr]

Merci pour la réponse Bbil, je n'ai pas le temps de tester tt de suite mais je ne manquerais pas de te le dire lorsque je l'aurais fait

[conconbrr]

lol ça fait pas si longtemps que ça effectivement
J'ai vraiment pas le temps d'essayer le truc là j'ai un peu trop de boulot mais promis je le ferais