Discussion :

[Faridpo]

Bonjour à tous,

J'ai une table avec 2 champs et je souhaiterais mettre à jour le second avec sa valeur + une mention si un fichier dont le nom se trouve dans le 1er champ n'existe pas.

J'ai testé un bout de code mais apparemment j'ouvre la table et lit l'enregistrement donc Access ne veut pas faire la MàJ.

Je ne suis vraiment pas doué avec VBA donc soyez indulgent avec ce code qui n'est certainement pas optimisé :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
 
Function Test_Verif_Fichier()
 
Dim db As DAO.Database
Dim DateJour, Chemin, Indice, Test As String
Dim rs1 As DAO.Recordset
 
Chemin = "E:\"
DateJour = Right(Date, 4) & Mid(Date, 4, 2) & Left(Date, 2)
Set db = CurrentDb
Set rs1 = db.OpenRecordset("Select * from FichierDuJour")
 
Indice = rs1("Indice")
Test = rs1("Test")
rs1.MoveFirst
 
    Do While rs1.EOF = False
 
        If Dir(Chemin & DateJour & rs1.Fields("Indice")) = "" Then
 
        CurrentDb.Execute "UPDATE FichierDuJour SET Test" & " / Fichier Manquant"
 
        End If
 
        rs1.MoveNext
 
    Loop
 
End Function

Un grand merci pour votre aide toujours aussi précieuse (j'ai vraiment chercher à réussir seul ou avec Google mais j'ai fait chou blanc).

Farid

[tee_grandbois]

Bonjour,
tu peux utiliser le recordset que tu lis pour le mettre à jour (option dbopendynaset qui autorise la mise à jour, ensuite la méthode Edit pour modifier l'enregistrement et Update pour enregistrer):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Function Test_Verif_Fichier()
 
Dim db As DAO.Database
Dim DateJour as string, Chemin as string
Dim rs1 As DAO.Recordset
 
Chemin = "E:\"
DateJour = Right(Date, 4) & Mid(Date, 4, 2) & Left(Date, 2)
Set db = CurrentDb
Set rs1 = db.OpenRecordset("Select * from FichierDuJour", dbopendynaset)
if rs1.recordcount>0 then
 
    Do While rs1.EOF = False
 
        If Dir(Chemin & DateJour & rs1.Fields("Indice")) = "" Then
            rs1.Edit
            rs1("Test") = rs1("Test") & " / Fichier Manquant"
            rs1.Update
        End If
 
        rs1.MoveNext
 
    Loop
end if
set rs1 = nothing 
End Function

[Faridpo]

Bonjour,
tu peux utiliser le recordset que tu lis pour le mettre à jour (option dbopendynaset qui autorise la mise à jour, ensuite la méthode Edit pour modifier l'enregistrement et Update pour enregistrer):

Un très grand MERCI pour la rapidité et l'efficacité de ta réponse ! Ça fonctionne à merveille !

Ce ne sont que des mots mais je t'en suis très reconnaissant car je me torturais le cerveau depuis ce matin

Farid