Discussion :

[fb62840]

Bonjour,

Voici une portion code que j'ai rédigé et qui me pose souci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
 
Sheets(Source1).Activate
    Cells(77, Col).Select
    If Selection = "" Then 'je vérifie si la cellule est vide et si elle l'est
    If Cells(79, Col).Value = "" AND Cells(80, Col).Value = "" AND Cells(81, Col).Value = "" Then
'je vérifie si les cellules en lignes 79, 80 et 81 le sont aussi et si c'est le cas
    ShDEST.Activate
'on active la feuille ShDEST
    Range("B2").Value = "Choix non fait"
'et on inscrit cette mention dans la cellule B2
    Else
    ShDEST.Activate
    Range("B2").Value = "Choix fait"
' sinon on écrit cette mention dans la cellule B2
    End If
    End If
 
'même principe avec ce qui suit pour la
    Cells(82, Col).Select
    If Selection = "" Then
    If Cells(84, Col).Value = "" AND Cells(85, Col).Value = "" AND Cells(86, Col).Value = "" Then
    ShDEST.Activate
    Range("D2").Value = "Choix non fait"
    Else
    ShDEST.Activate
    Range("D2").Value = "Choix fait"
    End If
    End If

Dans tous les cas, c'est la mention "Choix non fait" qui apparaît alors que ça ne devrait pas être le cas.

Une idée pour m'aider à corriger ?

[Menhir]

Une idée pour m'aider à corriger ?

Avant de commencer à regarder ton code, il serait souhaitable que tu fasses un copier/coller du code que tu as écris dans le VBE.
Parce que le code que tu présentes ne peut pas venir du VBE.

Et c'est un peu frustrant de passer du temps sur un code qui a tronqué de la partie dans laquelle se trouve le problème (comme c'est déjà souvent arrivé sur ce forum).

[fb62840]

Avant de commencer à regarder ton code, il serait souhaitable que tu fasses un copier/coller du code que tu as écris dans le VBE.
Parce que le code que tu présentes ne peut pas venir du VBE.

Et c'est un peu frustrant de passer du temps sur un code qui a tronqué de la partie dans laquelle se trouve le problème (comme c'est déjà souvent arrivé sur ce forum).

Désole, voici le code depuis le début.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
 
Sub CreerTCDINDISPO_Plage_Dynamique()
'Déclaration des variables
Dim Mysource As Long
Dim Col
Dim MaFsource
Dim ShDEST
MaFsource = ActiveSheet.Name
Dim d
 
Application.ScreenUpdating = False
 
d = InputBox("Date? jj/mm/aa")
Worksheets("ShDEST").Range("A1").Value = CDate(d)
Worksheets("SHDEST").Range("B1").Value = "VALEURS"
  If d <> "" Then
 
    On Error Resume Next
    [b4:bb4].Find(What:=Format(CDate(d), "dddd d mmmm yyyy"), LookIn:=xlValues).Select
    Col = ActiveCell.Column
 
    Sheets(Source1).Activate
    Cells(77, Col).Select
    If Selection = "" Then 'je vérifie si la cellule est vide et si elle l'est
    If Cells(79, Col).Value = "" And Cells(80, Col).Value = "" And Cells(81, Col).Value = "" Then
'je vérifie si les cellules en lignes 79, 80 et 81 le sont aussi et si c'est le cas
    ShDEST.Activate
'on active la feuille ShDEST
    Range("B2").Value = "Choix non fait"
'et on inscrit cette mention dans la cellule B2
    Else
    ShDEST.Activate
    Range("B2").Value = "Choix fait"
' sinon on écrit cette mention dans la cellule B2
    End If
    End If
 
'même principe avec ce qui suit pour la
    Cells(82, Col).Select
    If Selection = "" Then
    If Cells(84, Col).Value = "" And Cells(85, Col).Value = "" And Cells(86, Col).Value = "" Then
    ShDEST.Activate
    Range("D2").Value = "Choix non fait"
    Else
    ShDEST.Activate
    Range("D2").Value = "Choix fait"
    End If
    End If

[Soticca]

Bonjour,

Vous sélectionnez la feuille Source1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheets(Source1).Activate

, mais comme Source1 est vide (en tout cas elle n'est pas initialisée dans votre code), il est normal de tomber toujours sur "Choix non fait" puisque les contenus des cellules testés seront toujours vide.

J'ai testé en mettant des valeurs dans les cellules 79, 80 et 81 et j'ai bien "Choix fait" qui s'inscrit. Vous ne devez donc pas récupérer les valeurs des cellules dans le bon onglet.

[MarcelG]

Bonjour,

Franchement, j'ai du mal à m'y retrouver.

Quelques conseils.

1 - Pourrais-tu coder

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Option Explicit

en début de module.
Cela t'obligera à déclarer tes variables.

Je te conseillerais même de l'inscrire dans tes options VBE (déclaration de variables obligatoire)

2 - Il est important pour sa lisibilité de bien attacher les objets dans le code en stipulant la feuille qui les contient.
Pour ce faire, utiliser la méthode

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

With

.

3 - Des redondances ("Activate")

4 - Arrête ces p... de Select qui n'ajoutent rien en terme d'efficacité.

5 - Enfin, décale tes lignes au sein d'un même bloc If.
On y verra plus clair.

Reviens ces précautions prises.

[unparia]

Bonjour
Et enlever ce vilain "On Error Resume Next" qui cache la poussière sous le tapisn etc ... etc ...
A ce niveau de cumul de carences, il ne s'agit plus de "correction", mais de tout revoir !

[Menhir]

Je suis dans un jour de bonté, je te fais un petit nettoyage :

Comme tu ne renseignes jamais la variable Source1, j'ai supposé que c'était une reliquat d'un changement de nom de la variable MaFSource et donc que Sheets(Source1) était la feuille active au lancement de la macro.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Option Explicit
 
Sub CreerTCDINDISPO_Plage_Dynamique()
    Dim Mysource As Long
    Dim Col As Long
    Dim Rech As Range
    Dim MaFsource As Worksheet
    Dim ShDEST As Worksheet
    Dim d As String
 
    Set MaFsource = ActiveSheet
    Set ShDEST = Worksheets("ShDEST")
 
    d = InputBox("Date? jj/mm/aa")
 
    If d <> "" Then
        ShDEST.Range("A1").Value = CDate(d)
        ShDEST.Range("B1").Value = "VALEURS"
 
        Set Rech = Range("B4:BB4").Find(What:=Format(CDate(d), "dddd d mmmm yyyy"), LookIn:=xlValues)
        If Rech Is Nothing Then Exit Sub
 
        Col = Rech.Column
 
        If Cells(77, Col) = "" Then
            ShDEST.Range("B2").Value = "Choix fait"
            If Cells(79, Col).Value = "" And Cells(80, Col).Value = "" And Cells(81, Col).Value = "" Then ShDEST.Range("B2").Value = "Choix non fait"
        End If
 
        If Cells(82, Col).Value = "" Then
            ShDEST.Range("D2").Value = "Choix fait"
            If Cells(84, Col).Value = "" And Cells(85, Col).Value = "" And Cells(86, Col).Value = "" Then ShDEST.Range("D2").Value = "Choix non fait"
       End If
   End If
End Sub

[Marc-L]

Bonjour !

Désole, voici le code depuis le début.

En retirant les fioritures, code simplifié ainsi :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub Demo1()
    Dim Rg As Range, V
    V = InputBox(vbLf & "Date ? jj/mm/aa"):  If V = "" Then Exit Sub
    If Not IsDate(V) Then Beep: Exit Sub
    V = CDate(V)
    Range("ShDEST!A1:B1").Value = Array(V, "VALEURS")
    Set Rg = [B4:BB4].Find(What:=Format(V, "dddd d mmmm yyyy"), LookIn:=xlValues)
     If Rg Is Nothing Then
        MsgBox "Date non trouvée …", vbExclamation, V
     Else
        V = Split("Choix fait,Choix non fait", ",")
        If Cells(77, Rg.Column).Value = "" Then Range("ShDEST!B2").Value = V(-(Application.CountIf(Cells(79, Rg.Column).Resize(3), "") = 3))
        If Cells(82, Rg.Column).Value = "" Then Range("ShDEST!D2").Value = V(-(Application.CountIf(Cells(84, Rg.Column).Resize(3), "") = 3))
        Set Rg = Nothing
     End If
End Sub

Si la source n'est pas la feuille active alors évidemment il faut la préciser devant ses cellules …

___________________________________________________________________________________________________________

     Merci de cliquer sur en bas à droite de chaque message ayant aidé puis sur pour clore cette discussion …