Discussion :

[Protonus]

Bonjour,

J'ai fait une macro que je voudrait pouvoir utiliser sur d'autres fichiers excel.
J4ai suivi beaucoup de tuto qui permettent de le faire. Leur exemple fonctionne mais quand je l'applique à mon cas ca ne marche pas.
Situation: je suis daltonien. Office a eu la "bonne" idée d'utiliser la couleur verte pour encadrer les cellules actives. Je ne la vois pas.
J'ai donc chercher sur internet comment résoudre mon problème. Solution trouvé, utiliser la macro suivante:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Static Rng As Range
 
If Not Rng Is Nothing Then Rng.Interior.ColorIndex = xlNone
Target.Interior.ColorIndex = 12
Set Rng = Target
End Sub

Elle fonctionne très bien. Je la transforme donc en .XSLAM pour la partager avec mes autres feuilles. Je la valide deans les macros complémentaire mais rien ne se passe. Je met en pièce jointe le fichier XLSM car le XLSA n'est pas accepté par ce site.

Merci par avance pour votre aide.

[Menhir]

Les évènements Worksheet sont propres à la feuille de calcul dans laquelle ils sont enregistrés.
Donc, les mettre dans un autre fichier "générique" n'est pas une bonne idée.

Pour que ça concerne toutes les feuilles de tous les fichiers, il faut utiliser l'évènement Application.SheetChange.
https://msdn.microsoft.com/library/0...ice.15%29.aspx

Perso, je n'ai jamais touché aux évènements de Application. Je ne vois donc pas où il faut les placer.
Peut-être que d'autres pourront l'indiquer ou que tu trouveras des infos sur le sujet.

[Protonus]

Merci de ton aide. Je vais regarder si je trouve quelque chose a ce sujet.

[Protonus]

Bon malgré toutes mes recherches je n'arrive a rien. Quequ'un peux m'aiguiller s'il vous plait?
Merci par avance.

[eriiic]

Bonjour,

Avec une MFC plutôt, pour ne pas perdre les mises en forme.
à mettre dans ThisWorkbook :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Option Explicit
 
Private WithEvents App As Application
 
Private Sub App_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
    Dim fc     As FormatCondition
    For Each fc In Sh.Cells.FormatConditions
        If fc.Formula1 = "=""MFC_Sel""<>""""" Then fc.Delete
    Next fc
    With Target
        .FormatConditions.Add Type:=xlExpression, Formula1:="=""MFC_Sel""<>"""""
        .FormatConditions(Selection.FormatConditions.Count).SetFirstPriority
        With .FormatConditions(1).Interior
            .PatternColorIndex = xlAutomatic
            .Color = 52479
            .TintAndShade = 0
        End With
        .FormatConditions(1).StopIfTrue = False
    End With
End Sub
 
Private Sub Workbook_Open()
    'récupérer l'application Excel à l'ouverture
    Set App = Application
End Sub

Si tu modifies Sub App_SheetSelectionChange() relancer Workbook_Open() pour que les événements soient pris à nouveau en compte.

Par contre toute macro fait perdre l'annulation possible des dernières saisies (Ctrl+z).
Tu devrais fouiller du coté des 'Paramètres d'apparence avancés...' (clic-droit sur le bureau) pour voir s'il n'y aurait pas une solution plus générale. Je n'ai pas trouvé mais peut-être que quelqu'un a fouillé plus profondément de ce coté.
eric

PS: je n'arrive pas à insérer le fichier donc lancer Workbook_Open() pour tester.

[Protonus]

Bonjour,

Désolé pour la réponse tardive.
Ca marche super. Un grand merci toi.
Ca va enormement m'aider au quotidien.

J'avais déjà fouillé du coté apparence avancé mais sans résultat.